Zork — 6 of 13

Part 5 - The Round Room, Temple, and Alice Area

West of a dungeon called East-West Passage is north of Troll Room. "This is a narrow east-west passageway. There is a narrow stairway leading down at the north end of the room."

The rval of East-West Passage is 5.

North of East-West Passage is a dungeon called Deep Ravine. Down from East-West Passage is Deep Ravine.

The description of Deep Ravine is "This is a deep ravine at a crossing with an east-west crawlway. Some stone steps are at the south of the ravine, and a steep staircase descends."

Down from Deep Ravine is south from a dungeon called Reservoir South. The description of Reservoir South is "[if the pdl1 is on-stage]This is a long room on the south shore of a large reservoir.[otherwise]You are in a long room, to the north of which was formerly a reservoir.[end if] There is a western exit, a passageway south, and a steep pathway climbing up along the edge of a cliff."

A drainable watersource called the pdl1 is in Reservoir South.

Check going down from Deep Ravine when the player is carrying the coffin:

say "The stairs are to steep for you with your burden." instead.

East of East-West Passage is a dungeon called the Round Room. The description of the Round Room is "This is a circular room with passages off in eight directions."

Southwest of Round Room is Maze 1. Northeast of Maze 1 is nowhere.

After going:

if the location is Round Room and rotation room is 1, say "Your compass needle spins wildly, and you cannot get your bearings."; continue the action.

Check going nowhere from Round Room when rotation room is 1: try going east instead.

Check going from the Round Room when rotation room is 1:

say "Unfortunately, it is impossible to tell directions in here.";

move the player to a random adjacent room instead.

A dungeon called the Grail Room is east of the Round Room. "You are standing in a small circular room with a pedestal. A set of stairs leads up, and passages leave to the east and west."

An open container called a grail is here. "There is an extremely valuable (perhaps original) grail here."

The grail is not openable.

The size of the grail is 10.

The capacity of the grail is 5.

Understand "holy grail" as the grail. The case-points of the grail is 5.

After taking the grail for the first time: award 2 points; continue the action.

East of Grail Room is north of a dungeon called Narrow Crawlway. The description of Narrow Crawlway is "This is a narrow crawlway. The crawlway leads from north to south. However, the south passage divides to the south and southwest."

West of a dungeon called Temple is up from Grail Room. "This is the west end of a large temple. On the south wall is an ancient inscription, probably a prayer in a long-forgotten language. The north wall is solid granite. The entrance at the west end of the room is through huge marble pillars."

A scenery thing called the inscription is in Temple. Understand "prayer" as the inscription. The description of the inscription is "The prayer is inscribed in an ancient script which is hardly remembered these days, much less understood. What little of it can be made out seems to be a diatribe against small insects, absent-mindedness, and the picking up and dropping of small objects. The final verse seems to consign trespassers to the land of the dead. All evidence indicates that the beliefs of the ancient Zorkers were obscure."

A bell called a small brass bell is in Temple.

A dungeon called Altar is east of Temple. "This is the east end of a large temple. In front of you is what appears to be an altar."

A pair of candles is here. "On the two ends of the altar are burning candles."

The candles are flaming.

The later appearance of the pair of candles is "There are two candles here."

A large black book is here. "On the altar is a large black book, open to page 569."

Understand "bible" and "good book" and "goodbook" as the book.

The description of the black book is "[book text]".

The size of the black book is 10.

To say book text:

say fixed letter spacing;

say " Commandment #12592[line break]";

say "Oh ye who go about saying unto each other: 'Hello sailor':[line break]";

say "Dost thou know the magnitude of thy sin before the gods?[line break]";

say "Yea, verily, thou shalt be ground between two stones.[line break]";

say "Shall the angry gods cast thy body into the whirlpool?[line break]";

say "Surely, thy eye shall be put out with a sharp stick![line break]";

say "Even unto the ends of the earth shalt thou wander and[line break]";

say "unto the land of the dead shalt thou be sent at last.[line break]";

say "Surely thou shalt repent of thy cunning.";

say variable letter spacing.

South of Round Room is a dungeon called Engravings Cave. The description of Engravings cave is "You have entered a cave with passages leading north and southeast.

There are old engravings on the walls here."

The old engravings is a thing in Engravings Cave. The old engravings is scenery.

The description of the old engravings is "The engravings were incised in the living rock of the cave wall by an unknown hand. They depict, in symbolic form, the beliefs of the ancient peoples of Zork. Skillfully interwoven with the bas reliefs are excerpts illustrating the major tenets expounded by the sacred texts of the religion of that time. Unfortunately, a later age seems to have considered them blasphemous and just as skillfully excised them."

Southeast of Engravings Cave is down from a dungeon called Riddle Room.

The description of Riddle Room is "[riddle text]".

To say riddle text:

say "This is a room which is bare on all sides. There is an exit down. To the east is a great door made of stone. Above the door, the following words are written: 'No man shall enter this room without solving this riddle--[paragraph break]";

say " What is tall as a house,[line break]";

say " Round as a cup,[line break]";

say " And all the king's horses can't draw it up?'.[paragraph break]";

say "(Reply via [']ANSWER 'answer'['].)".

The great door is a door. The great door is closed and not openable. The great door is scenery. East of Riddle Room is the great door.

West of a dungeon called Pearl Room is the great door.

The description of Pearl Room is "This is a former broom closet. The exits are to the east and west."

A pearl necklace is here. Understand "pearls" as the pearl necklace.

The later appearance of the pearl necklace is "There is a pearl necklace here with hundreds of large pearls."

The pearl necklace is wearable. The description of the pearl necklace is "This is a pearl necklace with hundreds of large pearls."

After taking the necklace for the first time:

award 9 points; continue the action.

The case-points of the necklace is 5.

The size of the necklace is 5.

West of a dungeon called Circular Room is Pearl Room.

Check opening the unopenable great door: say "The door cannot be opened." instead.

The description of Circular Room is "This is a damp circular room, whose walls are made of brick and mortar. The roof of this room is not visible, but there appear to be some etchings on the walls. There is a passageway to the west."

An enterable container called the wooden bucket is here.

The initial appearance of the wooden bucket is "There is a wooden bucket here, three feet in diameter and three feet high."

The later appearance of the wooden bucket is "There is a wooden bucket here, three feet in diameter and three feet high."

The wooden bucket is fixed in place.

Check taking the quantity of water while in the bucket:

if the bottle is closed, say "The bottle is closed." instead;

now the quantity of water is in the bottle;

say "The bottle is now full of water.";

say "The bucket descends and comes to a stop.";

move the bucket to Circular Room;

try looking instead.

Check entering the wooden bucket when the quantity of water is in the bucket and the player is in Circular Room:

say "The bucket rises and comes to a stop.";

move the bucket to Top of Well;

move the player to the bucket, without printing a room description instead.

The rval of Top of Well is 10.

Check entering the wooden bucket when the quantity of water is in the bottle and the player is in Top of Well:

say "The bucket descends and comes to a stop.";

move the bucket to Circular Room;

move the player to the bucket, without printing a room description instead.

Top of Well is a dungeon. Top of Well is up from Circular Room.

Check going up from Circular Room:

say "The walls cannot be climbed." instead.

The description of Top of Well is "You are at the top of the well. Well done. There are etchings on the side of the well. There is a small crack across the floor at the entrance to a room on the east, but it can be crossed easily."

Check taking the bucket: say "Playing with the bucket in this manner doesn't seem to be accomplishing anything." instead.

The etchings is a backdrop.

The etchings is in Circular Room and Top of Well.

The description of the etchings is "[bucket text]".

To say bucket text:

say fixed letter spacing;

if the player is in Circular Room begin;

say " o b o[line break][line break]";

say " A G I[line break]";

say " E L[line break][line break]";

say " m p a[line break]";

else;

say " o b o[line break]";

say " r z[line break]";

say " f M A G I C z[line break]";

say " c W E L L y[line break]";

say " o n[line break]";

say " m p a[line break]";

end if;

say variable letter spacing.

Check going down from Top of Well: say "It's a long way down." instead.

Check jumping while the location is Top of Well: fatally leap instead.

Check kicking the bucket: say "If you insist."; end the game in death instead.

[Ha ha get it]

East of Top of Well is a dungeon called Tea Room.

The description of Tea Room is "This is a small square room, in the center of which is a large oblong table, no doubt set for afternoon tea. It is clear from the objects on the table that the users were indeed mad. In the eastern corner of this room is a small hole no more than four inches high."

A large oblong table is here. The table is scenery.

A piece of eat-me cake is in Tea Room.

The initial appearance of the piece of eat-me cake is "There is a piece of cake here with the words 'Eat-Me' on it."

The later appearance of the piece of eat-me cake is "There is a piece of cake here with the words 'Eat-Me' on it."

Understand "eatme cake" and "eat me cake" as the eat-me cake.

The size of the eat-me cake is 10.

The size of the blue cake is 4.

The size of the orange cake is 4.

The size of the red cake is 4.

A red cake is in Tea Room.

The printed name of the red cake is "piece of cake with red icing". Understand "piece of cake" and "piece of cake with red icing" and "piece of red cake" as the red cake.

An orange cake is in Tea Room.

The printed name of the orange cake is "piece of cake with orange icing". Understand "piece of cake" and "piece of cake with orange icing" and "piece of orange cake" as the orange cake.

A blue cake is in Tea Room.

The printed name of the blue cake is "piece of cake with blue (ecch) icing". Understand "piece of cake" and "piece of cake with blue icing" and "piece of blue cake" as the blue cake.

The red cake, the blue cake, and the eat-me cake are edible.

The description of the red cake is "The only writing visible is a capital E. The rest is too small to be clearly visible."

The description of the orange cake is "The only writing visible is a capital E. The rest is too small to be clearly visible."

The description of the blue cake is "The only writing visible is a capital E. The rest is too small to be clearly visible."

After reading a command:

if the player's command includes "cakes", replace the matched text with "both cake".

After eating the orange cake when the player is in Tea Room or the player is in Pool Room or the player is in Posts Room: say "You have been blasted to smithereens (whatever they are)."; end the game in death.

Check eating the blue cake when the player is in Tea Room or the player is in Pool Room:

say "The room around you seems to be getting smaller.[line break]The room seems to have become too small to hold you. It seems that the walls are not as compressible as your body, which is more or less demolished.";

end the game in death instead.

A dungeon called Low Room is northwest of Tea Room. "This is a room with a low ceiling which is circular in shape. There are exits to the east and southeast."

A person called a robot is here.

A green piece of paper is here.

Understand "robby" and "r2-d2" and "c-3po" and "r2d2" and "c3po" as the robot.

The description of the green paper is "[instruction text]".

The green paper is inflammable.

To say instruction text:

center "!!!! FROBOZZ MAGIC ROBOT COMPANY !!!!";

say paragraph break;

say "Hello, master![paragraph break]";

say " I am a late-model robot, trained at MIT Tech to perform various simple housekeeping functions.[paragraph break]";

say "Instructions for use:[paragraph break]";

say fixed letter spacing;

say " To activate me, use the following formula--[line break]";

say " TELL ROBOT 'something to do' (cr)[line break]";

say " The quotation marks are mandatory.[paragraph break]";

say variable letter spacing;

say "Warranty:[paragraph break]";

say " No warranty is expressed or implied.[paragraph break]";

say " At your service!".

The description of the eat-me cake is "The icing spells out Eat Me."

After eating the red cake:

if the player is in Tea Room or the player is in Pool Room or the player is in Posts Room begin;

say "That was delicious, but your dying memory is of feeling horribly dehydrated and thirsty.";

end the game in death;

else;

continue the action;

end if;

A persuasion rule for asking the robot to try doing something:

persuasion succeeds.

Instead of asking the robot to try eating or drinking something:

say "'I am sorry but that action is difficult for a being with no mouth.'".

The block giving rule is not listed in any rulebook.

After giving something to the robot: say "The robot gladly takes [the noun] and nods his head-like appendage in thanks."

After reading a command:

if the player's command includes "tell robot", replace the matched text with "robot,";

if the player's command includes "tell robby", replace the matched text with "robot,";

if the player's command includes "tell r2-d2", replace the matched text with "robot,";

if the player's command includes "tell r2d2", replace the matched text with "robot,";

if the player's command includes "tell c-3po", replace the matched text with "robot,";

if the player's command includes "tell c3po", replace the matched text with "robot,".

Check giving the quantity of water to the robot:

say "The water slips through his fingers.";

remove the water from play instead.

Check throwing something at the robot:

say "The robot is injured (being of shoddy construction) and falls to the floor in a pile of garbage, which disintegrates before your eyes.";

remove the robot from play instead.

Check attacking the robot:

say "The robot is injured (being of shoddy construction) and falls to the floor in a pile of garbage, which disintegrates before your eyes.";

remove the robot from play instead.

Check attacking the robot with something:

try attacking the noun instead.

Check dropping the orange cake:

if the player's command includes "throw" and the player is in Tea Room or the player is in Pool Room or the player is in Posts Room begin;

say "You have been blasted to smithereens (whatever they are).";

end the game in death instead;

else;

continue the action;

end if.

Check throwing the orange cake at something:

if the player is in Tea Room or the player is in Pool Room or the player is in Posts Room begin;

say "You have been blasted to smithereens (whatever they are).";

end the game in death instead;

else;

continue the action;

end if.

Check answering the robot that something: say "'I am only a stupid robot and cannot perform that command.'" instead.

Instead of asking the robot to try doing something other than going, taking, dropping, inserting it into, pushing, turning, giving, or lifting:

say "'I am only a stupid robot and cannot perform that command.'".

Instead of asking the robot to try doing something when dead flag is false:

say "'Whirr, buzz, click!'"; continue the action.

East of Low Room is a dungeon called Machine Room.

The description of Machine Room is "This is a large room full of assorted heavy machinery. The room smells of burned resistors. The room is noisy from the whirring sounds of the machines. Along one wall of the room are three buttons which are, respectively, round, triangular, and square. Naturally, above the buttons are instructions

written in EBDIC. A large sign above all the buttons says in English:[paragraph break][fixed letter spacing]

DANGER: HIGH VOLTAGE[paragraph break][variable letter spacing]There are exits to the west and the south."

The round button is a thing in Machine Room. The round button is scenery.

The square button is a thing in Machine Room. The square button is scenery.

The triangular button is a thing in Machine Room. The triangular button is scenery.

After reading a command:

if the player's command includes "buttons", replace the matched text with "both button".

Pushing the round button is getting fried. Pushing the square button is getting fried. Pushing the triangular button is getting fried.

Instead of getting fried:

say "There is a giant spark, and you are fried to a crisp.";

end the game in death.

Instead of the robot pushing:

if the noun is the triangular button and box flag is false begin;

say "A dull thump is heard in the distance.";

award 10 points;

now rotation room is rotation room times -1;

now box flag is true;

move the dented steel box to Round Room;

rule succeeds;

else if the noun is the triangular button;

say "Click.";

now rotation room is rotation room times -1;

rule succeeds;

else if the noun is the square button and rotation speed is -1;

say "Nothing seems to happen.";

rule succeeds;

else if the noun is the square button;

say "The whirring increases in intensity slightly.";

now rotation speed is -1;

rule succeeds;

else if the noun is the round button and rotation speed is 1;

say "Nothing seems to happen.";

rule succeeds;

else if the noun is the round button;

say "The whirring decreases in intensity slightly.";

now rotation speed is 1;

rule succeeds;

else;

continue the action;

end if.

After going:

if the location is Low Room and rotation speed is -1 and rotation room is -1 begin;

say "According to Prof. TAA of MIT Tech, the rapidly changing magnetic fields in the room are so intense as to cause you to be electrocuted. I really don't know, but in any event, something just killed you.";

end the game in death;

else if the location is Low Room and rotation room is -1;

say "Your compass needle spins wildly, and you cannot get your bearings.";

end if;

continue the action.

Check going from Low Room when rotation room is -1:

say "Unfortunately, it is impossible to tell directions in here.";

move the player to a random adjacent room instead.

Check going nowhere from Low Room when rotation room is -1: try going east instead.

After the robot going:

if the robot is in Low Room and rotation speed is -1 and rotation room is -1 begin; say "According to Prof. TAA of MIT Tech, the rapidly changing magnetic fields in the room are so intense as to fry all the delicate innards of the robot. I really don't know, but in any event, smoke is coming out of its ears, and it has stopped moving."; remove the robot from play; else; continue the action; end if.

Box flag is a truth state variable. Box flag is usually false.

The capacity of the dented steel box is 20.

The size of the dented steel box is 40.

The dented steel box is a closed openable container. In the dented steel is a fancy violin.

Understand "stradivarius" and "strad" as the fancy violin.

The later appearance of the fancy violin is "There is a Stradivarius here."

After taking the violin for the first time: award 11 points; continue the action.

The case-points of the violin is 10.

The size of the violin is 10.

After eating the eat-me cake while the location is Tea Room:

say "Suddenly, the room appears to have become very large.";

repeat with item running through things in Tea Room begin;

if the item is not the robot and the item is not the table and the item is not a backdrop, move the item to Posts Room;

end repeat.

After eating the blue cake while the location is Posts Room:

say "Suddenly, the room appears to have become very small.";

repeat with item running through things in Posts Room begin;

if the item is not a backdrop, move the item to Tea Room;

end repeat.

Pool Room is a dark room. Posts Room is a dark room.

The description of Posts Room is "This is an enormous room, in the center of which are four wooden posts delineating a rectangular area, above which is what appears to be a wooden roof. In fact, all objects in this room appear to be abnormally large. To the east is a passageway. There is a large chasm on the west and the northwest."

Check going east from Tea Room: say "Only a mouse could get in there." instead.

Check going northwest while the location is Posts Room: say "There is a chasm too wide to jump across." instead.

Check going west while the location is Posts Room: say "There is a chasm too wide to jump across." instead.

Check jumping while the location is Posts Room: fatally leap instead.

East of Posts Room is Pool Room. The description of Pool Room is "This is a large room, one half of which is depressed. [if the leak is in Pool Room]There is a large leak in the ceiling through which brown colored goop is falling. The leak has submerged the depressed area in a pool of sewage. [end if]The only exit from this room is to the west."

The leak is a thing in Pool Room. The leak is scenery.

The tin of rare spices is a thing. After taking the tin of spices for the first time: award 5 points; continue the action.

The case-points of the tin of rare spices is 5.

The size of the tin of spices is 8.

Check throwing the red cake at the leak:

say "The pool of water evaporates, revealing a tin of rare spices.";

remove the leak from play;

move the tin of rare spices to Pool Room instead.

Check dropping the red cake when the player's command includes "throw":

try throwing the red cake at the leak instead.

Check inserting the red cake into the leak:

try throwing the red cake at the leak instead.

Understand "pool" and "pool of sewage" and "pool of water" as the leak.

A flask is in Pool Room. "A flask is filled with some clear liquid is here."

Destroying the flask with something is getting poisoned. Destroying the flask is getting poisoned. Opening the flask is getting poisoned. Throwing the flask at something is getting poisoned.

Instead of getting poisoned:

say "Just before you pass out, you notice that the vapors from the

flask's contents are fatal.";

end the game in death.

Check dropping the flask when the player's command includes "throw":

try destroying the flask with your bare hands instead.

The size of the flask is 10.

South of Machine Room is a dark room called Dingy Closet. The description of Dingy Closet is "This is a dingy closet adjacent to the machine room. On one wall is a small sticker which reads:[sticker text]".

To say sticker text:

center "Protected by";

center "FROBOZZ";

center "Magic Alarm Company";

center "(Hello, footpad!)".

A white crystal sphere is in Dingy Closet.

Check searching the blue crystal sphere: try examining the noun instead.

The later appearance of the white crystal sphere is "There is a beautiful white crystal sphere here."

The description of the white crystal sphere is "[white sphere text]".

To say white sphere text:

if the blue crystal sphere is in something which is hiding begin;

say "You see only darkness.";

else;

say "As you peer into the sphere, a strange vision takes shape of

a distant room, which can be described clearly....[paragraph break]";

say "[description of the location of the blue crystal sphere][paragraph break]";

say "The vision fades, revealing only an ordinary crystal sphere.";

end if.

Check searching the blue crystal sphere: try examining the noun instead.

Understand "PALANTHIR" and "STONE" and "SEEING" and "GLASS" and "BALL" as the white crystal sphere.

The size of the white crystal sphere is 10.

After taking the white crystal sphere for the first time: award 6 points; continue the action.

The case-points of the white crystal sphere is 6.

Check asking the robot to try taking the sphere when the sphere is in Dingy Closet and cage solved is false:

say "As the robot reaches for the sphere, a steel cage falls from the

ceiling. The robot attempts to fend it off, but is trapped below it.

Alas, the robot short-circuits in his vain attempt to escape, and

crushes the sphere beneath him as he falls to the floor.";

remove the robot from play;

remove the sphere from play instead.

Cage solved is a truth state variable. Cage solved is usually false.

Check taking the sphere when the player is in Dingy Closet:

if cage solved is true, continue the action;

say "As you reach for the sphere, a steel cage falls from the ceiling to entrap you. To make matters worse, poisonous gas starts coming into the room.";

if the player cannot see the robot begin;

say "Time passes...and you die from some obscure poisoning.";

end the game in death instead;

else;

move the player to Cage;

move the robot to Cage instead;

end if.

Cage is a dark room. The description of Cage is "You are trapped inside a steel cage."

Check asking the robot to try going down from Top of Well:

say "Whirr, buzz, click![paragraph break]The robot is unable to do that." instead.

The steel cage is a thing in Cage. The steel cage is scenery.

Instead of asking the robot to try lifting or taking the steel cage:

say "Whirr, buzz, click![paragraph break]The cage shakes and is hurled across the room.";

now everything which is in the location which is not scenery is in Dingy Closet;

now cage solved is true;

move the mangled steel cage to Dingy Closet.

The mangled steel cage is a thing. The size of the mangled steel cage is 60.