Zork — 2 of 13

Part 1 - New Actions and Concepts

A room has a number called rval. The rval of a room is usually 0.

The story genre is "Fantasy".

The story headline is "A Computerized Fantasy Simulation Game".

The release number is 4.

The story creation year is 1979.

Use the serial comma.

A thing can be non-flaming or flaming. A thing is usually non-flaming. A thing can be non-inflammable or inflammable. A thing is usually non-inflammable.

[1]

Release along with the source text and a website.

Digging into it with is an action applying to one thing and one carried thing.

Understand "dig into/in [something] with/using [something]" as digging into it with.

Understand "dig [something] with/using [something]" as digging into it with.

Understand "dig with/using [something] into/in [something]" as digging into it with (with nouns reversed).

Counting is an action applying to one visible thing. Understand "count [something]" as counting.

Check counting:

if the noun is the pile of leaves, say "There are 69,105 leaves here." instead;

[2]

[3]

if the noun is the pair of candles, say "Let's see, how many objects in a pair? Don't tell me, I'll get it." instead;

if the noun is the bills, say "Don't you trust me? There are 200 bills." instead;

if the noun is the matchbook begin;

if match count is 1 begin;

say "You have one match.";

else if match count is 0;

say "You have no matches.";

else;

say "You have [match count] matches.";

end if;

end if.

Carry out counting:

say "You have lost your mind."

Understand "count blessings" as a mistake ("Well, for one, you are playing Zork....").

Understand "$COUNTREASURE" as a mistake ("Your adventure has netted [number of valuble things in the trophy case] treasure[s]. You are carrying [number of valuble things had by the player] valuble[s].")

Check digging into it with:

if the noun is not the guano and the noun is not the ground, say "Digging into [a noun] is silly." instead;

if the second noun is not the shovel, say "Digging with [the second noun] is slow and tedious." instead;

if the noun is the ground and the player is not in Sandy Beach, say "The ground is too hard for digging here.".

Playing is an action applying to one carried thing.

Understand "play [something]" as playing.

Exorcising is an action applying to nothing. Understand "exorcise" as exorcising.

Check exorcising:

if exorcism flag is not -1, say "You must perform the ceremony." instead.

Carry out exorcising:

say "There is a clap of thunder, and a voice echoes through the cavern: 'Begone, chomper!' Apparently, the voice thinks you are an evil spirit and dismisses you from the land of the living.";

end the game in death.

Definition: a thing is valuble if the case-points of it is not 0.

After reading a command:

if the player's command includes "COUNT TREASURE/TREASURES/VALUBLES", replace the matched text with "$COUNTREASURE".

Check playing:

if the noun is the violin, say "An amazing offensive noise issues from the violin." instead;

say "That makes no sense." instead.

Before playing a person who is not the player:

say "You are so completely engrossed in the role of [the noun] that you kill yourself, just as he would have done.";

end the game in death.

Playing it with is an action applying to two carried things. Understand "play [something] with [something]" as playing it with.

Check playing it with:

if the noun is not the violin, say "That makes no sense." instead;

if the second noun is not a weapon, say "An amazing offensive noise issues from the violin." instead;

say "Very good. The violin is now worthless.";

now the case-points of the violin are 0.

Putting it under is an action applying to one carried thing and one thing. Understand "put [something] under [something]" and "place [something] under [something]" and "slide [something] under [something]" as putting it under.

Check putting it under:

if the second noun is not a door, say "You can't do that." instead;

if the second noun is not the massive wooden door, say "There's not enough room under this door." instead;

if the noun is the green piece of paper or the noun is the tan label or the noun is the leaflet begin;

say "The paper is very small and vanishes under the door.";

move the noun to the other side of the second noun instead;

end if;

if the noun is not the mat, say "You can't do that." instead;

if mat under is true, say "Look around." instead.

Carry out putting it under:

say "The mat fits easily under the door.";

move the mat to the location;

Geronimoing is an action applying to nothing. Understand "geronimo" as geronimoing.

Check geronimoing:

if the player is not inside the barrel, say "Wasn't he an Indian?".

Carry out geronimoing:

say "I didn't think you would REALLY try to go over the falls in a

barrel. It seems that some 450 feet below, you were met by a number

of unfriendly rocks and boulders, causing your immediate demise. Is

this what 'over a barrel' means?";

end the game in death.

Check digging into the guano with the shovel for the first time:

say "You are digging into a pile of bat guano." instead.

Check digging into the guano with the shovel for the second time:

say "You seem to be getting knee deep in guano." instead.

Check digging into the guano with the shovel for the third time:

say "You are covered with bat turds, cretin." instead.

Check digging into the guano with the shovel more than 3 times:

say "This is getting nowhere." instead.

Check digging into the ground with the shovel when the player is in Sandy Beach for the first time:

say "You seem to be digging a hole here." instead.

Check digging into the ground with the shovel when the player is in Sandy Beach for the second time:

say "The hole is getting deeper, but that's about it." instead.

Check digging into the ground with the shovel when the player is in Sandy Beach for the third time:

say "You are surrounded by a wall of sand on all sides." instead.

Check digging into the ground with the shovel when the player is in Sandy Beach the fourth time:

say "You can see a small statue here in the sand.";

move the statue to Sandy Beach instead.

Check digging into the ground with the shovel when the player is in Sandy Beach more than 4 times:

say "The hole collapses, smothering you.";

end the game in death instead.

The ground is a backdrop. The ground is everywhere. Understand "sand" and "earth" and "here" and "hole" as the ground.

The description of yourself is "That's difficult unless your eyes are prehensile.".

Launching is an action applying to nothing. Understand "launch" as launching.

Check launching:

if the player is not in the magic boat and the player is not in the basket, say "You need to be in a vehicle to do that." instead.

Landing is an action applying to nothing. Understand "land" as landing.

Check landing:

if the player is not in the magic boat and the player is not in the basket, say "You need to be in a vehicle to do that.".

Carry out landing:

if the player is in the magic boat begin;

if the magic boat is in In Stream begin;

move the magic boat to Stream View;

try looking instead;

else if the magic boat is in Reservoir;

say "You must specify a direction." instead;

else if the magic boat is in River1;

move the magic boat to Dam Base;

try looking instead;

else if the magic boat is in River2;

say "The White Cliffs prevent your landing here." instead;

else if the magic boat is in River3 or the magic boat is in River4;

say "You must specify which direction here." instead;

else if the magic boat is in River5;

move the magic boat to Dam Base;

try looking instead;

end if;

else if the player is in the basket;

if the basket is in Volcano Near Small Ledge begin;

move the basket to Narrow Ledge;

try looking instead;

else if the basket is in Volcano Near Viewing Ledge;

say "The ledge is too narrow to land on." instead;

else if the basket is in Volcano Near WideLedge;

if the rusty old box is open, say "The ledge has collapsed and cannot be landed on." instead;

move the basket to Wide Ledge;

try looking instead;

end if;

end if;

say "You cannot land from here." instead.

Carry out launching:

if the player is in the magic boat begin;

if the magic boat is in Stream View begin;

move the magic boat to In Stream;

try looking instead;

else if the magic boat is in Dam Base;

move the magic boat to River1;

try looking instead;

else if the magic boat is in Reservoir South or the magic boat is in Reservoir North and the pdl1 is on-stage;

move the magic boat to Reservoir;

try looking instead;

else if the magic boat is in Rocky Shore or the magic boat is in WCLF1;

move the magic boat to River3;

try looking instead;

else if the magic boat is in WCLF2 or the magic boat is in Sandy Beach;

move the magic boat to River4;

try looking instead;

else if the magic boat is in Shore;

move the magic boat to River5;

try looking instead;

end if;

else if the player is in the basket;

if the braided wire is attached to a nonrope thing (called the tied object), now the braided wire is not attached to the tied object;

if the basket is in Narrow Ledge begin;

move the basket to Volcano Near Small Ledge;

try looking instead;

else if the basket is in Wide Ledge;

move the basket to Volcano Near WideLedge;

try looking instead;

end if;

end if;

say "You can't launch from here." instead.

Deflating is an action applying to one thing. Understand "deflate [something]" as deflating.

Check deflating:

if the noun is not the boat, say "How to you expect to do that?" instead;

if the player is in the boat, say "You can't deflate the boat while you're in it." instead;

if the player is carrying the boat, say "The boat must be on the ground to be deflated." instead.

Carry out deflating the boat:

say "The boat deflates.";

move the pile of plastic to the holder of the boat;

remove the boat from play.

Understand "brush teeth" as a mistake ("Dental hygiene is highly recommended, but I'm not sure what you want to brush them with.").

Inflating it with is an action applying to one thing and one carried thing. Understand "inflate [something] with/using [something]" and "pump up [something] with/using [something]" as inflating it with.

Your lungs are a part of the player. Understand "mouth" and "breath" as your lungs.

Check inflating it with:

if the noun is not the dboat and the noun is not the pile of plastic and the noun is not the boat, say "How can you inflate that?";

if the noun is the dboat, say "This boat will not inflate since some moron put a hole in it." instead;

if the noun is the boat, say "Inflating it further would probably burst it." instead;

if the second noun is your lungs, say "You don't have enough lung power to inflate it." instead;

if the second noun is not the air-pump, say "You don't have enough lung power to inflate it." instead;

if the player is carrying the noun, say "You cannot inflate it while carrying it." instead.

Inflating is an action applying to one thing. Understand "pump up [something]" and "inflate [something]" as inflating.

Check inflating:

if the player can see the air-pump, try inflating the noun with the air-pump instead;

else say "I don't really see how."

Brushing is an action applying to one carried thing. Understand "brush teeth with [something]" as brushing.

Check brushing:

if the noun is not the viscous material, say "Nice try, but with [a noun]?" instead.

Carry out brushing:

say "Well, you seem to have been brushing your teeth with some sort of

glue. As a result, your mouth gets glued together (with your nose)

and you die of respiratory failure.";

end the game in death.

Lubricating it with is an action applying to one thing and one carried thing. Understand "lubricate [something] with something" as lubricating it with. Understand "oil [something] with something" as lubricating it with. Understand "grease [something] with [something]" as lubricating it with.

Plugging it with is an action applying to one thing and one carried thing. Understand "plug [something] with [something]" and "glue [something] with [something]" and "patch [something] with [something]" as plugging it with.

Check plugging it with:

if the second noun is not the viscous material, say "That makes no sense." instead;

if the noun is not the leak2 and the noun is not the dboat, say "That makes no sense." instead.

Check lubricating it with:

if the second noun is not the viscous material, say "You probably put spinach in your gas tank, too." instead;

if the noun is not the bolt, say "That's not very useful." instead.

Turning it with is an action applying to one thing and one carried thing. Understand "turn [something] with [something]" as turning it with.

Understand "flip [something] with [something]" as turning it with.

Check turning it with:

if the noun is not the bolt and the noun is not the switch, try turning the noun instead.

Check throwing something at the player:

say "A terrific throw! [The noun] hits you squarely in the head. Normally, this

wouldn't do much damage, but by incredible mischance, you fall over backwards

trying to duck, and break your neck, justice being swift and merciful in the

Great Underground Empire.";

end the game in death instead.

Wishing is an action applying to nothing. Understand "wish" and "make wish" and "make a wish" as wishing.

Understand "$VERIFY" as verifying the story file.

Carry out wishing:

if the player is in Top of Well or the player is in Circular Room and the player is holding the bag of coins begin;

say "A whispering voice replies, 'Water makes the bucket go.'

Unfortunately, wishing makes the coins go...";

remove the bag of coins from play;

else;

say "No one is listening.";

end if.

A room can be indoors or outdoors. A room is usually indoors.

Understand "wall" as a direction when the location is indoors.

Understand "cretin" as yourself.

The former location is a room that varies.

First carry out going rule:

now the former location is the location.

Use the serial comma.

Include Basic Help Menu by Emily Short.

Include Punctuation Removal by Emily Short.

Before swearing obscenely:

say "[one of]Such language in a high-class establishment like this![or]Oh, dear. Such language from a supposedly winning adventurer![or]You ought to be ashamed of yourself.[or]It's not so bad. You could have been killed already.[or]Tough shit, asshole.[at random]" instead.

After reading a command:

remove stray punctuation;

if the player's command includes "&", replace the matched text with "and".

Understand "gdt" as a mistake ("If you want to debug the game, use the standard Inform debugging verbs.").

Understand "noobj" as a mistake ("In the MDL sources, NOOBJ is described as a 'hack'. As we are above such practices, NOOBJ is not implemented.").

Reading it through is an action applying to two things. Understand "examine [something] in [something]" as reading it through. Understand "examine [something] through [something]" as reading it through.

Understand "read [something] in [something]" as reading it through. Understand "read [something] through [something]" as reading it through.

Check reading it through:

if the second noun is the flask and the noun is the red cake begin;

say "The icing, now visible, says 'Evaporate'.";

else if the second noun is the flask and the noun is the blue cake;

say "The icing, now visible, says 'Enlarge'.";

else if the second noun is the flask and the noun is the orange cake;

say "The icing, now visible, says 'Explode'.";

else if the second noun is not transparent and the second noun is not the flask;

say "How does one look through [a second noun]?" instead;

else if the second noun is the bottle;

if the noun is the red cake or the noun is the blue cake or the noun is the orange cake begin;

say "The letters appear larger but are still too small to read.";

end if;

else;

try examining the noun instead;

end if.

Understand "board [something]" as entering.

Understand "disembark" as exiting.

Understand "climb [direction]" as going.

Understand "light [electric lamp]" as switching on.

Understand "extinguish [something]" as switching off.

Understand "douse [electric lamp]" as switching off.

Understand "climb through [something]" as climbing.

Understand "what is [something]" as examining.

Understand "mumble" and "sigh" as a mistake ("You'll have to speak up if you want me to hear you.").

Understand "repent" as a mistake ("It may well be too late.").

Ringing is an action applying to one carried thing. Understand "ring [something]" as ringing.

Check ringing:

if the noun is not a bell, say "How, exactly, do you ring that?" instead.

Carry out ringing:

say "Ding Dong."

A bell is a kind of thing.

Your bare hands are a part of the player.

Understand the command "stab" as "attack".

The better attacking rule is listed instead of the block attacking rule in the check attacking rulebook.

This is the better attacking rule:

if dead flag is true, say "All such attacks are vain in your position." instead;

if the player is carrying a weapon (called the blade), try attacking the noun with the blade instead;

if the noun is the player begin;

say "If you insist... Poof, you're dead!";

end the game in death instead;

end if;

say "You'll have to say with what you want to attack [the noun].".

Poking is an action applying to one visible thing. Understand "poke [something]" and "blind [something]" as poking.

Check poking:

if the noun is not the Cyclops, try attacking the noun instead.

Carry out poking: say "'Do you think I'm as stupid as my father?' he says, dodging."

When play begins:

move the thief to Round Room;

choose row 1 in Table of Basic Help Options;

now description entry is "Welcome to Zork![paragraph break] You are near a large dungeon, which is reputed to contain vast quantities of treasure. Naturally, you wish to acquire some of it. In order to do so, you must of course remove it from the dungeon. To receive full credit for it, you must deposit it safely in the trophy case in the living room of the house.[paragraph break] In addition to valuables, the dungeon contains various objects which may or may not be useful in your attempt to get rich. You may need sources of light, since dungeons are often dark, and weapons, since dungeons often have unfriendly things wandering about. Reading material is scattered around the dungeon as well; some of it

is rumored to be useful.[paragraph break] To determine how successful you have been, a score is kept. When you find a valuable object and pick it up, you receive a certain number of points, which depends on the difficulty of finding the object. You receive extra points for transporting the treasure

safely to the living room and placing it in the trophy case. In addition, some particularly interesting rooms have a value associated with visiting them. The only penalty is for getting yourself killed, which you may do only twice.[paragraph break] Of special note is a thief (always carrying a large bag) who likes to wander around in the dungeon (he has never been seen by the light of day). He likes to take things. Since he steals for pleasure rather than profit and is somewhat sadistic, he only takes things which you have seen. Although he prefers valuables, sometimes in his haste

he may take something which is worthless. From time to time, he examines his take and discards objects which he doesn't like. He may occasionally stop in a room you are visiting, but more often he just wanders through and rips you off (he is a skilled pickpocket).".

Rule for deciding whether all includes the quantity of water: if the quantity of water is in the bottle, it does not; else it does.

Rule for deciding whether all includes things which are fixed in place: it does not.

Understand "bye" and "goodbye" as quitting the game.

Understand "WIN" and "WINNAGE" as a mistake ("Naturally!").

Understand "LOSE" and "CHOMP" as a mistake ("I don't know how to do that: I win in all cases.").

Understand "foo" and "bar" and "bletch" as a mistake ("Oh yeah, well FOO, BAR, and BLETCH to you too.").

Understand "PLUGH" and "XYZZY" as a mistake ("A hollow voice says 'Fool'.").

Understand "back" and "go back" as a mistake ("He who puts his hand to the plow and looks back is not fit for the kingdom of winners. In any case, 'BACK' doesn't work.").

Odysseusing is an action applying to nothing. Understand "ODYSSEUS" and "ULYSSES" as Odysseusing. Carry out odysseusing: say "Wasn't he a sailor?".

Understand "ZORK" and "DUNGEON" as a mistake ("At your service!").

Swimming is an action applying to nothing. Understand "SWIM" as swimming.

Carry out swimming:

if the player can see a watersource begin;

say "Swimming is not allowed in this dungeon.";

else;

say "I think swimming is best accomplished in water.";

end if.

Understand "water" as a watersource.

Understand "bug" as a mistake ("It's not a bug, its a feature.").

Understand "feature" as a mistake ("That's right.").

Finding is an action applying to one visible thing. Understand "find [something]" as finding. Understand "locate [something]" as finding. Understand "where is [something]" as finding.

Check finding:

if the noun is the player, say "You're around here somewhere..." instead;

if the noun is the white house, say "It's right here! Are you blind or something?" instead;

if the noun is your hands, say "Within six feet of your head, assuming you haven't left that somewhere." instead;

if the noun is the lurking grue, say "There is no grue here, but I'm sure there is at least one lurking in the darkness nearby. I wouldn't let my light go out if I were you!" instead.

Carry out finding:

say "It's right here."

The better drinking rule is listed instead of the block drinking rule in the check drinking rulebook.

This is the better drinking rule:

if the noun is the quantity of water begin;

say "Thank you very much -- I was very thirsty (probably from all this talking).";

remove the noun from play;

else if the noun is the water;

say "Thank you very much -- I was very thirsty (probably from all this talking).";

else;

say "I don't think [the noun] would agree with you." instead;

end if.

Greeting is an action applying to nothing. Understand "hello" and "hi" and "greetings" as greeting. Carry out greeting: say "[one of]Hello[or]Good day[or]Nice weather we've been having lately[or]Goodbye[at random]."

Praying is an action applying to nothing. Understand "pray" as praying.

Check praying:

if the player is not in Altar and dead flag is true, say "Your prayers are not heard." instead;

if the player is not in Altar, say "If you pray enough, your prayers may be answered." instead.

Carry out praying:

if dead flag is true, say "From the distance the sound of a lone trumpet is heard. The room becomes very bright, and you feel disembodied. In a moment, the brightness fades, and you find yourself rising, as if from a long sleep, deep in the woods. In the distance you can faintly hear a song bird and the sounds of the forest.";

now the player is unlit;

now exit found is true;

move the player to Forest 1.

A secret door is a kind of door.

A secret door can be revealed or unrevealed.

A secret door is unrevealed.

A secret door is scenery.

A secret door is closed.

A secret switch is a kind of thing.

A secret switch can be revealed or unrevealed.

A secret switch is unrevealed.

A secret switch is scenery.

To print the you can't go message:

say the can't go that way rule response (A).

To print the you can't see message:

say "You can't see it.".

Rule for printing the description of a dark room: say "It is pitch black. You are likely to be eaten by a grue." instead.

Rule for printing a refusal to act in the dark: say "It is too dark in here to see." instead.

Before going through a secret door which is unrevealed:

print the you can't go message instead.

Before doing something to a secret door which is unrevealed:

print the you can't see message instead.

Before doing something when a secret door is the second noun and the second noun is unrevealed:

print the you can't see message instead.

Before doing something to a secret switch which is unrevealed:

print the you can't see message instead.

A thing has a number called case-points. The case-points of a thing is usually 0.

After inserting a thing (called the treasure) into the trophy case:

award case-points of the treasure points;

continue the action.

The taking action has an object called the place taken from (matched

as "from").

Setting action variables for taking:

now the place taken from is the holder of the noun.

After taking a thing (called the treasure) from the trophy case:

award zero minus case-points of the treasure points;

continue the action.

To say banknotes:

say line break;

say fixed letter spacing;

say " _______________________________________________________________[line break]";

say "| 1 0 0 GREAT UNDERGROUND EMPIRE 1 0 0 |[line break]";

say "| 1 0 0 0 0 1 0 0 0 0 |[line break]";

say "| 1 0 0 0 0 1 0 0 0 0 |[line break]";

say "| 1 0 0 DIMWIT 1 0 0 |[line break]";

say "| |||||||||||||||| |[line break]";

say "| || __ __ || B30332744D |[line break]";

say "| || -OO OO- || |[line break]";

say "| IN FROBS [unicode 92]|| >> ||/ WE TRUST |[line break]";

say "| || ______ || |[line break]";

say "| B30332744D | ------ | |[line break]";

say "| [unicode 92][unicode 92]________// |[line break]";

say "| 1 0 0 Series FLATHEAD LD Flathead 1 0 0 |[line break]";

say "| 1 0 0 0 0 719GUE Treasurer 1 0 0 0 0 |[line break]";

say "| 1 0 0 0 0 1 0 0 0 0 |[line break]";

say "| 1 0 0 One Hundred Royal Zorkmids 1 0 0 |[line break]";

say "|_______________________________________________________________|[line break][variable letter spacing]".

To say flathead:

say fixed letter spacing;

say " |||||||||||||| [line break]";

say " || __ __ || [line break]";

say " || $$ $$ || [line break]";

say " [unicode 92]|| >> ||/ [line break]";

say " || ________ || [line break]";

say " | -//----- | [line break]";

say " [unicode 92][unicode 92]_//_______// [line

break]";

say " ___// | | [line break]";

say " /__// | | [line break]";

say " | | [line break]";

say " __________// [unicode 92][unicode 92]__________

[line break]";

say " / $ / **** [unicode 92] $ [unicode 92]

[line break]";

say " / / ** [unicode 92] [unicode 92]

[line break]";

say " / /| ** |[unicode 92] [unicode 92]

[line break]";

say " / / | ** | [unicode 92] [unicode 92]

[line break]";

say " / / | ** | [unicode 92] [unicode 92]

[line break]";

say " ^ ^__|______$Z$**$Z$______|__^ ^ [line break]";

say " [unicode 92] * $Z$**$Z$ * / [line

break]";

say " [unicode 92]________*___$Z$**$ Z$___*________/ [line

break]";

say " | $Z$**$Z$ | [line break]";

say " J PIERPONT FLATHEAD [line break]";

say " CHAIRMAN[line break]";

say variable letter spacing.

Rotation speed is a number that varies. Rotation speed is usually 1.

Rotation room is a number that varies. Rotation room is usually 1.

The going action has a number called the dark terminus count.

Setting action variables for going:

now the dark terminus count is 0;

if in darkness, increase the dark terminus count by 1.

The last carry out going rule:

if in darkness, increase the dark terminus count by 1.

After going:

if the dark terminus count is 2, set off the grues instead;

if the coil of rope is attached to something (called the item) and the player is carrying the coil of rope, now the coil of rope is not attached to the item;

continue the action.

To set off the grues:

say "Oh no! You walked directly into the slavering fangs of a lurking grue!";

end the game in death.

[Procedural rule when inflating something that is part of the player:

ignore the carrying requirements rule.]

The part of player aware carrying requirements rule is listed instead of the carrying requirements rule in the action-processing rules.

This is the part of player aware carrying requirements rule:

if inflating something that is part of the player

or attacking something that is part of the player

or brushing something which is part of the player

or destroying something with something which is part of the player:

continue the action;

otherwise:

follow the carrying requirements rule;

A weapon is a kind of thing.

Understand the command "swing" as something new.

Swinging it is an action applying to one carried thing. Understand "swing [something]" as swinging it.

Carry out swinging it:

if dead flag is true, say "All such attacks are vain in your position." instead;

if the player can see a person (called the villain) who is not the player, try attacking the villain with the noun instead;

say "Please specify at what do you wish to swing the [noun]."

[Procedural rule while attacking something that is part of the player: ignore the carrying requirements rule.

Procedural rule while brushing something which is part of the player: ignore the carrying requirements rule.

Procedural rule while destroying something with something which is part of the player: ignore the carrying requirements rule.]

Attacking it with is an action applying to one visible thing and one carried thing.

Understand "attack [something] with [something]" as attacking it with.

Understand "attack [something] using [something]" as attacking it with.

Carry out attacking it with:

if dead flag is true, say "All such attacks are vain in your position." instead;

if the noun is the player begin;

say "If you insist... Poof, you're dead!";

end the game in death instead;

end if;

if the noun is not a person, say "I've known strange people, but attacking [a noun]?" instead;

if the second noun is not a weapon, say "Trying to kill [a noun] with only [a second noun] very self-destructive." instead.

The lurking grue is a backdrop. The lurking grue is everywhere.

The description of the lurking grue is "The grue is a sinister, lurking presence in the dark places of the earth. Its favorite diet is adventurers, but its insatiable appetite is tempered by its fear of light. No grue has ever been seen by the light of day, and few have survived its fearsome jaws to tell the tale."

Understand the commands "destroy", "break", "hit", and "smash" and "thump" as something new.

Destroying is an action applying to one visible thing.

Understand "destroy [something]" as destroying.

Understand "mangle [something]" as destroying.

Understand "mung [something]" as destroying.

Understand "break [something]" as destroying.

Understand "hit [something]" as destroying.

Understand "smash [something]" as destroying.

Understand "thump [something]" as destroying.

Carry out destroying:

if dead flag is true, say "All such attacks are vain in your position." instead;

if the noun is a person, try attacking the noun instead;

say "Trying to destroy [a noun] is not notably useful."

Destroying it with is an action applying to one visible thing and one carried thing. Understand "destroy [something] with [something]" as destroying it with.

Understand "mangle [something] with [something]" as destroying it with. Understand "mung [something] with [something]" as destroying it with . Understand "break [something] with [something]" as destroying it with. Understand "smash [something] with [something]" as destroying it with. Understand "swing [something] at [something]" as destroying it with (with nouns reversed).

Understand "mangle [something] using [something]" as destroying it with. Understand "mung [something] using [something]" as destroying it with . Understand "break [something] using [something]" as destroying it with. Understand "smash [something] using [something]" as destroying it with. Understand "thump [something] with something" as destroying it with. Understand "thump [something] using [something]" as destroying it with. Understand "destroy [something] using [something]" as destroying it with.

Carry out destroying it with:

if dead flag is true, say "All such attacks are vain in your position." instead;

if the noun is a person, try attacking the noun with the second noun instead;

say "Trying to destroy [a noun] is not notably useful."

Check searching a door:

say "[The noun] is [if open]open, but I can't see what's beyond it.[otherwise]closed.[end if]" instead.

Understand "frobozz" as a mistake ("The Frobozz Company, Ltd., created, owns, and operates this dungeon.").

Understand "schedule" as a mistake ("The dungeon is ALWAYS open (always room for one more).").

Understand "time" as a mistake ("You have been playing Zork for longer than you think.").

First after reading a command rule:

if the player's command matches "treasure", replace the player's command with "$treasure$".

Treasure-travelling is an action applying to nothing. Understand "$treasure$" as treasure-travelling. Check treasure-travelling: if the player is not in Temple, say "Nothing happens." instead.

Carry out treasure-travelling: move the player to Treasure Room.

Temple-travelling is an action applying to nothing. Understand "temple" as temple-travelling. Check temple-travelling: if the player is not in Treasure Room, say "Nothing happens." instead.

Carry out temple-travelling: move the player to Temple.

Hi-speaking is an action applying to one visible thing. Understand "hello [something]" and "hi [something]" as hi-speaking.

Check hi-speaking:

if the noun is the sailor, say "Nothing happens here." instead;

if the noun is the aviator, say "Here, nothing happens." instead;

if the noun is not a person, say "I think that only schizophrenics say 'Hello' to [a noun]." instead.

Carry out hi-speaking:

say "[The noun] bows his head to you in greeting."

Check asking someone to try greeting: try hi-speaking the noun instead.

The sailor is a backdrop. The sailor is everywhere.

The aviator is a backdrop. The aviator is everywhere. Understand "flyer" as the aviator.

Brochure flag is a number that varies. Brochure flag is usually 0.

Sending for is an action applying to one visible thing. Understand "send for [something]" as sending for. Understand "send [something]" as sending for.

Check sending for:

if the noun is not the obj1234, say "That doesn't make sends." instead.

Carry out sending for the obj1234:

if brochure flag is 0 begin;

say "OK, but you know the postal service...";

now brochure flag is 1;

else if brochure flag is 1;

say "It's probably on its way now.";

else if brochure flag is 2;

say "What, you mean you need another one?";

end if.

The obj1234 is a backdrop. The obj1234 is everywhere. Understand "brochure" and "free brochure" as the obj1234. The free brochure is a thing.

The free brochure is inflammable.

Instead of doing something other than sending for to the obj1234: print the you can't see message.

The description of the brochure is "[brochure text]".

Does the player mean sending for the obj1234: it is very likely.

Does the player mean doing something other than sending for to the free brochure: it is very likely.

To say brochure text:

say "The mailing label on this glossy brochure from MIT Tech reads [paragraph break]";

say " Intrepid Adventurer[line break]";

say " c/o Local Dungeon Master[line break]";

say " White House, GUE[line break]";

say "From the Introduction:[paragraph break]";

say "The brochure describes, for the edification of the prospective student, the stringent but wide-ranging curriculum of MIT Tech. Required courses are offered in Ambition, Distraction, Uglification, and Derision. The Humanities are not slighted at this institution, as the student may register for Reeling and Writhing, Mystery (Ancient and Modern), Seaography, and Drawling (which includes Stretching and Fainting in Coils). Advanced students are expected to learn Laughing and Grief.[paragraph break]";

say " William Barton Flathead, Founder[paragraph break]";

say "(The brochure continues in this vein for a few hundred more pages.)[line break]";

say "[if the Don Woods stamp is a part of the brochure]Affixed loosely to the brochure is a small stamp.[end if]".

The Don Woods stamp is a part of the brochure.

[Procedural rule when taking the Don Woods stamp:

ignore the can't take component parts rule.]

The conditional can't take component parts rule is listed instead of the can't take component parts rule in the check taking rulebook.

This is the conditional can't take component parts rule:

if taking the Don Woods stamp

or taking the coil of wire:

continue the action;

otherwise:

follow the can't take component parts rule;

The description of the Don Woods stamp is "[stamp text]".

The Don Woods stamp is inflammable.

To say stamp text:

say fixed letter spacing;

say "+--v----v----v----v----v--+[line break]";

say "| _______ |[line break]";

say "> One / [unicode 92] G <[line break]";

say "| Lousy / [unicode 92] U |[line break]";

say "> Point | ___ | E <[line break]";

say "| | (___) | |[line break]";

say "> <--)___[unicode 40]--> P <[line break]";

say "| / / [unicode 92][unicode 92] o |[line break]";

say "> / / [unicode 92][unicode 92] s <[line break]";

say "| |-|---------|-| t |[line break]";

say "> | | [unicode 92] _ / | | a <[line break]";

say "| | | --(_)-- | | g |[line break]";

say "> | | /| |[unicode 92] | | e <[line break]";

say "| |-|---|_|---|-| |[line break]";

say "> [unicode 92] [unicode 92]__/_[unicode 92]__/ / <[line break]";

say "| _/_______[unicode 92]_ |[line break]";

say "> | f.m.i.c. | <[line break]";

say "| ------------- |[line break]";

say "> <[line break]";

say "| Donald Woods, Editor |[line break]";

say "> Spelunker Today <[line break]";

say "| |[line break]";

say "+--^----^----^----^----^--+[line break]";

say variable letter spacing.

The case-points of the Don Woods stamp is 1.

The size of the free brochure is 30.

The size of the Don Woods stamp is 1.

Check hi-speaking the sailor for the tenth time:

say "I think that phrase is getting a bit worn out." instead.

Check hi-speaking the sailor for the 20th time:

say "You seem to be repeating yourself." instead.

Understand "pour [something] in/into/on/onto [something]" as inserting it into.

Understand "fill [something] with [something]" as inserting it into (with nouns reversed).

A watersource is a kind of thing. A watersource is always scenery.

A watersource can be drainable or nondrainable. A watersource is usually drainable.

A quantity of water is a thing.

The size of the quantity of water is 4.

When play begins: move the quantity of water to the bottle.

Check taking a watersource:

if the player is carrying the bottle, try inserting the noun into the bottle instead;

else say "The water slips through your fingers." instead.

Check inserting a watersource into something:

if the second noun is closed begin;

say "[The second noun] is closed." instead;

else if the second noun is not the bottle;

say "The water leaks out of [the second noun] and evaporates immediately." instead;

else if something is in the bottle;

say "The bottle is already full." instead;

else;

say "The bottle is now full of water.";

move the quantity of water to the bottle instead;

end if.

Check inserting the quantity of water into something:

if the second noun is closed begin;

say "[The second noun] is closed." instead;

else if the second noun is not the bottle;

say "The water leaks out of [the second noun] and evaporates immediately.";

remove the quantity of water from play instead;

end if.

Check inserting the quantity of water into the bottle:

try taking the quantity of water instead.

Check inserting the quantity of water into an enterable container:

if the bottle is closed, say "The bottle is closed." instead;

say "There is now a puddle in the bottom of [the second noun].";

now the quantity of water is in the second noun instead.

Check taking the quantity of water:

if the player is not carrying the bottle and the quantity of water is in the bottle begin;

try taking the bottle instead;

else if the quantity of water is in the bottle;

say "You already have it." instead;

else if the player is not carrying the bottle;

say "The water slips through your fingers." instead;

else if the bottle is closed;

say "The bottle is closed." instead;

else if something is in the bottle;

say "The bottle is already full." instead;

else if the player is in the bucket;

say "The bottle is now full of water.";

move the quantity of water to the bottle;

move the bucket to Circular Room instead;

else;

say "The bottle is now full of water.";

move the quantity of water to the bottle instead;

end if.

Check throwing the quantity of water at something:

say "The water splashes on [the second noun] and evaporates immediately.";

remove the quantity of water from play instead.

A persuasion rule for asking someone to try doing something when dead flag is true:

say "No one hears you." instead.

Check dropping when the player's command includes "throw":

if the noun is the quantity of water begin;

say "The water splashes on the walls and evaporates immediately.";

remove the noun from play instead;

else;

continue the action;

end if.

Check dropping the quantity of water when the player's command does not include "throw":

try pouring the noun instead.

Pouring is an action applying to one thing.

Understand "pour [something]" as pouring.

Carry out pouring:

if the noun is the bottle and the quantity of water is in the bottle begin;

try pouring the quantity of water instead;

else if the noun is the quantity of water and the bottle is closed;

say "You'll have to open the bottle first.";

else if the player is in the bucket;

move the quantity of water to the bucket;

say "There is now a puddle in the bottom of the wooden bucket.";

say "The bucket rises and comes to a stop.";

move the bucket to Top of Well;

try looking;

else if the noun is the quantity of water and the player is in an enterable container (called the conveyance);

say "There is now a puddle in the bottom of [the conveyance].";

move the quantity of water to the conveyance;

else if the noun is the quantity of water;

say "The water spills all over the ground and evaporates immediately.";

remove the quantity of water from play;

else if the noun is not a container;

say "You must tell me how to do that.";

else if the noun is closed;

say "You'll have to open [the noun] first.";

else;

now everything which is in the noun is in the location;

say "The contents of [the noun] spill out of [the noun] and onto the floor.";

end if.

Winding is an action applying to one carried thing. Understand "wind [something]" and "wind up [something]" and "wind [something] up" as winding.

Check winding: if the noun is not the golden clockwork canary and the noun is not the broken canary, say "You cannot wind up [a noun]." instead.

Understand the command "answer" as something new.

Understand the command "say" as something new.

speaking is an action applying to one topic. Understand "answer [text]" as speaking.

Understand "say [text]" as speaking.

Check speaking:

if the player is not in Riddle Room or the topic understood does not include "well" or the great door is open, say "No one seems to be listening." instead.

Carry out speaking:

say "There is a clap of thunder and the east door opens.";

now the great door is open;

now the great door is openable.

Leaving is an action applying to one visible thing. Understand "exit [something]" as leaving.

Check leaving:

if the player is not in the noun, say "How do you expect to do that when you aren't even in [the noun]?" instead;

try exiting.

Table of Rankings

Kicking is an action applying to one visible thing. Understand "kick [something]" as kicking.

Carry out kicking: if dead flag is true, say "All such attacks are vain in your position." instead;

say "Kicking [a noun] is not notably useful."

Lamp-power is a number that varies. Lamp-power is usually 325.

Check switching on the battery-powered brass lantern when lamp-power is 0: say "The battery has died." instead.

Load-max is a number that varies. Load-max is usually 100.

A thing has a number called size. The size of a thing is usually 5.

A container has a number called capacity. The capacity of a container is usually 5.

Weight-sum is a number that varies. Weight-sum is usually 0.

Check the player taking something:

now weight-sum is 0;

repeat with item running through things had by the player begin;

now weight-sum is weight-sum plus the size of item;

end repeat;

if weight-sum plus the size of the noun is greater than load-max, say "Your load is too heavy. You will have to leave something behind." instead.

Check inserting something into something else:

now weight-sum is 0;

repeat with item running through things in the second noun begin;

now weight-sum is weight-sum plus the size of item;

end repeat;

if weight-sum plus the size of the noun is greater than the capacity of the second noun, say "It won't fit." instead.

Lifting is an action applying to one visible thing. Understand "lift [something]" and "raise [something]" as lifting.

Check lifting:

if the noun is the rug begin;

say "The rug is too heavy to lift, but in trying to raise it you notice an irregularity beneath it.";

else if the noun is the tbasket;

if the player is in Lower Shaft begin;

say "The basket is raised to the top of the shaft.";

move the tbasket to Shaft Room;

move the fbasket to Lower Shaft;

else;

say "Playing in this way with [a noun] has no effect.";

end if;

else if the noun is the fbasket;

if the player is in Shaft Room begin;

say "The basket is raised to the top of the shaft.";

move the tbasket to Shaft Room;

move the fbasket to Lower Shaft;

else;

say "The basket is at the other end of the chain.";

end if;

else;

say "Playing in this way with [a noun] has no effect.";

end if.

Lowering is an action applying to one visible thing. Understand "lower [something]" as lowering.

Check lowering:

if the noun is the tbasket begin;

if the player is in Shaft Room begin;

say "The basket is lowered to the bottom of the shaft.";

move the fbasket to Shaft Room;

move the tbasket to Lower Shaft;

else;

say "Playing in this way with [a noun] has no effect.";

end if;

else if the noun is the fbasket;

if the player is in Lower Shaft begin;

say "The basket is lowered to the bottom of the shaft.";

move the fbasket to Shaft Room;

move the tbasket to Lower Shaft;

else;

say "The basket is at the other end of the chain.";

end if;

else;

say "Playing in this way with [a noun] has no effect.";

end if.

Attachment relates things to each other in groups. The verb to be attached to implies the attachment relation.

The block tying rule is not listed in any rulebook.

A rope is a kind of thing. Definition: a thing is nonrope if it is not a rope.

A thing can be round or unevenly shaped. A thing is usually round.

Check tying:

if the noun is the second noun, say "There is nothing it can be tied to." instead;

if the noun is the coil of rope and the second noun is the braided wire, say "There is nothing it can be tied to." instead;

if the second noun is a rope, try tying the second noun to the noun instead;

if the noun is not a rope, say "You can't tie stuff with that." instead;

if the noun is attached to a nonrope thing (called the item), say "[The noun] is already attached to [the item]." instead;

if the player is carrying the second noun, say "It is too clumsy when you are carrying it." instead;

if the second noun is round, say "There is nothing it can be tied to." instead.

Carry out tying:

now the noun is attached to the second noun;

if the second noun is in Slide Room and the player is carrying the noun begin;

move the noun to Slide Room;

say "The rope dangles down the slide." instead;

end if.

Report tying:

say "The rope is now attached to [the second noun].".

Check taking a rope (called the coil) when the coil is attached to a nonrope thing (called the item):

say "You'll have to untie [the item] first." instead.

Check taking a nonrope thing (called the item) which is attached to a rope:

say "The coil of rope comes loose from [the item].";

now the coil is not attached to the item.

Untying it from is an action applying to two things.

Understand "untie [something] from [something]" as untying it from. Understand "untie [something]" as untying it from.

Rule for supplying a missing second noun while untying something from:

if the number of secondary things attached to the noun is 0, say "[The noun] is already entirely free." instead;

if the noun is a rope

begin;

if the number of touchable nonrope things which are attached to the noun > 1

begin;

say "You'll have to say which thing you want to untie [the noun] from.";

rule fails;

otherwise;

if the number of touchable nonrope attached to the noun is 0, say "You can't reach [the random nonrope thing attached to the noun]." instead;

let the tied object be a random touchable nonrope thing which is attached to the noun;

say "(from [the tied object])[line break]";

now the second noun is the tied object;

end if;

otherwise;

if the noun is attached to a rope (called the tied object)

begin;

say "(from [the tied object])[line break]";

now the second noun is the tied object;

end if;

end if.

Check untying it from:

if the noun is attached to the second noun or the second noun is attached to the noun, do nothing;

otherwise say "[The noun] and [the second noun] are already not tied together." instead;

if the noun is not a rope, try untying the second noun from the noun instead.

Carry out untying it from:

now the noun is not attached to the second noun.

Report untying it from:

say "The rope is now untied.".

Definition: a thing is secondary if it is not the noun.

A thing has a text called the later appearance. The later appearance of something is usually "".

Rule for writing a paragraph about something (called the thingy):

if the thingy is untouched and the initial appearance of the thingy is not "" begin;

say "[initial appearance of the thingy]";

else if the later appearance of the thingy is not "";

say "[later appearance of the thingy]";

else;

say "There is [a thingy] here[unicode 46]";

end if;

if something visible is in the thingy begin;

if the thingy is the trophy case begin;

say "[line break]Your collection of treasures consists of:[line break][stuff in the thingy]";

else if the thingy is the nest and the egg is in the thingy and the egg is untouched;

say "[initial appearance of the egg]";

else;

say "[line break][The thingy] contains:[line break][stuff in the thingy]";

end if;

end if.

To say stuff in (O - an object):

list the contents of O,

with newlines,

indented,

giving inventory information,

including contents,

not listing concealed items,

and with extra indentation.

To say (j - a number) spaces:

(- spaces({j}); -).

A thing can be untouched or touched. A thing is usually untouched.

The initial appearance of something is usually "".

After taking something: now the noun is touched; continue the action.

To fatally leap:

say "[one of]You should have looked before you leaped.[or]I'm afraid that leap was a bit much for your weak frame.[or]In the movies, your life would be passing in front of your eyes.[or]Geronimo...[or]I'm afraid that leap you've attempted has done you in.[at random]";

end the game in death.

Table of Basic Help Options (continued)

Table of Hints

Table of Egg Hints

Table of Hades Hints

Table of Bar Hints

Table of Glacier Hints

Table of Well Hints

Table of Rainbow Hints

Table of Barrel Hints

Table of Bank Hints

Table of Endgame Hints

Table of Brochure Hints

Check requesting the score:

if dead flag is true, say "How can you think of your score in your condition?" instead.

Before opening:

if dead flag is true, say "Even such a simple action is beyond your capabilities" instead.

Before closing:

if dead flag is true, say "Even such a simple action is beyond your capabilities" instead.

Before eating:

if dead flag is true, say "Even such a simple action is beyond your capabilities" instead.

Before drinking:

if dead flag is true, say "Even such a simple action is beyond your capabilities" instead.

Before rubbing:

if dead flag is true, say "Even such a simple action is beyond your capabilities" instead.

Before touching:

if dead flag is true, say "Even such a simple action is beyond your capabilities" instead.

Before burning something with something:

if dead flag is true, say "Even such a simple action is beyond your capabilities" instead.

Before burning something:

if dead flag is true, say "Even such a simple action is beyond your capabilities" instead.

Before untying:

if dead flag is true, say "Even such a simple action is beyond your capabilities" instead.

Before speaking:

if dead flag is true, say "No one hears you." instead.

Before switching on something:

if dead flag is true, say "You need no light to guide you." instead.

Before taking something:

if dead flag is true, say "Your hand passes through the object." instead.

Before taking inventory:

if dead flag is true, say "You are empty handed." instead.

Instead of doing something other than looking, going, attacking, kicking, or destroying:

if dead flag is false, continue the action;

say "You can't do even that.".

Death count is a number that varies.

When play ends when the game ended in death:

increase death count by 1;

award -10 points;

if endgame flag is true begin;

say "Normally, I would attempt to rectify your condition, but I'm ashamed

to say my abilities are not equal to dealing with your present state

of disrepair. Please let me express my profoundest regrets.";

else if death count is 3;

say "You clearly are a suicidal maniac. We don't allow psychotics in the

dungeon, since they may harm other adventurers. Your remains will be

installed in the Land of the Living Dead, where your fellow adventurers

may gloat over them.";

else if Altar is unvisited;

say "Shall I patch you up? ";

if the player consents begin;

say "Now, let me see...[line break]Well, we weren't quite able to restore your state. You can't have everything.";

if the player is carrying the battery-powered brass lantern begin;

move the battery-powered brass lantern to Living Room;

now the battery-powered brass lantern is switched off;

end if;

repeat with item running through things had by the player begin;

move the item to a random visited room;

end repeat;

move the player to Forest 1;

resume the game;

else;

say "What? You don't trust me? Why, only last week I patched a running

ITS and it survived for over 30 seconds. Oh, well.";

end if;

else;

say "As you take your last breath, you feel relieved of your burdens. The feeling passes as you find yourself before the gates of Hell, where the spirits jeer at you and deny you entry. Your senses are disturbed. The objects in the dungeon appear indistinct, bleached of color, even

unreal.";

if the player is carrying the battery-powered brass lantern begin;

move the battery-powered brass lantern to Living Room;

now the battery-powered brass lantern is switched off;

end if;

repeat with item running through things had by the player begin;

move the item to a random visited room;

end repeat;

now dead flag is true;

now the player is lit;

move the player to Entrance to Hades;

resume the game;

end if.

The player has a number called wounds. Wounds is usually 0.

The player has a number called cure wait. Cure wait is usually 0.

Diagnosing is an action applying to nothing. Understand "diagnose" as diagnosing.

Check diagnosing:

if dead flag is true, say "You are dead as a doornail." instead.

[4]

Carry out diagnosing:

if the wounds of the player is 0 begin;

say "You are in perfect health. You are strong enough to take several wounds.";

else if the wounds of the player is 1;

say "You have a light wound, which will be cured in [cure wait of the player] turn[s]. You can survive one serious wound.";

else if the wounds of the player is 2;

say "You have a serious wound, which will be cured in [cure wait of the player] turn[s]. You can be killed by a serious wound.";

else if the wounds of the player is 3;

say "You have a several wounds, which will be cured in [cure wait of the player] turn[s]. You can be killed by one more light wound.";

else if the wounds of the player is 4;

say "You have a serious wounds, which will be cured in [cure wait of the player] turn[s]. You are at death's door.";

end if;

if death count is 1, say "You have been killed once.";

if death count is 2, say "You have been killed twice.".

Burning it with is an action applying to one thing and one carried thing. Understand "burn [something] with/using [something]" as burning it with. Understand "light [something] with/using [something]" as burning it with.

Check burning (this is the new burning rule):

if the noun is not the matchbook and the player is carrying something flaming begin;

let i be the number of flaming things had by the player;

if i is 1, try burning the noun with a random flaming thing held by the player instead;

else say "It's not clear what you want to burn [the noun] with." instead;

else if the noun is not the matchbook;

say "It's not clear what you want to burn [the noun] with." instead;

else if the matchbook is flaming;

say "The match is already lit." instead;

else if match count is less than 1;

say "I'm afraid you have run out of matches." instead;

end if.

Match tick is a number that varies. Match tick is usually -1.

Carry out burning:

say "One of the matches starts to burn.";

now match tick is 2;

now the matchbook is flaming.

Check switching off something which is flaming:

if the noun is the matchbook begin;

say "The match is out." instead;

now match tick is -1;

now the matchbook is non-flaming;

else if the noun is the pair of candles;

say "The flame is extinguished." instead;

else if the noun is the ivory torch;

say "You burn your hand as you attempt to extinguish the flame." instead;

end if.

The new burning rule is listed instead of the block burning rule in the check burning rulebook.

Check burning it with:

if the second noun is not flaming, say "How do you expect to burn anything with that?" instead;

if the noun is the black book begin;

say "A booming voice says 'Wrong, cretin!' and you notice that you have turned into a pile of dust.";

end the game in death instead;

end if;

if the noun is the barrel, say "The barrel is damp and cannot be burned." instead;

if the noun is flaming, say "[The noun] is already burning." instead;

if the noun is not the candles and the noun is not inflammable, say "I don't think you can burn [a noun]." instead;

if the noun is the brick begin;

say "Now you've done it. It seems that the brick has other properties

than weight, namely the ability to blow you to smithereens.";

remove the brick from play;

end the game in death instead;

end if.

Candle tick is a number that varies. Candle tick is usually 40.

Carry out burning it with:

if the noun is the pair of candles begin;

if the candles are flaming, say "You realize, just in time, that the candles are already lighted." instead;

if candle tick is 0, say "There's not much left of the candles; definately not enough left to light." instead;

if the second noun is the torch begin;

say "The heat from the torch is so intense that the candles are vaporized.";

remove the candles from play instead;

end if;

say "The candles are now lighted.";

if the player is in Entrance to Hades begin;

if exorcism flag is 1 begin;

say "The flames flicker wildly and appear to dance. The earth beneath

your feet trembles, and your legs nearly buckle beneath you.

The spirits cower at your unearthly power.";

now exorcism flag is 2;

else if exorcism flag is -1;

continue the action;

else;

say "The tension of this ceremony is broken, and the wraiths, amused but

shaken at your clumsy attempt, resume their hideous jeering.";

now exorcism flag is 0;

end if;

end if;

now the candles are flaming;

else if the noun is in the receptacle;

now the noun is flaming;

say "[The noun] burns inside the receptacle.";

now burn interrupt is 20 * the size of the noun;

else if the noun is the pile of leaves;

now the grating is revealed;

if the player is carrying the noun begin;

say "The sight of someone carrying a pile of burning leaves so offends the neighbors that they come over and put you out.";

remove the pile of leaves from play;

end the game in death;

else;

say "The leaves burn and the neighbors start to complain.";

remove the pile of leaves from play;

end if;

else if the noun is the coil of wire;

if the coil of wire is not part of the brick begin;

say "The wire rapidly burns to nothingness.";

remove the coil of wire from play;

else;

say "The wire starts to burn.";

now wire clock is 1;

end if;

else;

if the noun is the bills, say "Nothing like having money to burn!";

if the player is carrying the noun begin;

say "[The noun] catches fire and is consumed. Unfortunately, you were holding it at the time.";

end the game in death;

else;

say "[The noun] catches fire and is consumed.";

end if;

end if.

Wire clock is a number that varies. Wire clock is usually -1.

Ledge clock is a number that varies. Ledge clock is usually -1.

Burn interrupt is a number that varies. Burn interrupt is usually -1.

After dropping the candles:

if the candles are flaming, now the candles are non-flaming;

continue the action.

Every turn when the candles are flaming and the candles are touched:

decrease candle tick by 1;

if candle tick is 0 begin;

now the candles are non-flaming;

say "I hope you have more light than from a pair of candles.";

else if candle tick is 20 or candle tick is 10 or candle tick is 5;

say "The candles grow shorter.";

end if.

The bad place is a room that varies.

Squish clock is a number variable. Squish clock is usually -1.

Knocking is an action applying to one visible thing. Understand "knock [something]" and "knock on [something]" and "rap on [something]" and "rap [something]" as knocking.

Check knocking:

if the noun is not a door, say "Why knock on [a noun]?" instead;

if the noun is not the large wooden door, say "I don't think anyone is home." instead.

Carry out knocking:

say "The knock reverberates along the hall. For a time it seems there

will be no answer. Then you hear someone unlatching the small wooden

panel. Through the bars of the great door, the wrinkled face of an

old man appears. He gazes down at you and intones as follows:[paragraph break]";

say "[5 spaces] 'I am the Master of the dungeon, whose task it is to insure

that none but the most scholarly and masterful adventurers are

admitted into the secret realms of the dungeon. To ascertain whether

you meet the stringent requirements laid down by the Great

Implementers, I will ask three questions which should be easy for

one of your reputed excellence to answer. You have undoubtedly

discovered the answers during your travels through the dungeon.

Should you answer each of these questions correctly within five

attempts, then I am obliged to acknowledge your skill and daring and

admit you to these regions.'[paragraph break]";

say "All answers should be in the form [']ANSWER 'answer'['].";

now question number is 1;

move the dungeon master to Hallway4.

Spinning it to is an action applying to one thing and one number. Understand "spin [something] to [a number]" as spinning it to. Understand "turn [something] to [a number]" as spinning it to.

Check spinning it to:

if the noun is not the dial, say "You can't do that to [the noun]." instead;

if the number understood is less than 1, say "The dial only goes from 1 to 8." instead;

if the number understood is greater than 8, say "The dial only goes from 1 to 8." instead.

Carry out spinning it to:

say "The dial now points to [the number understood].";

now dial number is the number understood.