Bronze — 40 of 46

Section 8 - Find (any object we have seen)

Understand "find [any pending thing]" as hunting. Hunting is an action applying to one visible thing. Carry out hunting: try hinting about the noun instead. Understand "look for [any pending thing]" as hunting. Understand "go to [any pending thing]" as hunting.

Instead of hunting the beast:

if the beast is deceased, say "You doubt you'll find him again unless you have the misfortune to meet in Hell.";

otherwise say "You will have to wander until you discover where he is."

Definition: a thing is pending:

if it is a ringer, no;

if it is in Storage-Box, yes;

no.

Understand "find [any seen thing]" as finding. Understand the command "seek" as "find". Understand "look for [any seen thing]" as finding. Understand "go to [any seen thing]" as finding.

Finding is an action applying to one visible thing.

Instead of finding the windchimes when the Rose Garden is unvisited: say "That's the trick, isn't it?"

Carry out finding:

if the player is carrying the noun

begin;

say "You're holding [the noun]!";

otherwise;

let place be the ultimate location of the noun;

if place is not a room and the noun is a door

begin;

let place be the front side of the noun;

if place is not visited, let place be the back side of the noun;

end if;

if place is a room and place is not the location

begin;

try approaching place;

if the noun is visible, stop the action;

end if;

if noun is a backdrop

begin;

say "That wasn't in one specific location.";

otherwise;

if the place is the location, say "You have [the noun] in front of you.";

otherwise say "[The noun] [are] gone.";

end if;

end if.