When in Rome 1: Accounting for Taste — 22 of 31

Chapter 6 - The Office

Understand "girl" or "woman" as a woman.

Esther is a woman. Understand "milligan" or "miss milligan" as Esther. The description of Esther is "She's a tall, shapely girl; taken on figure and clothes alone she'd be too perfected to seem real, but there is also an edge of exasperation: life has not been quite to her taste.

She reminds you a little of a nurse you knew back in the war." The description of Esther's hair is "Despite her attempts to arrange them, there are always at least two curls escaping from their assigned places, sometimes getting into her eyes." The description of Esther's eyes is "Pale blue and unreadable."

[Understand "ask Esther [text]" as a mistake ("Not really an option just now."). Understand "tell Esther [text]" as a mistake ("Not really an option just now."). Understand "talk to esther [text]" as a mistake ("Not really an option just now.").]

Understand "miss milligan" or "milligan" or "girl" or "woman" or "esther milligan" or "miss esther milligan" or "esther" as "[esther]".

Before reading a command:

remove properties.

After reading a command:

while the player's command includes "the":

cut the matched text; [1]

while the player's command includes "a":

cut the matched text;

if the player's command includes "[thugs]", replace the matched text with "thug";

if the player's command includes "[esther]", replace the matched text with "girl";

if the player's command includes "ask girl to", replace the matched text with "girl,";

if the player's command includes "tell girl to", replace the matched text with "girl,";

if the player's command includes "ask thug to", replace the matched text with "thug,";

if the player's command includes "tell thug to", replace the matched text with "thug,". [There may eventually be a classier way to do this, but for now we can divert ask (person) to (do something) to the correct command form by changing the command before it reaches the parser.]

Understand the command "grab" as "take".

Understand "call [any thing]" or "summon [any thing]" or "shout to/for/at [any thing]" or "call to/for [any thing]" or "yell to/for/at [any thing]" as summoning.

Summoning is an action applying to one thing. Summoning is useless action.

Carry out summoning: say "There is no answer."

Instead of summoning a timid creature: if the creature is visible, say "[The creature] flinches, covering its ears."; otherwise continue the action.

Set-like Hallway is a room. "[if the Hallway is unvisited]Your new company, which claims to belong to a private investigation firm, in case anyone wonders who you are and why officers of the law need to visit from time to time. The Alien Protocol men -- you've come to call them AP in your head -- arranged the whole thing with such efficiency that you wonder whether you've underestimated military intelligence all these years.

This area has been decorated[otherwise]Decorated[end if], over the last few days, by Esther, whose idea of investigators comes largely from 'Charlie Wild, Private Detective.' Every time you walk through here you half expect to come nose-to-nose with an advertisement for Wildroot Hair Cream Oil, Charlie Wild's corporate sponsor.

Just inside is your office."

Instead of going nowhere from the Hallway, say "In seems to be the operative direction here."

After taking the salami for the first time:

say "You acquire the salami. 'Esther, you shouldn't have,' you shout, divesting it of its bow. It has about the size, if not the heft, of a policeman's cosh.

'It wasn't me, sir,' she yells. 'It's from the head of the Alien Protocol office, because of your new assignment as an independent agent.'

Oh. 'Did they get you anything?'

'No, they did not.' The typewriter resumes, more loudly than ever."

Instead of eating the salami:

say "It's a bit early in the morning for this kind of meal."

Instead of waiting in the Set-like Hallway: say "You try postponing the inevitable, but the critter does await you inside."

Office on Floor Fifty-One is inside from Set-like Hallway. "Your office[if the number of scenery things in the office is less than three]. Recent remodeling efforts have left it positively spacious, with only [the list of scenery things in the office] as permanent features[otherwise]. It's cramped, what with [the list of scenery things in the office], but it's got a great view down Fifth Avenue[end if]."

After going to the Office:

say "'Try not to get killed!' Esther shouts cheerily, as you go inside.";

try looking;

say "From the strand dangling out of its mouth, you surmise the Thing has just eaten the hooked rug your mother gave you.

'Glorp?' it inquires.";

end the story saying "To be continued";

The window is scenery in the office. Understand "view" as the window. The description is "It is raining periodically and colder than it should be for this time of year; which had better clear up by this afternoon, because the Yankees are playing the Red Sox." Instead of searching the window, try examining the window. Before opening the window: say "In the normal course of things, windows on the fifty-first floor do not open.

Your particular window does, of course, since the pods have to get out somehow, but the whole thing is rigged with machinery you can't control. You've heard rumors that your predecessor sent a pod out straight through the plate glass, hospitalizing ten people from the sidewalk below. Best not to meddle." instead.

The desk is scenery in the Office. It is a supporter. The description is "Grim, gun-metal grey, but quite sturdy, impervious to blows, and washable. All of these features have come in useful in your work."

The chair is scenery in the Office. It is an enterable supporter. The description of the chair is "Made of slightly less sturdy matter than the desk, and therefore the fourth you have owned in the course of this job. You also used to have a potted cactus, but it got eaten, in an incident that did not end happily for anyone."

The file drawer is scenery in the Office. It is a container. Understand "drawers" or "cabinets" or "cabinet" as the drawer. A lot of paperwork is a thing. The file drawer is closed and openable. The autographed picture of Joe DiMaggio is on the desk. The description of the picture is "He's mid-swing, and the autograph is made out to you personally." Before printing the name of the file drawer: if the file drawer is damaged, say "severely dented".

After opening the file drawer when the file drawer contains more than five things:

say "You open the file drawer with a bit of struggle -- something in there is catching when you pull. But it finally comes open, and half-disgorges [a list of things in the file drawer]."

The paperwork is fixed in place. Understand "files" as paperwork. The paperwork is papery.

The description of the paperwork is "Copies of previously filed forms (mostly done by your predecessor), indexed by home-world." Understand "papers" or "forms" or "form" as the paperwork. Instead of consulting the drawer about something: try consulting the paperwork about it.

Burying relates various things to various things. The verb to disguise (it disguises, they disguise, he is disguising) implies the burying relation.

Understand "conceal [something] in [something]" or "hide [something] in [something]" or "bury [something] in [something]" as hiding it in. Hiding it in is an action applying to two things. Check hiding it in: if the second noun is not a container, say "[The second noun] will not conceal much." instead; if the second noun is not openable, say "[The second noun] cannot be closed." instead; if the player does not carry the noun, try taking the noun; if the player does not carry the noun, stop the action. Carry out hiding it in: try inserting the noun into the second noun; if the noun is in the second noun and the second noun is openable, try closing the second noun. Hiding something in something is useless action.

Understand "dig in [something]" as digging. Digging is an action applying to one thing. Carry out digging: say "Pointless."

Understand "look up [moon] in [something]" as researching in it about (with nouns reversed). Understand "consult [something] on/about [moon]" as researching in it about. Understand "read about [moon] in [something]" as researching in it about (with nouns reversed). Understand "read [moon] in [something]" as researching in it about (with nouns reversed). Understand "look up [moon]" as researching vaguely.

Researching vaguely is an action applying to one moon. Check researching vaguely: say "You've no reference works handy that will apply to the present situation."

Researching in it about is an action applying to one thing and one moon.

Carry out researching in it about: say "You find nothing of interest in [the noun]."

The setup rules is a rulebook.

A setup rule (this is the tongue rule):

if food of creature is meaty, now tongue of creature is "sharp carnivore teeth";

if food of creature is wood-pulpy, now tongue of creature is "a long raspy tongue";

if food of creature is earthly, now tongue of creature is "a round pink tongue";

if food of creature is textile, now tongue of creature is "a forked tongue".

A setup rule (this is the claws rule):

if the moon of the creature is Europa, now the claw of the creature is "flipper-tip".

A setup rule (this is the color-assignment rule):

if the creature lies nearer than Luna, now the color of the creature is a random color between red and yellow;

if the creature lies beyond Venus and creature lies nearer than Mars, now the color of the creature is a random color between yellow and cyan;

if the creature lies beyond Luna and creature lies nearer than Saturn, now the color of the creature is a random color between green and purple;

if the creature lies beyond Jupiter, now the color of the creature is a random color between tan and grey;

if the moon of the creature is Triton, now the color of the creature is grey.

To say creature clothing:

if the creature wears something

begin;

say "It is wearing [the list of things worn by the creature]";

end if.

Rule for writing a paragraph about the creature when the location is the Office:

say "There's a collared [creature] waiting."

Rule for writing a paragraph about the creature:

say "Lurking in the opposite corner from you is a creature, about the size of a large dog, with [color of the creature] ";

if the creature is scaly, say "scales. ";

if the creature is furry, say "fur. ";

if the creature is not furry and the creature is not scaly, say "skin. ";

if the creature wears something

begin;

say "It is wearing [list of things worn by the creature]. ";

end if;

if the creature carries something, say "It is carrying [a list of things carried by the creature]. ";

say paragraph break.

Before listing nondescript items:

if the creature is marked for listing, now the creature is not marked for listing.

Showing confusion at is an action applying to one thing.

Carry out the creature trying showing confusion at: do nothing.

Report the creature trying showing confusion at:

say "[The creature] blinks at [the noun] uncertainly."

Before a stupid creature trying playing with something when a random chance of 1 in 3 succeeds:

now the creature is passive;

if the creature is hostile,

say "[The creature] watches you belligerently[if the carrying capacity of the creature > 2] with two of its [carrying capacity of the creature in words] hands[end if] on its hips." instead;

otherwise say "[The creature] scratches its head[if the carrying capacity of the creature > 2] with one of its [carrying capacity of the creature in words] hands[end if]." instead.

Report a stupid creature trying wearing the socks:

say "[The creature][quickly] puts on your socks -- one over each ear." instead.

Report a creature trying wearing the fedora:

say "[The creature] dons the fedora[if the creature is smart] and flicks the brim at you[end if]." instead.

Report a fast creature trying playing with something delicious:

if the noun is undershorts,

say "[The creature] darts its tongue out to [the noun], sampling the flavor. Then it looks appalled and begins spluttering and spitting." instead;

otherwise

say "[The creature] darts its tongue out to [the noun], sampling the flavor[if the creature is friendly]. It gives you a shy look afterward, as though caught at some embarrassing practice[end if]." instead.

To decide whether (item - a thing) outweighs strength:

if the item is light, no;

if the gravity of the creature is greater than fractional and the item is medium-weight, no;

if the gravity of the creature is greater than Marslike, no;

yes.