Zork — 12 of 13

Part 11 - Old Man River, That Old Man River

Down from Flood Control Dam #3 is a room called Dam Base. The description of Dam Base is "You are at the base of Flood Control Dam #3, which looms above you

and to the north. The river Frigid is flowing by here. Across the river are the White Cliffs which seem to form a giant wall stretching from north to south along the east shore of the river as it winds its way downstream."

A broken sharp stick is in Dam Base. The initial appearance of the broken sharp stick is "A sharp stick, which appears to have been broken at one end, is here."

The later appearance of the broken sharp stick is "There is a broken sharp stick here."

The size of the broken sharp stick is 3.

The pile of plastic is inflammable. The magic boat is inflammable. The dboat is inflammable.

A pile of plastic is in Dam Base. The later appearance of the pile of plastic is "There is a folded pile of plastic here which has a small valve

attached." The size of the pile of plastic is 20. Understand "boat" as the pile of plastic.

A dboat is a thing. The printed name of the dboat is "plastic boat (with hole)". Understand "pile" and "boat" and "plastic" as the dboat.

Carry out plugging the dboat with the viscous material:

say "Well done. The boat is repaired.";

move the pile of plastic to the holder of the dboat;

remove the dboat from play.

A magic boat is a vehicle. Understand "plastic" and "raft" and "seaworthy" as the magic boat. The later appearance of the magic boat is "There is an inflated boat here." The size of the magic boat is 20. The capacity of the magic boat is 100.

Carry out inflating it with:

say "The boat inflates and appears seaworthy.";

now the magic boat is in the holder of the pile of plastic;

remove the pile of plastic from play.

Check entering the boat when the player is carrying the sharp stick:

say "There is a hissing sound and the boat deflates.";

move the dboat to the holder of the boat;

remove the boat from play instead.

Definition: a room is offroad if it does not contain a nondrainable watersource.

Check going by the magic boat when the player is in somewhere offroad:

say "You can't go there in a magic boat." instead.

The tan label is inflammable.

A tan label is in the magic boat. Understand "fine print" and "fineprint" as the tan label. The description of the tan label is "[tan label text]".

To say tan label text:

center "!!!! FROBOZZ MAGIC BOAT COMPANY !!!!";

say paragraph break;

say "Hello, Sailor![paragraph break]";

say "Instructions for use:[paragraph break]";

say "[four spaces]To get into boat, type 'BOARD BOAT'[line break]";

say "[four spaces]To leave boat, say 'DISEMBARK'[paragraph break]";

say "[four spaces]To get into a body of water, say 'LAUNCH'[paragraph break]";

say "[four spaces]To get to shore, say 'LAND'[paragraph break]";

say "This boat is guaranteed against all defects in parts and

workmanship for a period of 76 milliseconds from date of purchase or

until first used, whichever comes first.[paragraph break]";

say "WARNING: This boat is made of plastic.[paragraph break]";

say "Good Luck!".

A river is a kind of room. The printed name of a river is usually "Frigid River". Check going up from a river: say "You cannot go upstream due to strong currents." instead.

East of Dam Base is a river called River1. The description of River1 is "You are on the River Frigid in the vicinity of the Dam. The river flows quietly here. There is a landing on the west shore."

A nondrainable watersource called the pdl5 is in River1.

Down from River1 is a river called River2. The description of River2 is "The River turns a corner here making it impossible to see the

Dam. The White Cliffs loom on the east bank and large rocks prevent

landing on the west."

A nondrainable watersource called the pdl6 is in River2.

Down from River2 is a river called River3. The description of River3 is "The river descends here into a valley. There is a narrow beach on

the east below the cliffs and there is some shore on the west which may be suitable. In the distance a faint rumbling can be heard."

A nondrainable watersource called the pdl7 is in River3.

Down from River3 is a river called River4. The description of River4 is "The river is running faster here and the sound ahead appears to bethat of rushing water. On the west shore is a sandy beach. A small area of beach can also be seen below the Cliffs."

A nondrainable watersource called the pdl8 is in River4.

Down from River4 is a river called River5. The description of River5 is "The sound of rushing water is nearly unbearable here. On the west

shore is a large landing area."

A nondrainable watersource called the pdl9 is in River5.

Down from River5 is a dungeon called Moby Lossage.

The rusty iron key is in Moby Lossage. The initial appearance of the rusty iron key is " ".

Every turn when the magic boat is in Moby Lossage and the player is in the magic boat: say "Unfortunately, a rubber raft doesn't provide much protection from the unfriendly sorts of rocks and boulders one meets at the bottom of many waterfalls. Including this one."; end the game in death; remove the magic boat from play.

A closed openable container called a red buoy is in River4. The initial appearance of the red buoy is "There is a red buoy here (probably a warning)."

The capacity of the buoy is 20. The size of the buoy is 10.

A large emerald is in the buoy. After taking the emerald: award 5 points; continue the action.

The case-points of the emerald is 10.

Check going east from River2: say "The White Cliffs prevent your landing here." instead.

South of Tiny Cave is northwest of a room called Rocky Shore. The description of Rocky Shore is "You are on the west shore of the river. An entrance to a cave is

to the northwest. The shore is very rocky here."

East of Rocky Shore is River3.

WCLF1 is a room. The description of WCLF1 is "You are on a narrow strip of beach which runs along the base of the White Cliffs. The only path here is a narrow one, heading south

along the Cliffs." WCLF1 is west of River3. The printed name of WCLF1 is "White Cliffs Beach".

South of WCLF1 is a room called WCLF2. The description of WCLF2 is "You are on a rocky, narrow strip of beach beside the Cliffs. A narrow path leads north along the shore."

The printed name of WCLF2 is "White Cliffs Beach". East of WCLF2 is River4.

West of River4 is a room called Sandy Beach. The description of Sandy Beach is "You are on a large sandy beach at the shore of the river, which is flowing quickly by. A path runs beside the river to the south here."

South of Sandy Beach is a room called Shore. The description of Shore is "You are on the shore of the River. The river here seems somewhat treacherous. A path travels from north to south here, the south end quickly turning around a sharp corner." East of Shore is River5.

South of Shore is a room called Aragain Falls. The description of Aragain Falls is "You are at the top of Aragain Falls, an enormous waterfall with a drop of about 450 feet. The only path here is on the north end. [if rainbow flag is true]A solid rainbow spans the falls.[otherwise]A beautiful rainbow can be seen over the falls and to the east.[end if]".

Rainbow Room is a room. The description of Rainbow Room is "You are on top of a rainbow (I bet you never thought you would walk on a rainbow), with a magnificent view of the Falls. The rainbow travels east-west here. There is an NBC Commissary here."

Rainbow flag is a truth state that varies. Rainbow flag is usually false.

Check waving the stick:

if the player is in Aragain Falls or the player is in End of Rainbow begin;

if rainbow flag is true begin;

say "The rainbow seems to have become somewhat run-of-the-mill.";

change the east exit of Aragain Falls to nowhere;

change the west exit of Rainbow Room to nowhere;

change the west exit of End of Rainbow to nowhere;

change the east exit of Rainbow Room to nowhere;

now rainbow flag is false instead;

else;

say "Suddenly, the rainbow appears to become solid and, I venture,

walkable (I think the giveaway was the stairs and bannister).";

if the pot of gold is untouched, move the pot of gold to End of Rainbow;

change the east exit of Aragain Falls to Rainbow Room;

change the west exit of Rainbow Room to Aragain Falls;

change the west exit of End of Rainbow to Rainbow Room;

change the east exit of Rainbow Room to End of Rainbow;

now rainbow flag is true instead;

end if;

else if the player is in Rainbow Room;

say "The structural integrity of the rainbow seems to have left it,

leaving you about 450 feet in the air, supported by water vapor.";

end the game in death instead;

else;

say "Very good." instead;

end if.

A pot of gold is a thing. The initial appearance of the pot of gold is "At the end of the rainbow is a pot of gold." The later appearance of the pot of gold is "There is a pot of gold here." The size of the pot of gold is 15. The case-points of the pot of gold is 10. After taking the pot of gold: award 10 points; continue the action.

A statue is a thing.

Understand "beautiful" and "sculpture" and "rock" as the statue.

The size of the statue is 8.

After taking the statue: award 11 points; continue the action.

The case-points of the statue is 13.

Every turn while the location is Rainbow Room: now exit found is true.

After taking the buoy for the first time:

say "Something seems funny about the feel of the buoy.".

An open unopenable enterable container called a man-sized wooden barrel is in Aragain Falls. The printed name of the man-sized wooden barrel is "wooden barrel". The later appearance of the man-sized wooden barrel is "There is a man-sized barrel here which you might be able to enter." The barrel is fixed in place. The capacity of the man-sized wooden barrel is 100.

Check looking when the player is inside the barrel: say "You are inside a barrel. Congratulations. Etched into the side of the barrel is the word 'Geronimo!'. From your position, you cannot see the falls." instead.

After entering the barrel: try looking.