Zork — 4 of 13

Part 3 - Cellar Area and Bank of Zork

A dungeon is a kind of room. A dungeon is usually dark.

The Cellar is a dungeon. The Cellar is west of a dungeon called Troll Room. "You are in a dark and damp cellar with a narrow passageway leading east, and a crawlway to the south. On the west is the bottom of a steep metal ramp which is unclimbable."

Check going west while the location is Cellar: say "You attempt to climb the ramp, but it is too slippery, and you slide back down." instead.

The description of Troll Room is "This is a small room with passages off in all directions. Bloodstains and deep scratches (perhaps made by an axe) mar the

walls."

A man called the Troll is in Troll Room. The initial appearance of the Troll is "[if the troll is consious]A nasty-looking troll, brandishing a bloody axe, blocks all passages out of the room.[otherwise]There is an unconsious troll here.[end if]".

Check going when the player can see the consious Troll:

if the noun is not west, say "The troll fends you off with a menacing gesture." instead;

else continue the action.

Check throwing something at the troll:

say "The troll, who is remarkably coordinated, catches [the noun] " instead;

if the noun is a weapon begin;

say "and being for the moment sated, throws it back. Fortunately, the troll has poor control, and the knife falls on the floor. He does not look pleased.";

move the noun to the location instead;

else;

say "and not having the most discriminating tastes, gleefully eats it.";

remove the noun from play instead;

end if.

The troll can be consious or unconsious.

Check attacking the unconsious troll with something:

say "The unconscious troll cannot defend himself: He dies.";

say "Almost as soon as the troll breathes his last breath, a cloud

of sinister black fog envelops him, and when the fog lifts, the

carcass has disappeared.";

remove the troll from play instead.

West of a dungeon called West of Chasm is south of Cellar. "You are on the west edge of a chasm, the bottom of which cannot be seen. The east side is sheer rock, providing no exits. A narrow passage goes west. The path you are on continues to the north and south."

Check going down from West of Chasm: say "The chasm probably leads directly to the infernal regions." instead.

Check jumping while the location is West of Chasm: fatally leap instead.

A dungeon called Gallery is south of West of Chasm. "This is an art gallery. Most of the paintings which were here have been stolen by vandals with exceptional taste. The vandals left through the north, south, or west exits."

A painting is here. "Fortunately, there is still one chance for you to be a vandal, for on the far wall is a work of unparalleled beauty."

The printed name of the painting is "masterpiece by a neglected genius".

Understand "masterpiece" as the painting. The painting is inflammable.

After taking the painting for the first time: award 4 points; continue the action.

The painting has case-points 7.

The size of the painting is 15.

A worthless piece of canvas is a thing.

Check destroying the painting:

say "Congratulations! Unlike the other vandals, who merely stole the

artist's masterpieces, you have destroyed one."; now the player has the worthless piece of canvas; remove the painting from play instead.

Check destroying the painting with something:

say "Congratulations! Unlike the other vandals, who merely stole the

artist's masterpieces, you have destroyed one."; now the player has the worthless piece of canvas; remove the painting from play instead.

To strike a blow at the player:

let x be a random number between 1 and 6;

if x is 1 or x is 2 begin;

say "[one of]The troll swings his axe, but it misses.[or]The troll's axe barely misses your ear.[or]The axe sweeps past as you jump aside.[or]The axe crashes against the rock, throwing sparks![at random]";

else if x is 3;

say "The troll's axe removes your head.";

end the game in death;

else if x is 4 or x is 5;

say "[one of]The troll hits you with a glancing blow, and you are momentarily

stunned.[or]An axe stroke makes a deep wound in your leg.[or]The troll's axe swings down, gashing your shoulder.[at random]";

increase the wounds of the player by 1;

else if x is 6;

say "[one of]You stagger back under a hail of axe strokes.[or]The troll's mighty blow drops you to your knees.[or]The troll swings; the blade turns on your armor but crashes

broadside into your head.[at random]";

increase the wounds of the player by 2;

end if.

Carry out attacking the troll with something:

if a random chance of 1 in 2 succeeds begin;

if the second noun is the sword begin;

say "[one of]Your sword crashes down, knocking the troll into dreamland.[or]The troll is battered into unconsciousness.[or] A furious exchange, and the troll is knocked out![at random]";

else;

say "[one of]The haft of your knife knocks out the troll.[or]The troll drops to the floor, unconscious.[or]The troll is knocked out![at random]";

end if;

now the troll is unconsious;

else if a random chance of 1 in 2 succeeds;

if the second noun is the sword begin;

say "[one of]The troll receives a deep gash in his side.[or]A savage blow on the thigh! The troll is stunned but can still fight![or]Slash! Your blow lands! That one hit an artery, it could be serious![at random]";

else;

say "[one of]The troll receives a deep gash in his side.[or]A savage cut on the leg stuns the troll, but he can still fight![or]Slash! Your stroke connects! The troll could be in serious trouble![at random]";

increase the wounds of the troll by 2;

end if;

else;

say "A good stroke, but it's too slow, the troll dodges.";

end if;

The troll has a number called wounds.

Every turn when the troll is on-stage:

if the wounds of the troll is greater than 4 begin;

say "The troll takes a final blow and slumps to the floor, dead.";

say "Almost as soon as the troll breathes his last breath, a cloud

of sinister black fog envelops him, and when the fog lifts, the

carcass has disappeared.";

remove the troll from play;

end if.

Every turn when the player can see the consious troll:

strike a blow at the player.

Every turn when the troll is unconsious and the troll is on-stage and the player cannot see the troll:

now the troll is consious.

South of Gallery is northwest of a dungeon called Studio. The description of Studio is "This is what appears to have been an artist's studio. The walls and floors are splattered with paints of 69 different colors. Strangely enough, nothing of value is hanging here. At the north and northwest of the room are open doors (also covered with paint). An extremely dark and narrow chimney leads up from a fireplace. Although you might be able to get up the chimney, it seems unlikely that you could get back down."

The chimney is a door. The chimney is open and not openable. Check climbing the chimney: try entering the noun instead. The chimney is scenery. The chimney is up from Studio and down from Kitchen.

Check going through the chimney when the player is carrying more than 2 things:

say "The chimney is too narrow for you and your baggage." instead.

Check going through the chimney while the location is Kitchen:

say "Only Santa Claus climbs down chimneys." instead.

Check going through the chimney when the player is not carrying anything:

say "Going up empty-handed is a bad idea." instead.

South of a dungeon called Bank Entrance is west of Gallery.

"This is the large entrance hall of the Bank of Zork, the largest banking institution of the Great Underground Empire. A partial account of its history is in 'The Lives of the Twelve Flatheads' with the chapter on J. Pierpont Flathead. A more detailed history (albeit less objective) may be found in Flathead's outrageous autobiography 'I'm Rich and You Aren't -- So There!'

Most of the furniture has been ravaged by passing scavengers. All that

remains are two signs at the northwest and northeast corners of the room, which say

[paragraph break]

[fixed letter spacing]

<-- WEST VIEWING ROOM EAST VIEWING ROOM -->

[variable letter spacing]".

Northwest of Bank Entrance is south of a dungeon called West Teller's Room. The description of West Teller's Room is "This is a small square room, which was used by a bank officer whose job it was to retrieve safety deposit boxes for the customer. On the north side of the room is a sign which reads 'Viewing Room'. On the west side of the room, above an open door, is a sign reading [paragraph break]

[fixed letter spacing]

BANK PERSONNEL ONLY [variable letter spacing]".

Northeast of Bank Entrance is south of a dungeon called East Teller's Room. The description of East Teller's Room is "This is a small square room, which was used by a bank officer whose job it was to retrieve safety deposit boxes for the customer. On the north side of the room is a sign which reads 'Viewing Room'. On the east side of the room, above an open door, is a sign reading [paragraph break]

[fixed letter spacing]

BANK PERSONNEL ONLY [variable letter spacing]".

North of West Teller's Room is a dungeon called Viewing Room. The description of Viewing Room is "This is a room used by holders of safety deposit boxes to view their contents. On the north side of the room is a sign which says [paragraph break][sign text]".

To say sign text:

center "REMAIN HERE WHILE THE BANK OFFICER RETRIEVES YOUR DEPOSIT BOX";

center "WHEN YOU ARE FINISHED, LEAVE THE BOX, AND EXIT TO THE SOUTH";

center "AN ADVANCED PROTECTIVE DEVICE PREVENTS ALL CUSTOMERS FROM";

center "REMOVING ANY SAFETY DEPOSIT BOX FROM THIS VIEWING AREA!";

center "Thank you for banking at the Zork!".

South of Viewing Room is Bank Entrance.

North of East Teller's Room is Viewing Room.

North of Bank Entrance is nowhere.

East of East Teller's Room is a east of a lighted dungeon called Safety Depository.

West of West Teller's Room is a west of Safety Depository.

The description of Safety Depository is "This is a large rectangular room. The east and west walls here were used for storing safety deposit boxes. As might be expected, all have been carefully removed by evil persons. The northern 'wall' of the room is a shimmering curtain of light. To the east, west, and south of the room are large doorways."

A large stone cube is here. "In the center of the room is a large stone cube, about 10 feet on a side. Engraved on the side of the cube is some lettering." Understand "vault" as the cube. The cube is fixed in place.

A dungeon called Chairman's Office is south of Safety Depository. "This room was the office of the Chairman of the Bank of Zork. Like the other rooms here, it has been extensively vandalized. The lone exit is to the north."

A portrait is here. "A portrait of J. Pierpont Flathead hangs on the wall." Understand "painting" as the portrait. The printed name of the portrait is "portrait of J. Pierpont Flathead".

The description of the portrait is "[flathead]".

Gnome flag is a truth state that varies. Gnome flag is usually true.

The curtain of light is a thing in the Safety Depository. The curtain is scenery. Understand "north" and "wall" as the curtain.

Small Room is a dark room. The description of Small Room is "This is a small bare room with no distinguishing features. There are no exits from this room."

Vault is a dark room. The description of Vault is "This is the Vault of the Bank of Zork, in which there are no doors."

A stack of zorkmid bills is here. "On the floor sit 200 neatly stacked zorkmid bills." Understand "notes" or "banknotes" or "bank notes" as the bills. The description of the bills is "[banknotes]".

The stack of bills is inflammable.

After taking the portrait for the first time: award 11 points; continue the action.

After taking the bills for the first time: award 10 points; continue the action.

The case-points of the portrait is 5.

The case-points of the bills is 15.

The size of the bills is 10.

The size of the portrait is 25.

The portrait is inflammable.

Check going east when the player is in Safety Depository and the player has the portrait: say "The alarm sounds briefly, and an invisible force prevents your from leaving." instead.

Check going west when the player is in Safety Depository and the player has the portrait: say "The alarm sounds briefly, and an invisible force prevents your from leaving." instead.

Check going east when the player is in Safety Depository and the player has the bills: say "The alarm sounds briefly, and an invisible force prevents your from leaving." instead.

Check going west when the player is in Safety Depository and the player has the bills: say "The alarm sounds briefly, and an invisible force prevents your from leaving." instead.

Instead of touching, taking, pushing, pulling, or rubbing the curtain: say "As you attempt this feat, your hand goes through the curtain."

Check entering the curtain:

say "You feel somewhat disoriented as you pass through.";

if the former location is West Teller's Room, move the player to Viewing Room instead;

if the former location is East Teller's Room, move the player to Viewing Room instead;

if the former location is Small Room, move the player to Vault instead;

if the former location is Vault or the former location is Chairman's Office, move the player to Small Room instead.

Understand "NORTH WALL" and "NORTHERN WALL" as the curtain.

The Gnome of Zurich is a man. The description of the Gnome of Zurich is "This is an epicene Gnome of Zurich, wearing a three-piece suit and carrying a safety deposit box."

Giving something to the Gnome of Zurich is paying the gnome. Throwing something at the Gnome of Zurich is paying the gnome.

Instead of paying the gnome:

if the case-points of the noun is not 0 begin;

say "The gnome carefully places the [noun] in the deposit box. 'Let me show you the way out,' he says, making it clear that he will be pleased to see the last of you. Then, you are momentarily disoriented, and when you recover, you are back at the Bank Entrance.";

remove the noun from play;

remove the Gnome of Zurich from play;

move the player to Bank Entrance;

else;

say "'I wouldn't put THAT in a safety deposit box,' remarks the gnome with disdain, tossing it over his shoulder, where it disappears with an understated 'pop'.";

remove the noun from play;

end if.

Check attacking the Gnome of Zurich: say "The gnome says, 'Well, I never!' and disappears with a snap of his fingers, leaving you alone." instead.

Check attacking the Gnome of Zurich with something: say "The gnome says, 'Well, I never!' and disappears with a snap of his fingers, leaving you alone." instead.

Check throwing something at the curtain:

say "The curtain dims slightly as the [noun] passes through it.";

if the former location is West Teller's Room, move the noun to Viewing Room instead;

if the former location is East Teller's Room, move the noun to Viewing Room instead;

if the former location is Small Room, move the noun to Vault instead;

if the former location is Vault, move the noun to Small Room instead;

if the former location is Chairman's Office, move the noun to Small Room instead.

The south wall is a thing in Small Room. The south wall is scenery.

Check entering the south wall: say "You feel somewhat disoriented as you pass through."; now the former location is the location; move the player to Safety Depository instead.

Understand "southern wall" as the south wall.

The north wall is a thing in Vault. The north wall is scenery.

Check entering the north wall: say "You feel somewhat disoriented as you pass through."; now the former location is the location; move the player to Safety Depository instead.

To say pizza:

say "Your way is blocked by debris from an explosion.";

move the player to the former location;

Check throwing something at the north wall:

say "The [noun] goes through." instead.

Check throwing something at the south wall:

say "The [noun] goes through." instead.

Understand "NORTHERN WALL" as the north wall.

Does the player mean doing something to the curtain: it is very likely.

Does the player mean doing something to the north wall: it is very likely.

Does the player mean doing something to the south wall: it is very likely.

Instead of touching, taking, pushing, pulling, or rubbing the north wall: say "As you attempt this feat, your hand goes through the wall."

Instead of touching, taking, pushing, pulling, or rubbing the south wall: say "As you attempt this feat, your hand goes through the wall."

A dungeon called North-South Crawlway is north of Studio. "This is a north-south crawlway; a passage also goes to the east. There is a hole above, but it provides no opportunities for climbing." North of North-South Crawlway is north of West of Chasm. East of North-South Crawlway is east of Troll Room.

Check going up while the location is North-South Crawlway: say "Not even a human fly could get up it." instead.