Bronze — 41 of 46

Chapter 2 - Adaptive Hints

Dependence relates various things to various things. The verb to follow (it follows, they follow, it followed, it is followed, it is following) implies the dependence relation.

Before hinting about something which follows something (called the prior issue):

if the prior issue is solved, continue the action;

say "The current problem cannot be fully dealt with until you have addressed another issue; further exploration is called for[if the prior issue is tantalizing]. You might concentrate on [the prior issue] for now[end if]." instead.

Explaining relates various things to various things. The verb to explain (it explains, they explain, it explained, it is explained, it is explaining) implies the explaining relation.

Instead of hinting about something when something unexamined (called the clue) explains the noun:

if the clue is the noun, say "Try examining [the noun]." instead;

say "You're still missing some information that might be useful to understanding the problem. [More]";

if player consents, try hinting about the clue.

Requiring relates various things to various things. The verb to require (it requires, they require, it required, it is required, it is requiring) implies the requiring relation.

Instead of hinting about something when the noun requires something (called the implement) which is not had by the player:

if the noun is solved, continue the action;

if the implement is the stool and the stool is visible, continue the action;

say "You're missing an object that might be useful to resolving this problem. [More]";

if player consents, try hinting about the implement.

Definition: a thing is unsolved:

no.

Understand the command "hint" as something new. [1]

Understand "hint" as asking for a hint. Asking for a hint is an action out of world. Instead of thinking, try asking for a hint.

Carry out asking for a hint:

if the Beast is unseen

begin;

say "Your goal is to discover the beast; you might try exploring and looking for him. ";

otherwise;

if the beast is hungry, say "You might try finding some food for the Beast. ";

otherwise say "The Beast has asked that you destroy the contract book. You could work on that problem, or consider some of the other possibilities. ";

end if;

if the number of tantalizing things is greater than 0

begin;

say "Tantalizing leads at the moment include [the list of tantalizing things].";

otherwise;

if the number of unvisited rooms is greater than 0, say "Exploring further might be a good idea.";

otherwise say paragraph break;

end if.

Definition: a thing is tantalizing:

if it is solved, no;

if it is unseen, no;

if it follows an unsolved thing, no;

if it is unsolved, yes.

After reading a command:

if the player's command includes "think", replace the matched text with "hint".

Hinting topically about is an action applying to one topic. Understand "hint about [text]" as hinting topically about.

Carry out hinting topically about: say "Sorry, there is nothing to say about that."

Instead of hinting topically about a topic listed in the Table of Topic Hints:

say "[reply entry][paragraph break]".

Table of Topic Hints

Hinting about is an action applying to one visible thing. Understand "hint about [any seen thing]" as hinting about. Understand "remember [any seen thing]" as hinting about.

Understand "hint about [any pending thing]" as hinting about. Understand "remember [any pending thing]" as hinting about.

Understand "hint about [any visited room]" as hinting roomily about. Understand "remember [any visited room]" as hinting roomily about. Hinting roomily about is an action applying to one visible thing.

Instead of hinting about a ringer when the Bellroom is not visited:

say "There's a room on the upstairs level that may be relevant to all this."

Instead of hinting roomily about a solved room:

say "You have already accomplished the changes that need to be made to this room."

Instead of hinting roomily about a room which is controlled by a ringer (called the control):

if the noun is solved, continue the action;

say "[The noun] was built for a specific purpose. [more]";

if player consents,

say "When it comes to [the noun], it may help to have the right implements. [more]";

otherwise stop the action;

if player consents, try hinting about the control.

Instead of hinting roomily about paradise when the trapdoor is scenery:

say "Something seems unusual about the floor, but you're not able to see what it is. [more]";

if player consents,

say "Maybe you need to shed some new light on the subject. [more]";

otherwise stop the action;

if player consents,

say "How did you read the inscription? [more]";

otherwise stop the action;

if player consents,

say "Try putting the candle on the ground in an adjacent room, then returning to Debtor's Paradise.";

otherwise stop the action;

Instead of hinting roomily about the location:

if the noun contains a visible thing which is not the player, say "You notice here [the list of visible things which are not irrelevant].";

otherwise say "There isn't much here for you to play with."

Definition: a thing is irrelevant:

if it is the player, yes;

if it is the generic surroundings, yes;

no.

Instead of hinting roomily about a dark room:

say "You will need a light source to explore. [more]";

if player consents, try hinting about the candle.

Carry out hinting roomily about:

say "If there is a clear path, you can go to any room you like, just by saying go to [noun]."

Control relates a thing (called X) to a room (called Y) when Y is the target locale of X. The verb to control (it controls, they control, it controlled, it is controlled, it is controlling) implies the control relation.

[This allows us to create the most absolutely generic sort of hint -- boring, perhaps, but in practice the player often just needs a nudge about what part of the game world he should be examining for a solution:]

Carry out hinting about:

if something explains the noun, say "You might want to review [the list of things which explain the noun]. ";

if the noun requires something

begin;

say "You should be sure that you have [the list of things required by the noun]. ";

otherwise;

say "You can't think of anything further on the topic.";

end if.

[These things cover hinting about objects that are themselves puzzles. But what if the player asks for hints about a tool or piece of information because he doesn't know how to apply it yet? We might want to give some guidance there, as well.]

Carry out hinting about an unexamined thing which explains something (called target):

if target is solved

begin;

say "[The noun] was mostly useful as a source of clues about [the target]." instead;

end if;

if target is unseen

begin;

if the target is in Storage-Box, continue the action;

otherwise say "[The noun] might prove useful information, sooner or later." instead;

otherwise;

say "You could examine [the noun]." instead;

end if.

Carry out hinting about something which is required by something:

say "[The noun] might be useful to have. [More]";

if player consents

begin;

if a seen thing requires the noun, say "[The noun] may help with [the list of seen things which require the noun]." instead;

otherwise say "There [if the number of things which require the noun is 1]is[otherwise]are[end if] [number of things which require the noun in words] problem[s] for which [the noun] might come in handy." instead;

end if;

stop the action.

Carry out hinting about a ringer which is required by something (called target):

if the target is solved

begin;

say "[The noun] was mostly useful to get [the target]." instead;

end if;

say "[The noun] might be useful to have. [More]";

if player consents

begin;

if a seen thing requires the noun, say "[The noun] may help with [the list of seen things which require the noun]." instead;

otherwise say "Try ringing [the noun] in [the target locale of the noun]." instead;

otherwise;

stop the action;

end if.

[Now we have these general hints written, but we want to pre-empt them if the player has not yet fulfilled all the prerequisites.]

Instead of hinting about the cow bell:

say "Perhaps you could summon the spirit of Yvette to speak with you. [More]";

if player consents, say "Lucrezia was able to do this by ringing bells in the presence of a mirror. [More]";

otherwise stop the action;

if player consents, say "Go to the mirrors, then ring the bell."

Instead of hinting about something unseen:

if the noun is visible

begin;

now the noun is seen;

continue the action;

end if;

say "Perhaps you should explore further. ";

if the ultimate location of the noun is an unvisited room

begin;

try hinting about the ultimate location of the noun;

otherwise;

if the ultimate location of the noun is the location

begin;

say "You're in the correct room right now[if the visible shell of the noun is a thing]. Try further exploring [the visible shell of the noun][end if].";

otherwise;

if the ultimate location of the noun is a room,

try hinting about the ultimate location of the noun;

otherwise say "Focus on other things for the time being.";

end if;

end if.

Instead of hinting about a visited room:

say "There's a room you've visited, but you haven't exhausted all there is to see there. (The [if novice mode is functioning][bold type][end if]place[roman type] command will list every room you've visited, if you'd like to review.) [More]";

if player consents

begin;

say "Try going back to [the noun].";

end if.

Instead of hinting about an unvisited room:

say "There's a room you haven't yet visited. [More]";

if player consents, direct player to the noun.

To direct player to (goal - a room):

if the goal is visited

begin;

say "Try going to [the goal]."; rule succeeds;

end if;

if goal is location

begin;

say "Something in this very location will help you.";

rule succeeds;

end if;

let way be the best route from location to the goal, using doors;

if way is a direction, say "Try going [way] to start your explorations.";

otherwise say "The way is long, and possibly blocked by a locked door.";

Instead of hinting about a portable seen thing which is not visible:

if the noun is scenery, continue the action;

if the noun is a person, continue the action;

if in darkness and the player has the noun

begin;

say "You have something useful in your inventory. [more]";

if player consents, continue the action;

end if;

say "You have seen the item you need to solve this problem, but it's not in sight at the moment. (The [if novice mode is functioning][bold type][end if]objects[roman type] command will list everything you remember seeing, if you'd like to review.) [More]";

if player consents

begin;

try hinting about the ultimate location of the noun;

end if.

[And this business of "seen" things requires, of course, that we keep track:]

A thing can be seen or unseen. A thing is usually unseen. The player is seen. Before printing the name of something (called target): now the target is seen.

[We also need to deal with the question of whether the player has examined an object, for those objects whose descriptions carry vital information:]

A thing can be examined or unexamined. A thing is usually unexamined. Carry out examining something: now the noun is examined.

After taking something unexamined:

say "You acquire [the noun], and assess it curiously.";

try examining the noun.

After taking something, say "You acquire [the noun]."

[This is meant to speed up play, in that the player does not need to examine portable object separately.]

To decide what room is the ultimate location of (item - a thing):

let place be the holder of the item;

while the place is a thing:

let the place be the holder of the place;

if the place is a room, decide on the place.

To decide what thing is the visible shell of (item - a thing):

if item is visible, decide on the item;

let place be the holder of the item;

while place is a thing and place is not visible:

let place be the holder of the place;

if the place is visible, decide on the place.

To say more:

say "[paragraph break]Shall I go on? > ";

[That covers most of the generic hints, but let's also add some slightly more precise hints about a few kinds of objects that are especially important in the model world. These hints will probably not be very interesting to a seasoned IF veteran, but a novice player who does not know the wording or cannot guess what something might be for may still find them useful:]

Carry out hinting about a locked lockable thing:

say "You could unlock [the noun] with [the matching key of the noun]." instead.

Instead of hinting about the windchimes when the windchimes are not handled and the player is not on a supporter:

say "To reach the windchimes, it might help to stand on something. [more]";

if player consents, say "Try standing on the stool."

Carry out hinting about a closed openable unlocked thing:

say "You could open [the noun]." instead.

Carry out hinting about an open door:

say "You could enter [the noun]." instead.

Carry out hinting about an unexamined thing:

say "You might find out something if you examine [the noun]. (Then again, you might not -- but it's worth a try.)" instead.

Carry out hinting about an edible thing:

say "You could eat [the noun]." instead.

Carry out hinting about a wearable thing:

say "You could wear [the noun]." instead.

Instead of hinting about the shackle:

say "The shackle has little purpose now, except as a symbol of the enslavement that everyone in the castle -- including you -- would prefer to escape."

Carry out hinting about a pushable between rooms thing:

say "You could push [the noun] some direction." instead.

Carry out hinting about a visited room:

say "To return to any room you've already visited, try GO TO {the room}." instead.

Carry out hinting about an enterable supporter:

say "You could sit on [the noun]." instead.

Carry out hinting about an enterable container:

say "You could get inside [the noun]." instead.

Instead of hinting about the unexamined quill:

say "Try having another look at it."

Instead of hinting about the sign:

say "There were many times when you wanted to believe it was nonsense, but it conveys unmistakeable seriousness; and in any case you have seen enough else in various parts of the castle to be aware that strange powers do apply.

But the Beast assured you that you could leave and come back safely, with the right arrangements, which he was willing to make."

Instead of hinting about the leak: say "It should probably be patched in the long run if it's not to damage the castle wall, but for now it has no effect important enough to worry over."

Instead of hinting about the sinister door:

say "The inscription may be some help."

Instead of hinting about the storybook:

say "It does seem to suggest a means of scrying or communicating with sympathetic spirits -- at least with those who might wish to talk with you."

Instead of hinting about the cord:

try hinting about the inscription.

Instead of hinting about the bars of wax, say "You can't possibly use these yourself."

Instead of hinting about the scrap, say "There's nothing you can do with the scrap."

Instead of hinting about the forest:

say "Your family home is better remembered than visited, now: this is your conclusion. Or, if things were different and your sisters could visit you here... but to live there again holds no appeal for you."

Instead of hinting about the sea:

say "It is many many miles away; but if you find yourself without a place to live after this, perhaps you will go back to the seashore and find passage to some other country."

Instead of hinting about the helmet:

if the helmet is solved, continue the action;

if the helmet is unexamined, say "Try examining the helmet first." instead;

say "It seems that the helmet helps with hearing. [More]";

if player consents, say "Perhaps you can use it in a situation where you need good hearing. [More]";

otherwise stop the action;

if player consents

begin;

if the Maze Room is unvisited and the Quarters is unvisited, say "You have yet to run into the situation where you need good hearing, though. Explore more rooms, then come back to this problem." instead;

say "The helmet might be a useful guide to you in darkness, for instance. [More]";

otherwise;

stop the action;

end if;

if player consents, say "With the helmet on, you can hear sounds from several rooms away in the darkness, and use these noises to guide your movements. [More]";

otherwise stop the action;

if player consents, say "You should concentrate on the sound that you have heard before in an interesting context, and ignore any other noises. [More]";

otherwise stop the action;

if player consents, say "Try going down from the Servant Quarters, then following the sound of the windchimes until you surface in daylight again. If the room description does not mention chimes, try listening to get your bearings.";

otherwise stop the action.

Definition: the windchimes is unsolved if it is not handled.

Definition: the windchimes is solved:

if it is handled, yes;

if it is in the Bellroom, yes;

no.

Instead of hinting about the windchimes when the windchimes are not handled and the windchimes are unlocked:

say "Try taking them down, to silence them."

Instead of hinting about the windchimes when the windchimes are in the bellroom: say "The windchimes have served their purpose."

Definition: the helmet is solved if the Rose Garden is visited. Definition: the helmet is unsolved if it is not solved.

Instead of hinting about the solved helmet: say "The helmet was useful to get you to the rose garden, and may come in handy for problems involving sound again, if you run into any. But there is nothing further that you can think of to do with it at the moment."

The windchimes require the helmet and the stool and the small key. The windchimes follow the helmet.

The small door requires the small key. The small key follows the helmet.

Definition: the heavy door is unsolved if the Bellroom is unvisited and the White Gallery is unvisited. Definition: the heavy door is solved if it is not unsolved. Definition: the thick door is unsolved if the Bellroom is unvisited and the White Gallery is unvisited. Definition: the thick door is solved if it is not unsolved.

The heavy door and the thick door follow the windchimes.

The silver bell follows the heavy door. The candle requires the silver bell.

The dinner bell follows the heavy door. The feast requires the dinner bell. The Beast requires the feast. Definition: the Beast is solved if it is deceased. Definition: the Beast is unsolved if the Beast is not solved.

Definition: the dinner bell is solved if the feast is not in Storage-Box. Definition: The dinner bell is unsolved if the feast is in Storage-Box. Definition: the silver bell is solved if the candle is not in Storage-Box. Definition: the silver bell is unsolved if the candle is in Storage-Box.

The shoes follow the iron cage.

The iron cage requires the iron key. The iron key follows the Beast.

Definition: the cage is unsolved if it is locked. Definition: the cage is solved if it is unlocked.

The image follows the sinister door. The inscription explains the sinister door and the cord. The inscription requires the stool and the candle.

The notes follow the sinister door. The notes explain the girdle and the inkpot. The Wedding Treasure explains the inkpot. The inkpot follows the ivory door.

The ivory door requires the ivory key. The ivory door follows the shoes. The ivory key follows the shoes. The shoes require the leather tambourine. The image explains the tambourine.

Definition: the shoes are solved if it is wearable. Definition: the shoes are unsolved if it is not wearable.

The contract book requires the candle.

To repurpose the player: now the contract book requires the glass bell; now the contract book requires the inkpot; now the contract book does not require the candle; now the contract book follows the ivory door; now the beast requires the girdle; now the beast does not require the feast.

The inkpot follows the trapdoor. The fountain explains the inkpot. The stand explains the stand.

Definition: the trapdoor is solved if it is not scenery. Definition: the trapdoor is insolved if it is scenery.

The contract book and the miniature explain the girdle. The contract book explains the glass bell.

The harness explains the gong. The papers explain the quill.

The jigsaw puzzle requires the jagged piece. The jagged piece follows the iron cage.

Elzibad requires the gong.

Instead of hinting about the map when the candle is in the Rotunda:

say "By the candlelight, you can see all there is to see; there's nothing else that the map will tell you."

The map requires the candle.

Carry out hinting about the map:

say "It looks as though it can be illuminated with the candle, if the candle is set in the right place."

Instead of hinting about the quill: say "It isn't for you to use."

Instead of hinting about the inkpot when the stones are unsolved:

say "Before concerning yourself with that, you should thoroughly explore the crypt. ";

if the Debtor's Paradise is not visited

begin;

say paragraph break;

otherwise;

say "[More]";

if player consents, say "Especially the Debtor's Paradise. [More]";

otherwise stop the action;

if player consents, say "Do you notice anything odd about walking into and out of it repeatedly?";

end if.

Definition: the stones are solved if the trapdoor is not scenery. Definition: the stones are unsolved if the trapdoor is scenery.

Instead of hinting about the stones:

say "Perhaps there is some unevenness in the floor that would show where a trapdoor is. [more]";

if player consents,

say "In the past, you've needed to discern irregularities in floors and walls... [more]";

otherwise stop the action;

if player consents,

say "How did you resolve the inscription problem? [more]";

otherwise stop the action;

if player consents,

say "Drop the candle in any adjoining room, then come back and see what has changed."

Carry out hinting about the book return stand:

say "The stand is here to allow you to get things shelved in the Lie Library. [more]";

if player consents

begin;

say "Judging by the pictures would need to place the required object on the stand, then ring the correct bell for the librarian. [more]";

otherwise;

stop the action;

end if;

if player consents

begin;

say "Doing this might render the book in question false. [more]";

otherwise;

stop the action;

end if;

if player consents

begin;

say "This decision is up to you, but you could, if you wished, put the contract book on the book return stand, then ring the glass bell, thus converting the book to a work of fiction, and freeing everyone under contract." instead;

end if;

Instead of hinting about the glass bell when the glass bell is in Storage-Box:

say "The Lie Library might work if you could summon the librarian. He (or she) might reshelve whatever you take there. [more]";

if player consents

begin;

say "First, you'll need to find out how to summon the librarian. [more]";

otherwise;

stop the action;

end if;

if player consents, say "Try consulting the contract book about the librarian."

Instead of hinting about feast when the feast is in Storage-Box:

say "The beast seems to be suffering extreme hunger. [More]";

if player consents,

say "You will not be able to find food; you'll have to get the castle servants to bring it to you. [More]";

otherwise stop the action;

if player consents,

say "Therefore, you'll need a way to control them. [More]";

otherwise stop the action;

if player consents, try hinting about gold dinner bell.

Instead of hinting about candle when candle is in Storage-Box and the Translation Room is visited:

say "Lighting the translation room might be useful. [More]";

if player consents,

say "You will not be able to find light; you'll have to get the castle servants to bring it to you. [More]";

otherwise stop the action;

if player consents,

say "Therefore, you'll need a way to control them. [More]";

otherwise stop the action;

if player consents, try hinting about silver bell.

Instead of hinting about the candle when the candle is in Storage-Box and the Rose Garden is visited and the Translation Room is unvisited:

say "There is a room here where you might be able to acquire light, but you haven't reached it yet. Try exploring further."

Instead of hinting about the contract book when the Translation Room is unvisited:

say "The contract book's script is incomprehensible to you. You'll have to find some way to decipher it, or some location that assists you. Further exploration of the State Rooms might be in order."

Instead of hinting about candle when candle is in Storage-Box and the Rose Garden is unvisited:

if the location is dark

begin;

say "It is possible to wander in the dark, for the time being. [more]";

if player consents,

say "Perhaps you could rely on one of your other senses to guide you. [More]";

otherwise stop the action;

if player consents,

say "Listening might tell you something. [More]";

otherwise stop the action;

if player consents, try hinting about helmet;

otherwise;

say "There is enough light to see by for now.";

end if.

Instead of hinting about the pending feast when the Beast is unseen:

say "Finding the beast is your first priority."

Instead of hinting about the beast when the beast is in Storage-Box:

if the beast is deceased, say "You've avenged the wrongs of centuries, and put him out of his misery. There is nothing more you could do for or to him, even if you were able to find him again." instead;

say "Keep exploring: you'll find him sooner or later. [more]";

if player consents

begin;

if the helmet is unsolved

begin;

say "There are more rooms you can walk through, though not all of them are lit.";

stop the action;

end if;

if windchimes are unsolved

begin;

say "There is a way to make the state rooms available for exploration. [more]";

if player consents, say "Whenever you encounter the spirit guards, you hear a peculiar sound... [more]";

otherwise stop the action;

if player consents, try hinting about windchimes;

otherwise;

say "There are more rooms that you can reach if you wander.";

end if;

end if.

Instead of hinting about a solved thing:

if something requires the noun, continue the action;

otherwise say "There's nothing more you need to do about [the noun]."

Instead of hinting about yourself:

say "You'll be all right, as soon as you see Him well again."

Instead of hinting about the contract book in the presence of the candle:

say "Now that you have adequate lighting, you will be able to read the contract book in the translation room. [More]";

if player consents

begin;

say "You can just read it, or you can look up specific people in it. [More]";

otherwise;

stop the action;

end if;

if player consents

begin;

say "It's a book of contracts for enslavement, so consider looking up people you know have been enslaved here. [More]";

otherwise;

stop the action;

end if;

if player consents

begin;

say "Though there are other possibilities, you may find it most enlivening to look up yourself in the book; also perhaps your father, and any of the bells you are still curious about." instead;

otherwise;

stop the action;

end if.

Definition: the Translation Room is solved if the candle is not in Storage-Box. Definition: the Translation Room is unsolved if the candle is in Storage-Box.

Definition: a door is solved if it is unlocked. Definition: a door is unsolved if it is locked.

Definition: the Kitchen is solved if the feast is not in Storage-Box. Definition: the Kitchen is unsolved if the feast is in Storage-Box.

Definition: the Dining Hall is solved if the feast is not in Storage-Box. Definition: the Dining Hall is unsolved if the feast is in Storage-Box.

Definition: a grail is solved if it is not in Storage-Box. Definition: a grail is unsolved if it is in Storage-Box.

Instead of hinting about the miniature when the miniature is unseen:

say "What gave the Beast his beastly form was an incident from his personal history, not a part of his family's troubled dealings. Therefore it is not Lucrezia's magic that will help you with this, but whatever you can find out about his own history. [More]";

if the player consents, say "The Beast has some living rooms underground. If you explore these, you may find evidence of elements in his past that mattered to him, which you could then research further."

Instead of hinting about the miniature:

say "Obviously this is the picture of someone who is (or was) significant to the Beast. [More]";

if player consents, say "Perhaps some reference to her will appear in one of the castle's books or records. [More]";

otherwise stop the action;

if player consents, say "Of course, the only identifying sign you have is that green girdle. [More]";

otherwise stop the action;

if player consents, say "You could try looking the girdle up in the contract book."

Instead of hinting about the roses:

say "They have a pungent, sickly smell: from a distance it isn't so bad, almost pleasant at times, but up close it is nauseating. You've been given to understand that the strain was developed by Lucrezia herself."

Understand "rooms" or "places" as seeking room list. Seeking room list is an action out of world. Carry out seeking room list: say "Thus far you have visited [the list of visited rooms]."

Understand "objects" or "things" as seeking object list. Seeking object list is an action out of world. Carry out seeking object list: say "Thus far you have seen [a list of listable things]."

Definition: a thing is listable:

if it is the player, no;

if it is unseen, no;

if it explains something, yes;

if it requires something, yes;

if something requires it, yes;

if it is scenery, no;

yes.