Glass — 11 of 25

Section 5 - Speech Acts

[Yes, no, swearing, and saying sorry are accounted for in the basic library, and we should re-map these as well:]

Instead of asking someone to try swearing mildly: try swearing mildly.

Instead of swearing mildly:

say "[A random visible woman] giggles faintly."

Understand "shit" or "fuck" or "damn" or "sod" as "[obscenity]". [1]

Understand "swear" or "curse" or "mention obscenities" as swearing obscenely.

Understand "bother" or "curses" or "drat" or "darn" as "[mild obscenity]".

Instead of swearing obscenely for the first time:

now the player is disgraced;

say "You squawk very loudly.

'If that happens again,' says the old woman to you, 'we will sell you to the first man with an earring we can find.'

Lucinda's cheeks go pink."

Swearing obscenely is speech. Swearing mildly is speech. Saying yes is speech. Saying no is speech. Saying sorry is speech.

Instead of asking someone to try doing something:

if asking someone to try speech, continue the action;

say "No one in this house obeys you at all."

Instead of asking someone to try swearing obscenely: try swearing obscenely.

Instead of swearing obscenely:

say "'Right,' says the old lady. And she rings for a servant to remove you from the room.";

end the story saying "You are sold to pirates and have a glorious career on the open sea".

A person can be disgraced or approved. A person is usually approved.

Bird trouble is a scene. Bird trouble begins when the player is disgraced. Bird trouble ends when time since bird trouble began is 2 minutes. When Bird trouble ends: now the player is approved.

Instead of asking someone to try saying sorry: try saying sorry.

Instead of answering someone that "sorry", try saying sorry.

Instead of saying sorry:

say "'Oops!' you squawk. 'Sorry! Oops, sorry!'

[if player is disgraced]'Just mind your beak from now on, that's all,' says the old lady sternly. 'And stop interrupting.'

Everyone turns back to the human conversation.[otherwise]They all ignore you.[end if]"

Instead of asking someone to try saying yes: try saying yes. Instead of answering someone that "yes", try saying yes.

Instead of saying yes:

say "'[awwk]! Yes!'"

Instead of asking someone to try saying yes: try saying no. Instead of answering someone that "no", try saying no.

Instead of saying no:

say "'No!' you squawk. 'No no!'

[The random visible person who is not the player] frowns in your direction."

[Now we've set up the conversation model; time to provide some actors.]