When in Rome 1: Accounting for Taste — 21 of 31

Chapter 4 - Factory

The Factory Floor is a room. "A vast room in which cars were once assembled. It has obviously been derelict for some time, since most of the machinery has been stripped out. There remain only a couple of presses and lathes, which look too dangerous for someone so mechanically disinclined as yourself.

Since its automotive days, it has become a command center, or perhaps a library. Stacked on every available surface are printed materials: magazines, newspapers, movie pamphlets. A large bulletin board fills one wall.

To the north is a smaller room which you would guess to be the foreman's base of operation." North from the Factory Floor is the Foreman's Area.

The machinery is scenery in the Factory Floor. Understand "presses" and "press" and "lathe" and "lathes" as the machinery. The description is "Large; heavy. This concludes your expertise in mechanics."

The printed materials are scenery in the Factory Floor. Understand "magazine" or "magazines" or "newspaper" or "papers" or "newspapers" or "paper" or "pamphlet" or "pamphlets" or "movie" as the printed materials. The description of the printed materials is "You flip through the nearest pile: LIFE magazine from 1952 ('Are Flying Saucers Real?'); a number of issues of 'Astounding Stories'; pamphlet for 'The Day the Earth Stood Still'; some recent newspaper articles in French."

The large bulletin board is scenery in the Factory Floor. Understand "map" and "maps" and "picture" and "pictures" and "pin" and "pins" as the bulletin board. The description of the board is "On the board is a map of Manhattan with pins in it, and lines drawn, like a subway map, but not corresponding to any subway lines that actually exist.

The whole thing reminds you obliquely of field planning centers during the war."

Rule for listing nondescript items of the Factory Floor:

say "You've been left with ";

list the contents of the Factory Floor, as a sentence, tersely, listing marked items only, including contents and giving brief inventory information;

say "."

The metal bar is in the Factory Floor. "A heavy bar of scrap metal sits on one of the newspaper piles, doing duty as a paperweight." The weight is heavy. Understand "paperweight" or "scrap" or "heavy" as the metal bar. The description is "You've heard of these vertical-integration plants that can turn a lump of iron ore into an engine block in less than 24 hours. The metal bar appears to come from an early-ish phase of that process, refined into heavy steel but not shaped like an auto part yet."

The Foreman's Area is a room. "Elevated a few steps above the factory floor itself, this room must once have contained some office equipment or furniture: there are marks on the floor that suggest chairs and a desk, at the very least. But it has been cleared of all this."

Instead of going down in the Foreman's Area: try going south.

The cardboard box is in the Foreman's Area. It is a papery enterable container. It is openable and open. The description of the cardboard box is "It is about waist-high and roughly cubical. No clear sign of what used to be inside, though."

The built-in counter is a supporter in the Foreman's Area. The description of the counter is "From the many ring-shaped stains and the odor of failed coffee experiments, you guess that this area has been serving as break-room and impromptu kitchen since the factory shut down. [if something is on the counter]It currently contains [a list of things which are on the counter][otherwise]It is bare at the moment[end if]." The counter is scenery.

The paint lid is a thing on the counter. It is stinky. The description of the paint lid is "The top announces it to be from a tin of Saddle Brown paint, and it must have been used relatively recently, because it still carries a pungent chemical odor." Before opening the paint: say "This is just the lid, anyway." instead.

The rubber ball is a thing. The description is "A red rubber ball, slightly chewed, much like the one favored by your dog Lloyd when you were a kid." Understand "red" as the rubber ball. Instead of squeezing the ball, say "Pleasantly resilient."

The hood ornament is a medium-weight thing on the counter. The description of the hood ornament is "Oddly lonely without the rest of a car to go with it. It does have a moderate heft to it, though."

The Chevrolet Passenger Car Shop Manual is a papery thing on the counter. The description of the manual is "The front cover reads: Chevrolet Passenger Car Shop Manual -- 1949-53 Models -- 1954 supplement -- RW-34-SM. Which will come in handy should you feel a sudden need to construct your very own automobile, but from its dusty and derelict air you get the sense that the suits are not expecting you to do any such thing."

Rule for printing room description details of the cardboard box when the number of things contained by the box is 0: stop. [This turns off the (empty) message afterward.]

Report the creature trying playing with the rubber ball:

say "[The creature] throws [the ball] [forcefully] against the far wall." instead.

Report the creature trying dropping the rubber ball:

now the rubber ball is unexplored;

say "[The creature] drops [the ball], which, of course, bounces back. It scoots back in surprise." instead.

Report the creature trying dropping the rubber ball more than once:

say "[The creature] holds [the ball] out in front of it carefully and then lets go; nods intently as it bounces." instead.

Report an Earthlike creature trying playing with a heavy thing:

say "[The creature] does a couple of quick lifts of [the noun]; why do you get the sense that it's showing off?" instead.

The creature can be known or unknown. The creature is unknown.

Understand "shout [moon]" as guessing a moon. Understand "say [moon]" as guessing a moon. Understand "shout [text]" as guessing randomly. Understand "shout [moon] to [any person]" or "say [moon] to [any person]" as directed guessing. Understand the commands "yell" and "holler" as "shout".

Directed guessing is an action applying to one moon and one visible thing. [1]

Check directed guessing: [if the Test is not happening, say "That seems pointless." instead;] if the second noun is not the thugs, say "It is unlikely that anyone but the thugs can hear you." instead. Carry out directed guessing: try guessing a moon the moon understood. Directed guessing is useless action.

Guessing a moon is an action applying to one moon. Guessing randomly is an action applying to one topic. Guessing a moon is useless action. Guessing randomly is useless action.

[

Before guessing a moon when Test is not happening: say "No reason to do any such thing." instead.

]

Carry out guessing randomly: say "No one answers."

Instead of guessing a moon for the first time:

if the moon understood is not the moon of the creature,

say "A microphone crackles. 'We recommend against guessing randomly,' says a stern voice. 'The repercussions for yourself and Miss Milligan could be quite serious.' Again you remember why you were glad not to be in intelligence, back in the war.";

otherwise continue the action.

Instead of guessing a moon:

if the moon understood is not the moon of the creature

begin;

say "A microphone crackles in another room. 'That is not correct,' says a voice, through the loudspeaker. 'We are going to have to--'

Someone interrupts, and they have what sounds like an argument, though you catch only snippets of it: something about the situation not being your fault, and so on. Then the microphone cuts off.

There's a very long silence, one that goes on for five or ten minutes, maybe more.

Finally the door opens and you are invited to emerge. Strong men grasp you firmly by the arms, and there is a sharp prick in the neck: drugs, presumably. You feel your legs going weak, then a somewhat confused and dizzy journey down a passageway. This ends in a steel-lined room that reminds you of the undertaker's, when your father died: the same cold slabs, some with people on them.

The last thing you see clearly is Esther on an adjacent table, fetal, with a bright metal hat fitted over her head.";

end the story saying "This can't be good";

otherwise;

now the creature is known;

say "'I believe this one is from [the moon understood],' you announce loudly, for the benefit of the unseen men spying on you.

'Excellent,' says a voice from the loudspeaker above you. It sounds genuinely relieved. 'Stay there a moment, please.'

The door opens again and the black-suited man comes back in. 'Call me Max,' he says, shaking your hand firmly. 'Welcome to the Office of Alien Protocol.'

'Wonderful,' you say, furious now that your life is no longer in danger. 'Is this for real? Who do you think you are, anyway? Have you been toying with us?'

He looks at you for a moment. From his expression it is obvious he has never even heard of such a thing as a practical joke.

'Do you mind me asking the nature of my employment?' you try, instead.

Max smiles.";

end if.