Zork — 3 of 13

Part 2 - Above Ground Stuff

A room called West of House is an outdoors room. "You are in an open field on the west side of a white house with a boarded front door."

The small mailbox is a container in West of House. The mailbox is fixed in place, closed, and openable.

Understand "box" and "mail box" and "mail-box" as the mailbox.

The size of the leaflet is 2.

The capacity of the mailbox is 10.

A leaflet is in the mailbox. The description of the leaflet is "[leaflet text]".

To say leaflet text:

center "Welcome to Zork!";

say paragraph break;

say " Zork is a game of adventure, danger, and low cunning. In it you will explore some of the most amazing territory ever seen by mortal man. Hardened adventurers have run screaming from the terrors contained within.[paragraph break]";

say " In Zork, the intrepid explorer delves into the forgotten secrets of a lost labyrinth deep in the bowels of the earth, searching for vast treasures long hidden from prying eyes, treasures guarded by fearsome monsters and diabolical traps![paragraph break]";

say " No system should be without one![paragraph break]";

[1]

say " Zork was created at the MIT Laboratory for Computer Science by

Tim Anderson, Marc Blank, Bruce Daniels, and Dave Lebling. It was inspired by the Adventure game of Crowther and Woods, and the long tradition of fantasy and science fiction games.[paragraph break]";

say " On-line information may be obtained with the command HELP (synonyms are ABOUT, INFO, HINT, etc.)."

The leaflet is inflammable.

An electric lamp is a kind of device. Carry out switching on an electric lamp: now the noun is lit. Carry out switching off an electric lamp: now the noun is unlit.

A portable supporter called a rubber welcome mat is here. "A rubber mat saying 'Welcome to Zork' lies by the door." The description of the mat is "The mat says 'Welcome to Zork'."

The size of the rubber welcome mat is

12.

Mat under is a truth state that varies. Mat under is usually false.

After taking, pushing, or pulling the rubber welcome mat:

if something (called the thingy) is on the mat begin;

say "As the mat is moved, [a thingy] falls from it and onto the floor.";

move the thingy to the location;

now mat under is false;

else;

now mat under is false;

continue the action;

end if.

Check removing something from the mat when mat under is true:

print the you can't see message instead.

An outdoors room called North of House is north of West of House. "You are facing the north side of a white house. There is no door here, and all the windows are barred." South of North of House is nowhere. West of North of House is West of House.

An outdoors room called South of House is south of West of House. "You are facing the south side of a white house. There is no door here, and all the windows are barred." North of South of House is nowhere. West of South of House is West of House.

An outdoors room called Behind House is east of North of House and east of South of House. "You are behind the white house. In one corner of the house is a window that is [if the window is closed]slightly ajar. [otherwise]open."

North of Behind House is North of House. South of Behind House is South of House. Behind House is outdoors.

The white house is a backdrop. The white house is in West of House and North of House and South of House and Behind House. The description of the white house is "The house is a beautiful colonial house which is painted white. It is clear that the owners must have been extremely wealthy."

The front door is scenery in West of House.

Check entering the front door: say "The door is locked, and there is evidently no key." instead.

Check going east from West of House: say "The door is locked, and there is evidently no key." instead.

Check opening the front door: say "The door cannot be opened." instead.

Check unlocking the front door with something: say "It doesn't seem to work." instead.

The window is a door. The window is west of Behind House and east of Kitchen. The window is closed and openable. The window is scenery.

Check climbing the window: try entering the noun instead.

Check going inside while the location is Behind House: try entering the window instead. Check exiting while the location is Kitchen: try entering the window instead.

Report opening the window: say "With great effort, you open the window far enough to allow entry." instead.

Report closing the window: say "The window closes (more easily than it opened)." instead.

After going through the window for the first time: award 10 points; continue the action.

The description of Kitchen is "This is the kitchen of the white house. A table seems to have been used recently for the preparation of food. A passage leads to the west, and a dark staircase can be seen leading upward. A dark chimney leads down and to the east is a small window which is [if the window is open]open. [otherwise]closed."

The sack is in Kitchen. "On the table is an enlongated brown sack, smelling of hot peppers." The sack is a closed openable container.

The sack is inflammable.

The capacity of the sack is 15. The size of the sack is 3.

Inside the sack is a lunch and a clove of garlic. The lunch and the garlic are edible.

Report eating something: say "Thank you very much. That reallly hit the spot." instead.

A closed openable transparent container called a bottle is in Kitchen. "Sitting on the table is a small bottle."

Check destroying the bottle:

say "A brilliant maneuver destroys the bottle.";

remove the bottle from play instead.

The capacity of the bottle is 4.

Check dropping the bottle when the player's command includes "throw":

try throwing the noun at the player instead.

Check throwing the bottle at something:

say "The bottle hits the far wall and shatters.";

remove the bottle from play instead.

Understand "bottle of [something related by containment]" as the bottle.

The Living Room is west of the Kitchen. "This is the living room. There is a door to the east. [if the wooden door is closed] To the west, there is a wooden door with strange gothic lettering, which appears to be nailed shut. [otherwise] To the west, there is a wooden door with strange gothic lettering and a cyclops-sized hole in it."

The description of the wooden door is "The engravings translate to 'This space intentionally left blank.' [if the door is open]The door has a cyclops-sized hole in it."

An oriental rug is here. "In center of the room is [if the trap door is not revealed]a large oriental rug.[otherwise][status of the trap door] trap door." Understand "carpet" as the rug.

A closed openable transparent container called a trophy case is here.

Check taking the case: say "The trophy case is securely fastened to the wall (perhaps to foil any attempt by robbers to remove it)." instead.

A weapon called an elvish sword is here. "On hooks above the mantelpiece hangs an elvish sword of great antiquity."

Understand "glamdring" and "orcrist" as the elvish sword.

Understand "lamp" as the battery-powered brass lantern.

The capacity of the trophy case is 32767.

The size of the sword is 30.

An electric lamp called a battery-powered brass lantern is here. "A battery powered brass lantern is on the trophy case."

The size of the battery-powered brass lantern is 15.

A broken lamp is a thing. Understand "lantern" and "brass" as the broken lamp.

Check throwing the lamp at something:

say "The lamp smashes into the ground and is ruined.";

remove the battery-powered brass lantern from play;

now the broken lamp is in the location instead.

Check dropping the battery-powered brass lantern when the player's command includes "throw":

say "The lamp smashes into the ground and is ruined.";

remove the battery-powered brass lantern from play;

now the broken lamp is in the location instead.

Instead of switching on or switching off the broken lamp: say "The lamp is broken. Some idiot must have smashed it.".

A newspaper is here. "There is an issue of US NEWS & DUNGEON REPORT here."

The description of the newspaper is

" [masthead]This is the Inform 7 version of Dungeon (Zork). For more information on Inform 7, see <http://inform-fiction.org>. Please report all bugs to Dean Menezes <samanddeanus@yahoo.com>.

Lots and lots and lots and LOTS of bugs have been fixed.

Aspiring adventurers should avail themselves of every opportunity to broaden their intellectual horizons and increase their perspicacity.

Fatal events have somewhat more convoluted results than previously."

The newspaper is inflammable.

To say masthead:

center "US NEWS AND DUNGEON REPORT";

center "2007[12 spaces]Late Dungeon Edition";

say paragraph break.

Understand "news", "report", and "paper" as the newspaper.

Forest is a region. Forest 1, Forest 2, Forest 3, Forest 4, Forest 5, and Up a Tree are in Forest.

North of North of House is Forest 4 with printed name "Forest" and description "This is a dimly lit forest, with large trees all around. One particularly large tree with some low branches stands here."

Every turn while the location is in Forest:

if a random chance of 1 in 5 succeeds, say "You hear in the distance the chirping of a song bird.".

Up a Tree is an outdoors room.

A door called the tree is a door. The tree is scenery. The tree is open and not openable. The tree is up from Forest 4 and down from Up a Tree.

The description of Up a Tree is "You are about ten feet above the ground nestled among some large branches. The nearest branch above you is beyond your reach."

Check climbing the tree: try entering the noun instead.

A container called a birds nest is here. "On the branch is a small birds nest. ". A closed unopenable container called a jewel-encrusted egg is in the nest. The initial appearance of the jewel-encrusted egg is "In the bird's nest is a large egg encrusted with precious jewels, apparently scavenged somewhere by a childless songbird. The egg is covered with fine gold inlay and ornamented in lapis lazuli and mother-of-pearl. Unlike most eggs, this one is hinged and has a delicate looking clasp holding it closed. The egg appears extremely fragile." The description of the egg is "The egg is covered with fine gold inlay and ornamented in lapis lazuli and mother-of-pearl. Unlike most eggs, this one is hinged and has a delicate looking clasp holding it closed. The egg appears extremely fragile."

Understand "whole" as the jewel-encrusted egg.

The birds nest is inflammable.

The capacity of the nest is 20.

The capacity of the jewel-encrusted egg is 6.

Check dropping something while the location is Up a Tree:

if the noun is not the jewel-encrusted egg begin;

say "[The noun] falls to the ground.";

move the noun to Forest 4 instead;

else if the golden clockwork canary is not in the jewel-encrusted egg;

say "The jewel-encrusted egg falls to the ground and is ruined.";

move the broken jewel-encrusted egg to Forest 4;

remove the broken canary from play;

remove the jewel-encrusted egg from play instead;

else;

say "The jewel-encrusted egg falls to the ground and is ruined.";

move the broken jewel-encrusted egg to Forest 4;

remove the jewel-encrusted egg from play instead;

end if.

The broken jewel-encrusted egg is an open openable container. The broken clockwork canary is inside the broken egg.

The golden clockwork canary is inside the jewel-encrusted egg.

Check dropping the jewel-encrusted egg when the player's command includes "throw": try destroying the broken egg instead.

Check throwing the jewel-encrusted egg at something:

try destroying the jewel-encrusted egg instead.

Check destroying the jewel-encrusted egg when the jewel-encrusted egg is not openable:

say "Your rather indelicate handling of the egg has caused it some damage.[line break]The egg is now open.";

move the broken egg to the holder of the jewel-encrusted egg;

remove the jewel-encrusted egg from play;

say "There is a golden clockwork canary nestled in the egg. It seems to have recently had a bad experience. The mountings for its jewel-like eyes are empty, and its silver beak is crumpled. Through a cracked crystal window below its left wing you can see the remains of intricate machinery. It is not clear what result winding it would have, as the mainspring appears sprung." instead.

Carry out winding the broken canary:

say "There is an unpleasant grinding noise from inside the canary."

The description of the broken canary is "There is a golden clockwork canary nestled in the egg. It seems to have recently had a bad experience. The mountings for its jewel-like eyes are empty, and its silver beak is crumpled. Through a cracked crystal window below its left wing you can see the remains of intricate machinery. It is not clear what result winding it would have, as the mainspring appears sprung."

The description of the golden clockwork canary is "This is a golden clockwork canary. It has ruby eyes and a silver beak. Through a crystal window below its left wing you can see intricate machinery inside. It appears to have wound down."

Check destroying the jewel-encrusted egg with something:

try destroying the jewel-encrusted egg instead.

After taking the jewel-encrusted egg for the first time: award 5 points; continue the action.

A beautiful brass bauble is a thing.

Bauble flag is a truth state that varies. Bauble flag is false.

The case-points of the jewel-encrusted egg is 7.

Carry out winding the golden clockwork canary:

if the player is in Forest and bauble flag is false begin;

say "The canary chirps, slightly off key, an aria from a forgotten opera.

From out of the greenery flies a lovely song bird. It perches on a

limb just over your head and opens its beak to sing. As it does so,

a beautiful brass bauble drops from its mouth, bounces off the top

of your head, and lands glimmering in the grass. As the canary winds

down, the song bird flies away.";

now bauble flag is true;

move the bauble to the location;

else;

say "The canary chirps blithely, if somewhat tinnily, for a short time.";

end if.

After taking the golden clockwork canary for the first time: award 6 points; continue the action.

After taking the bauble for the first time: award 1 point; continue the action.

The case-points of the golden clockwork canary is 2.

The case-points of the bauble is 1.

North of an outdoors room called Clearing is nowhere. West of Clearing is Forest 4.

Southwest of Clearing is Behind House. Northeast of Behind House is nowhere. East of Behind House is Clearing.

Forest 3 is an outdoors room.

South of Clearing is Forest 3. North of Forest 3 is South of House. East of Forest 3 is Clearing. "This is a dimly lit forest, with large trees all around. To the east, there appears to be sunlight." The printed name of Forest 3 is "Forest".

West of Forest 4 is North of House. Clearing is south of Forest 4. North of Forest 4 is Forest 3. South of Forest 3 is Forest 5. Forest 5 has printed name "Forest" . Forest 5 has description "This is a large forest, with trees obstructing all views except to the east, where a small clearing may be seen through the trees." North of Forest 5 is Forest 2. The description of Forest 2 is "This is a forest with trees in all directions around you." The printed name of Forest 2 is "Forest". South of Forest 5 is Forest 5. West of Forest 5 is Forest 3. North of Forest 2 is Forest 2. West of Forest 2 is Forest 3. Southeast of Clearing is Forest 2. Northwest of Forest 2 is nowhere. South of Forest 1 is west of Forest 3.

West of West of House is Forest 1. East of Forest 1 is Forest 4. North of Forest 1 is Forest 1. West of Forest 1 is Forest 1. The printed name of Forest 1 is "Forest". The description of Forest 1 is "This is a forest with trees in all directions around you."

Clearing has description "This is a clearing, with a forest surrounding you on the west and south." A pile of leaves is here.

The pile of leaves is inflammable.

The later appearance of the pile of leaves is "There is a pile of leaves on the ground."

The size of the leaves is 25.

The grating is a secret door. The grating is down from Clearing and up from Grating Room. The grating is closed, openable, locked, and lockable.

After taking or pushing or pulling the leaves for the first time:

say "Moving the pile of leaves reveals a grating.";

now the grating is revealed.

The attic stairs is a door. The attic stairs are open and not openable.The attic stairs is scenery.

A dark room called the Attic is up from the attic stairs. "This is the Attic. The only exit is stairs that lead down."

A rope called a large coil of rope is here. "A large coil of rope is in the corner." A square brick feeling like clay is here.

The brick is inflammable.

The later appearance of the square brick is "There is a square brick here which feels like clay."

The size of the rope is 10.

The size of the brick is 15.

A weapon called a nasty-looking knife is here. "On a table is a nasty-looking knife."

Understand "nasty knife" as the nasty-looking knife.

Down from the attic stairs is the Kitchen. Check climbing the attic stairs: try entering the noun instead.

The wooden door is a door. The wooden door is scenery. The wooden door is west of Living Room and east of Strange Passage. The wooden door is closed and not openable.

Down from the Living Room is a secret door called the trap door.

To say status of the trap door:

say "[if the trap door is open]an open[otherwise]a closed".

The trap door is up from the Cellar. Understand "trapdoor" and "trap-door" as the trap door.

After opening the trap door:

say "The door reluctantly opens to reveal a rickety staircase descending into darkness."

After closing the trap door:

say "The door swings shut and closes."

Exit found is a truth state variable. Exit found is false.

The rval of Cellar is 25.

After going through the trap door:

if exit found is false, shut the player in;

continue the action.

To shut the player in:

say "The trap door crashes shut, and you hear someone barring it.";

now the trap door is closed.

Check opening the trap door when the player is in the Cellar and exit found is false:

say "The trap door is locked from above." instead.

Check looking under the rug: say "There's a trap door under the rug." instead.

Check going through the closed trap door: say "The trap door is closed." instead.

Check taking the rug: say "The rug is too heavy to lift." instead.

After pushing or pulling the rug for the first time: say "With a great effort, the rug is moved to one side of the room. With the rug moved, the dusty cover of a closed trap door appears."; now the trap door is revealed.

After pushing or pulling the rug: say "Having moved the carpet previously, you find it impossible to move it again."

Southeast of Forest 2 is west of a room called Canyon View. South from Canyon View is east of Forest 5. The description of Canyon View is "You are at the top of the Great Canyon on its south wall. From here there is a marvelous view of the Canyon and parts of the Frigid River

upstream. Across the canyon, the walls of the White Cliffs still

appear to loom far above. Following the Canyon upstream (north and

northwest), Aragain Falls may be seen, complete with rainbow.

Fortunately, my vision is better than average and I can discern the

top of the Flood Control Dam #3 far to the distant north. To the

west and south can be seen an immense forest, stretching for miles

around. It is possible to climb down into the canyon from here."

Down from Canyon View is a room called Rocky Ledge. The description of Rocky Ledge is "You are on a ledge about halfway up the wall of the river canyon.

You can see from here that the main flow from Aragain Falls twists

along a passage which it is impossible to enter. Below you is the

canyon bottom. Above you is more cliff, which still appears

climbable."

Down from Rocky Ledge is a room called Canyon Bottom. The description of Canyon Bottom is "You are beneath the walls of the river canyon which may be climbable

here. There is a small stream here, which is the lesser part of the

runoff of Aragain Falls. To the north is a narrow path."

North of Canyon Bottom is southeast of a room called End of Rainbow. The description of End of Rainbow is "You are on a small, rocky beach on the continuation of the Frigid River past the Falls. The beach is narrow due to the presence of the White Cliffs. The river canyon opens here and sunlight shines in from above. A rainbow crosses over the falls to the west and a narrow path continues to the southeast."