Zork — 8 of 13

Part 7 - Volcano Area

A note card is a thing. The description of the note card is "[agrippa text]".

The later appearance of the note card is "There is a card with writing on it here."

Understand "notecard" and "note-card" and "plain" as the note card.

To say agrippa text:

say "Warning:[line break]";

say "[4 spaces]This room was constructed over very weak rock strata. Detonation of explosives in this room is strictly prohibited![line break]";

say "[24 spaces]Frobozz Magic Cave Company[line break]";

say "[24 spaces] per M. Agrippa, foreman[line break]";

A gaudy crown is a thing. The later appearance of the crown is "The excessively gaudy crown of Lord Dimwit Flathead is here." The crown is wearable. The size of the crown is 10. After taking the crown: award 15 points; continue the action. The case-points of the crown is 10.

East of a dungeon called Volcano View is south of Egyptian Room. "You are on a ledge in the middle of a large volcano. Below you the volcano bottom can be seen and above is the rim of the volcano. A couple of ledges can be seen on the other side of the volcano;

it appears that this ledge is intermediate in elevation between those on the other side. The exit from this room is to the east."

Check going down from Volcano View:

say "I wouldn't try that." instead.

Check jumping while the location is Volcano View:

fatally leap instead.

The ascending staircase is a door. The ascending staircase is up from Egyptian Room. Through the ascending staircase is Glacier Room.

The ascending staircase is open and not openable. Check climbing the ascending staircase:

try entering the noun instead.

The ascending staircase is scenery.

Glacier Room is a dungeon. The description of Glacier Room is "This is a large room with giant icicles hanging from the walls and ceiling. There are passages to the north and east."

East of Glacier Room is Egyptian Room.

The mass of ice is a thing in Glacier Room. The mass of ice is fixed in place. Understand "glacier" as the mass of ice.

The initial appearance of the mass of ice is "A mass of ice fills the western half of the room.[if the mass of ice is off-stage] There is a large passageway leading westward.[end if]".

West of Egyptian Room is nowhere.

West of Glacier Room is south of a dungeon called Ruby Room.

The description of Ruby Room is "This is a small chamber behind the remains of the great glacier. To the south and west are small passageways."

A moby ruby is in Ruby Room.

West of Ruby Room is west of a dungeon called Lava Room. The description of Lava Room is "This is a small room, whose walls are formed by an old lava flow.

There are exits here to the west and the south."

South of Lava Room is a dungeon called Volcano Bottom. The description of Volcano Bottom is "You are at the bottom of a large dormant volcano. High above you

light may be seen entering from the cone of the volcano. The only

exit here is to the north."

In Volcano Bottom is an enterable open unopenable container called a basket. The later appearance of the basket is "There is a very large and extremely heavy wicker basket with a cloth bag here. Inside the basket is a metal receptacle of some kind.

Attached to the basket on the outside is a piece of wire." Understand "balloon" and "basket" and "wicker" as the basket. The capacity of the basket is 100. The size of the basket is 100. A metal receptacle is part of the basket. The metal receptacle is a container. It is closed and openable. The carrying capacity of the receptacle is 1. The capacity of the receptacle is 100.

A rope called a piece of braided wire is part of the basket. Understand "rope" as the braided wire.

Volcano Core is a dungeon. The description of Volcano Core is "You are about one hundred feet above the bottom of the volcano. The top of the volcano is clearly visible here."

A VolcanoLedge is a kind of dungeon.

Volcano Near Small Ledge is a dungeon. The description of Volcano Near Small Ledge is "You are about two hundred feet above the volcano floor. Looming

above is the rim of the volcano. There is a small ledge on the west

side."

Volcano Near Viewing Ledge is a dungeon. The description of Volcano Near Viewing Ledge is "You are high above the floor of the volcano. From here the rim of

the volcano looks very narrow and you are very near it. To the

east is what appears to be a viewing ledge, too thin to land on."

Volcano Near WideLedge is a dungeon. The description of Volcano Near WideLedge is "You are near the rim of the volcano which is only about 15 feet

across. To the west, there is a place to land on a wide ledge." The printed name of Volcano Near WideLedge is "Volcano Near Wide Ledge".

Narrow Ledge is a VolcanoLedge. The description of Narrow Ledge is "You are on a narrow ledge overlooking the inside of an old dormant volcano. This ledge appears to be about in the middle between the floor below and the rim above. There is an exit here to the south."

A small hook is in Narrow Ledge. The small hook is fixed in place. The small hook is unevenly shaped.

South of Narrow Ledge is a VolcanoLedge called Library. The description of Library is "This is a room which must have been a large library, probably for the royal family. All of the shelves appear to have been gnawed to pieces by unfriendly gnomes. To the north is an exit."

A priceless zorkmid is in Narrow Ledge. The initial appearance of the priceless zorkmid is "On the floor is a gold zorkmid coin (a valuable collector's item)."

The later appearance of the priceless zorkmid is "There is an engraved zorkmid coin here."

Understand "gold" and "engraved" and "coin" as the zorkmid.

The size of the zorkmid is 10.

After taking the zorkmid for the first time:

award 10 points; continue the action.

The case-points of the zorkmid is 12.

The description of the priceless zorkmid is "[zorkmid text]".

To say zorkmid text:

say fixed letter spacing;

say line break;

say " --------------------------[line break]";

say " / Gold Zorkmid \\[line break]";

say " / T e n T h o u s a n d \\[line break]";

say " / Z O R K M I D S \\[line break]";

say " / \\[line break]";

say " / |||||||||||||||||| \\[line break]";

say " / !|||| ||||! \\[line break]";

say " | ||| ^^ ^^ ||| |[line break]";

say " | ||| OO OO ||| |[line break]";

say " | In Frobs ||| << ||| We Trust |[line break]";

say " | || (______) || |[line break]";

say " | | | |[line break]";

say " | |__________| |[line break]";

say " \\ /[line break]";

say " \\ -- Lord Dimwit Flathead -- /[line break]";

say " \\ -- Beloved of Zorkers -- /[line break]";

say " \\ /[line break]";

say " \\ * 722 G.U.E. * /[line break]";

say " \\ /[line break]";

say " --------------------------[line break]";

say variable letter spacing.

In Library is a closed openable container called a blue book. The later appearance of the blue book is "There is a blue book here." The description of the blue book is "This book is written in a tongue with which I am unfamiliar." The blue book is inflammable.

The capacity of the blue book is 2. The size of the blue book is 10.

In Library is a closed openable container called a green book. The later appearance of the green book is "There is a green book here." The description of the green book is "This book is written in a tongue with which I am unfamiliar." The green book is inflammable.

The capacity of the green book is 2. The size of the green book is 10.

In Library is a closed openable container called a white book. The later appearance of the white book is "There is a white book here." The description of the white book is "This book is written in a tongue with which I am unfamiliar." The white book is inflammable.

The capacity of the white book is 2. The size of the white book is 10.

In Library is a closed openable container called a purple book. The later appearance of the purple book is "There is a purple book here." The description of the purple book is "This book is written in a tongue with which I am unfamiliar." The purple book is inflammable.

The capacity of the purple book is 2. The size of the purple book is 10.

In the purple book is a Flathead stamp. The description of the stamp is "[flathead text]".

The size of the Flathead stamp is 1.

After taking the Flathead stamp:

award 4 points.

The case-points of the Flathead stamp is 10.

To say flathead text:

say fixed letter spacing;

say "---v----v----v----v----v----v----v----v---[line break]";

say "| |[line break]";

say "| |||||||||| LORD |[line break]";

say "> !|||| | DIMWIT <[line break]";

say "| |||| ---| FLATHEAD |[line break]";

say "| |||C CC \\ |[line break]";

say "> |||| _\\ <[line break]";

say "| ||| (____| |[line break]";

say "| || | |[line break]";

say "> |______| Our <[line break]";

say "| / \\ Excessive |[line break]";

say "| / \\ Leader |[line break]";

say "> | | <[line break]";

say "| | | |[line break]";

say "| |[line break]";

say "> G.U.E. POSTAGE 3 Zorkmids <[line break]";

say "| |[line break]";

say "---^----^----^----^----^----^----^----^---[line break]";

say variable letter spacing.

Wide Ledge is a VolcanoLedge. The description of Wide Ledge is "You are on a wide ledge high into the volcano. The rim of the volcano is about 200 feet above and there is a precipitous drop below to the bottom. There is a small door to the south."

Check jumping while the location is Wide Ledge: fatally leap instead.

Check jumping while the location is Narrow ledge: fatally leap instead.

A tiny hook is in Wide Ledge. The tiny hook is fixed in place. The tiny hook is unevenly shaped.

South of Wide Ledge is a VolcanoLedge called Dusty Room. The description of Dusty Room is "You are in a dusty old room which is virtually featureless, except

for an exit on the north side."

A closed unopenable container called a rusty old box is in Dusty Room. The rusty old box is fixed in place. The initial appearance of the rusty old box is "[if closed]Embedded in the far wall, there is a rusty old box. It appears that the box is somewhat damaged, since an oblong hole has been chipped out of the front of it.[otherwise]On the far wall is a rusty box, whose door has been blown off.[end if]".

An open unopenable container called an oblong hole is part of the rusty old box.

The capacity of the oblong hole is 15. The carrying capacity of the oblong hole is 1.

Does the player mean inserting the brick into the oblong hole: it is very likely.

After taking the moby ruby for the first time:

award 15 points; continue the action.

The case-points of the moby ruby is 8.

The initial appearance of the moby ruby is "On the floor lies a moby ruby."

The later appearance of the moby ruby is "There is a moby ruby lying here."

Check going west from Glacier Room when the player can see the mass of ice:

say "A mass of ice fills the western half of the room." instead.

Before throwing the ivory torch at the mass of ice:

say "The torch hits the glacier and explodes into a great ball of flame, devouring the glacier. The water from the melting glacier rushes downstream, carrying the torch with it. In place of the glacier, there is a passageway leading west.";

remove the mass of ice from play;

now the printed name of the ivory torch is "burned-out ivory torch";

now the ivory torch is not lit;

move the ivory torch to Stream View;

now the ivory torch is non-flaming instead.

Before dropping the ivory torch when the player's command includes "throw":

try throwing the ivory torch at the mass of ice instead.

Understand "burned-out" and "burned out" as the ivory torch when the ivory torch is not lit.

North of Glacier Room is north of a room called Stream View.

The description of Stream View is "You are standing on a path beside a gently flowing stream. The path travels to the north and the east."

A nondrainable watersource called the pdl2 is in Stream View.

A dungeon called In Stream is dark. The description of In Stream is "You are on the gently flowing stream. The upstream route is too narrow to navigate and the downstream route is invisible due to twisting walls. There is a narrow beach to land on."

Check going up from In Stream: say "The way is too narrow." instead.

Check going north from Glacier Room: move the player to Stream View instead.

A coil of thin shiny wire is in Stream View.

Understand "fuse" as the coil of wire. Understand "string" as the coil of wire.

The printed name of the coil of thin shiny wire is "wire coil".

The wire coil is inflammable.

The size of the wire coil is 1.

Check inserting the coil of wire into the brick:

say "You insert the fuse into the brick.";

now the coil of wire is part of the brick instead.

[Procedural rule when taking the coil of wire:

ignore the can't take component parts rule.]

Check putting the coil of wire on the brick:

say "You insert the fuse into the brick.";

now the coil of wire is part of the brick instead.

The later appearance of the coil of wire is "There is a coil of thin shiny wire here."

East of Stream View is Reservoir South. Check going west from Reservoir South:

move the player to Stream View instead.

Up from Reservoir South is northwest of a dungeon called Deep Canyon.

South of Deep Canyon is northwest of Round Room. "You are on the south edge of a deep canyon. Passages lead off to the east, south, and northwest. You can hear the sound of flowing water below."

Check going northwest from Deep Canyon when the player is carrying the coffin:

say "The passage is too steep for carrying the coffin." instead.

Check going up from Deep Canyon when the player is carrying the coffin:

say "The stairs are too steep for carrying the coffin." instead.

Southeast of Round Room is a dungeon called Winding Passage. The description of Winding Passage is "This is a winding passage. It seems that there is only an exit on the east end, although the whirring from the round room can be heard faintly to the north."

Northwest of Winding Passage is nowhere.

East of Winding Passage is a dungeon called Mirror Room No 1. The printed name of Mirror Room No 1 is "Mirror Room". The description of Mirror Room No 1 is "This is a large square room with tall ceilings. On the south wall is an enormous mirror which fills the entire wall. There are exits on the other three sides of the room."

An enormous mirror is in Mirror Room No 1. It is scenery.

The description of the enormous mirror is "[if the enormous mirror is whole]There is an ugly person staring back at you.[otherwise]The mirror is broken into many pieces.[end if]".

Instead of touching or rubbing the enormous mirror:

say "There is a rumble from deep within the earth and the room shakes.";

move the player to Mirror Room No 2.

Every turn when the player is not in the basket:

if the basket is in a VolcanoLedge for at least two turns and the braided wire has not been attached to a nonrope thing begin;

say "The balloon floats away. It seems to be ascending, due to its light load.";

remove the basket from play;

end if.

Does the player mean tying the braided wire to something: it is very likely.

Does the player mean tying something to the braided wire: it is very likely.

Every turn when the player is in the basket and the player's command does not include "launch":

if something flaming is in the receptacle begin;

if the receptacle is open begin;

if the basket is in Volcano Near WideLedge begin;

say "Your balloon has hit the rim of the volcano, ripping the cloth and

causing you a 500 foot drop. Did you get your flight insurance?";

end the game in death;

else if the basket is in Volcano Near Viewing Ledge;

move the basket to Volcano Near WideLedge;

try looking;

else if the basket is in Volcano Near Small Ledge;

move the basket to Volcano Near Viewing Ledge;

try looking;

else if the basket is in Volcano Core;

move the basket to Volcano Near Small Ledge;

try looking;

else if the basket is in Volcano Bottom;

move the basket to Volcano Core;

try looking;

end if;

else;

if the basket is in Volcano Near WideLedge begin;

move the basket to Volcano Near Viewing Ledge;

try looking;

else if the basket is in Volcano Near Viewing Ledge;

move the basket to Volcano Near Small Ledge;

try looking;

else if the basket is in Volcano Near Small Ledge;

move the basket to Volcano Core;

try looking;

else if the basket is in Volcano Core;

say "The balloon has landed.";

move the basket to Volcano Bottom;

try looking;

end if;

end if;

else;

if the basket is in Volcano Near WideLedge begin;

move the basket to Volcano Near Viewing Ledge;

try looking;

else if the basket is in Volcano Near Viewing Ledge;

move the basket to Volcano Near Small Ledge;

try looking;

else if the basket is in Volcano Near Small Ledge;

move the basket to Volcano Core;

try looking;

else if the basket is in Volcano Core;

say "You have landed, but the balloon did not survive.";

remove the basket from play;

end if;

end if;

if the basket has been in Wide Ledge for at least 2 turns and the braided wire is not attached to a nonrope thing begin;

say "The balloon leaves the ledge.";

move the basket to Volcano Near WideLedge;

else if the basket has been in Narrow Ledge for at least 2 turns and the braided wire is not attached to a nonrope thing;

say "The balloon leaves the ledge.";

move the basket to Volcano Near Small Ledge;

end if.