When in Rome 1: Accounting for Taste — 9 of 31

Section 2 - Creature Actions

Rule for implicitly taking something (called target) when the person asked is the creature:

try the creature taking the target.

The animal feeding rule is listed instead of the can't eat unless edible rule in the check eating rules.

The can't take people's possessions rule does nothing when the person asked is not the player.

Instead of asking the creature to try doing something when the creature is in a closed container:

say "The creature watches your mouth move, fascinated, but it obviously cannot hear you."

Before printing the name of the creature:

if a random chance of 1 in 4 succeeds:

if the creature is scaly, say "scaly ";

if the creature is furry, say "furry ";

say "[color of the creature] ".

Rule for printing the name of the creature:

if a random chance of 1 in 2 succeeds, say "creature";

otherwise say "Visitor".

This is the animal feeding rule:

if the actor is the player and the noun is not edible, say "That's plainly inedible." instead;

if the noun is not delicious, stop the action.

A person can be active or passive.

[After the creature trying doing something: now the creature is passive; continue the action.]

Before someone trying taking something: now containment context is the holder of the noun.

Containment context is a thing that varies.

Heart's desire is a thing that varies. Before someone trying taking something, now heart's desire is the noun.

Report the creature trying taking something:

if the creature is in the containment context and the containment context is a container,

say "[The creature] picks up [the noun], now it is in [the containment context]." instead;

otherwise say "[The creature] [if a random chance of 1 in 3 succeeds][forcefully] [end if][if containment context is a container]extracts[otherwise]picks up[end if] [the noun] from [if containment context is the location]the floor[otherwise][the containment context][end if]." instead.

Report an acquisitive creature trying taking something:

if the creature is in the containment context and the containment context is a container,

say "[The creature] gleefully picks up [the noun] from [the containment context]." instead;

otherwise say "[The creature] [if a random chance of 1 in 3 succeeds][forcefully] [end if][if containment context is a container]extracts[otherwise]acquires[end if] [the noun] from [if containment context is the location]the floor[otherwise][the containment context][end if], then recounts its possessions: [number of things carried by the creature in words]." instead.

Report a fidgety creature trying inserting something into something:

say "[The creature] shoves [the noun] hastily into [the second noun]." instead.

Report an athletic creature trying inserting something into something:

say "[The creature] [puts] [the noun] away in [the second noun]." instead.

Report someone trying inserting something into something:

say "[The person asked] [puts] [the noun] into [the second noun]." instead.

To say puts:

choose a random row in the Table of Insertion Words;

say "[word entry]".

Table of Insertion Words

Report the creature trying dropping something when the creature is athletic:

say "[The creature] tosses aside [the noun]." instead.

Report the creature trying dropping a wearable thing when the number of portable things in the location is greater than 4:

if the creature is in the location,

say "[The creature] drops [the noun] beside [the random fixed in place thing in the location]." instead;

otherwise say "[The creature] sets down [the noun] inside [the holder of the creature]." instead.

Report the creature trying closing something:

say "[The creature] [if a random chance of 1 in 3 succeeds]shuts[otherwise]closes[end if] [the noun]." instead.

Report the creature trying closing something which contains the creature:

if the creature is timid, say "With a shy look at you, [the creature] ";

otherwise say "[The creature] ";

say "[if a random chance of 1 in 3 succeeds]shuts[otherwise]closes[end if] [the noun] on itself." instead.

Report the creature trying opening something:

say "[The creature] opens [the noun]." instead.

Report the creature trying dropping something:

say "[The creature] puts down [the noun] [if the holder of the creature is not the location]inside [the holder of the creature][otherwise]on the floor[end if][if the gravity of the creature is less than negligible and the creature is not weak], breathing quickly[end if]." instead.

Instead of the creature trying taking something when the number of things carried by the creature is the carrying capacity of the creature:

let the new target be a random thing carried by the creature;

if the creature is hungry and the creature carries a delicious thing (called the target):

while the new target is the target:

let the new target be a random thing carried by the creature;

try the creature trying dropping the new target.

Instead of the creature trying taking something when the creature is in a container (called the playhouse):

if the noun is in the playhouse, continue the action;

otherwise try the creature trying exiting.

Instead of the creature trying taking something when the noun is in an enterable container (called the playhouse):

if the creature is tall

begin;

if the creature is visible and the creature is not in the playhouse, say "[The person asked] reaches for [the noun] with long arms.";

continue the action;

end if;

if the creature is not in the playhouse

begin;

if the creature is visible, say "[The person asked] tries to reach into [the playhouse], but its arms are a bit short for its purposes. [run paragraph on]";

if the creature carries the playhouse

begin;

try the creature trying dumping out the playhouse;

otherwise;

try the creature trying entering the playhouse;

end if;

otherwise;

continue the action;

end if.

Instead of the creature trying entering something closed:

try the creature trying opening the noun.

Instead of the creature trying entering something when the creature is not carrying the noun and the noun is not in the location:

try the creature trying taking the noun.

Instead of the creature trying entering something when the noun is not available:

try the creature trying taking the noun.

Instead of the creature trying entering something when the creature has the noun:

try the creature trying dropping the noun.

Instead of a negligible creature trying eating a useful leathery thing:

now the creature is passive;

now the noun is pointless;

if the creature is visible, say "[The creature] bites [the noun], but is too weak to tear off portions of its leathery substance."

Instead of a negligible creature trying eating a pointless leathery thing:

try the creature trying dropping the noun.

Instead of the creature trying eating something which contains something:

if the creature is not carrying the noun, continue the action;

otherwise try the creature trying dumping out the noun.

Instead of the creature trying eating something portable which is not carried by the creature:

try the creature trying taking the noun.

Carry out the creature trying eating something:

now the last feed time of the creature is the turn count;

if the noun is poisoned and the creature is not wood-pulpy and the creature is negligible, now the creature is poisoned.

Report the creature trying eating a poisoned thing:

say "[The creature] consumes [the noun], ";

if the creature is negligible

begin;

if the creature is wood-pulpy, say "but even though it is small and light-structured, its unusual metabolism seems capable of dealing with the glue." instead;

otherwise say "and immediately its eyes fill with tears and it begins to cough. After a moment or two of this it slumps into an inactive state." instead;

otherwise;

say "but because of the relatively small amount of toxin relative to its body mass and sturdiness it does not suffer any visible ill effect." instead;

end if.

Report the creature trying eating something:

say "[The creature] eats [the noun] in small neat bites, turning it in its paws as it goes[if the creature is comfortable]. At last it gives a pleased sigh[end if]." instead.

Report a fast creature trying eating something edible:

say "[The creature] gobbles up [the noun], scattering flecks everywhere." instead.

Report a fast creature trying eating something wearable:

say "[The creature] swiftly tears [the noun] into shreds, then consumes the confetti." instead.

Report a lightning creature trying eating something:

say "[The creature] devours the whole of [the noun] in one lightning-fast bolt." instead.

Report a creature trying eating the socks:

if the socks are poisoned, continue the action;

say "[The creature] chows down on your socks. Ew." instead.

Report the creature trying taking something stinky when the odor sensitivity of the creature is strong:

now the creature is passive;

say "[The creature] picks up [the noun]";

let index be 0;

repeat through Table of Stink Disgust

begin;

if a random chance of 1 in 3 succeeds

begin;

if index is 0, say ", "; otherwise say " and ";

say "[reaction entry]";

increase index by 1;

if index is 2

begin;

say "." instead;

end if;

end if;

end repeat;

say "." instead.

Table of Stink Disgust

Report the creature trying taking something stinky when the odor sensitivity of the creature is inverse:

now the creature is passive;

say "[The creature] picks up [the noun] and sniffs it with obvious pleasure." instead.

Report the creature trying closing a container which contains a stinky thing when the odor sensitivity of the creature is strong:

say "[The creature] [if the gravity of the creature is Earthlike]slams[otherwise]closes[end if] [the noun] [forcefully]." instead.

Before someone trying closing something which is not available:

if the creature is in the noun, continue the action;

try the person asked trying taking the noun instead.

The can't take people's possessions rule does nothing.

Instead of taking something which is worn by the creature when the speed of the creature is lightning:

now the creature is passive;

if the creature is visible, say "The creature dodges you with lightning speed and is at the far side of the room in a moment."

Instead of taking something worn by the creature when the creature is fast:

now the creature is passive;

if the creature is visible, say "You don't get close enough to the creature -- it moves away too fast."

Before taking something worn by the creature when the speed of the creature is moderate and the creature is friendly:

now the creature is passive;

say "The creature looks as though it might move away, but then decides to allow you to go ahead.";

continue the action.

Instead of taking something which is carried by the creature when the speed of the creature is lightning:

now the creature is passive;

say "You are no match for the creature's lightning reflexes, and never even get close to [the noun]." instead.

Instead of taking something carried by a slow creature:

move the noun to the player;

now the creature is passive;

say "[The creature] tries to evade you, but its movements are really too slow." instead.

Instead of taking something carried by the creature when the speed of the creature is moderate:

now the creature is passive;

if a random chance of 1 in 2 succeeds

begin;

move the noun to the player;

say "It's an even thing, with the creature's moderate reflexes, whether you're going to succeed or not, but you do manage to snatch [the noun] from it." instead;

otherwise;

say "You make a move towards [the noun]; [the creature] dodges. But not terribly quickly; with another try you might succeed. Moderate reflexes at best." instead;

end if.

Instead of taking something carried by a fast creature:

now the creature is passive;

if the creature is playful, say "You reach for [the noun], but the creature tosses it to another hand, winking at you. It's a quick thing, at least.";

otherwise say "You try to retrieve [the noun], but the creature deftly moves it out of your reach. Fast reflex, there.".

[Instead of the passive creature trying doing something:

stop the action.]

Definition: a container is contaminated if the odor sensitivity of the creature is strong and it contains a stinky thing.

Before the hostile smart creature trying taking something which is not available when the creature can see a papery available thing (called the target):

if the creature can see the player, try the creature trying threatening the target for the noun instead.

A thing can be threatened or unthreatened. A thing is usually unthreatened.

Threatening it for is an action applying to two things. Threatening something for something is useless action.

Instead of the creature trying threatening an unthreatened thing for something:

now the noun is threatened;

now the creature is passive;

if a random chance of 1 in 2 succeeds,

say "[The creature] gestures dire things it will do to [the noun] if it does not receive [the second noun].";

otherwise

say "[The creature] mimes tearing [the noun] to bits, then points at [the second noun].";

Carry out the creature trying threatening something for something:

try the person asked trying attacking the noun instead.

[Must be a before or it will fail the basic accessibility rule]

Before the creature trying taking something which is in a closed container (called the protection):

if the creature can touch the noun, continue the action;

try the creature trying opening the protection instead.

Instead of the starving creature trying crying for the first time:

now the creature is passive;

if the creature is visible

begin;

if the creature can see a delicious thing (called target),

say "[The creature] settles in one place, no longer strong enough to beg for [the target].";

otherwise say "[The creature] settles in one place, no longer strong enough to beg for food.";

end if.

Instead of the starving creature trying crying:

if the person asked is visible

begin;

if the creature can see a delicious thing (called target) and the creature is visible

begin;

if the target is the player,

say "[The creature] stares hungrily in your direction.";

otherwise

say "[The creature] eyes [the target][if the gravity of the creature is less than Earthlike] weakly, but does not move towards it[otherwise] wistfully[end if].";

otherwise;

say "[The creature] whimpers in hunger.";

end if;

end if;

now the creature is passive.

Before a fidgety hostile smart creature trying taking something which is carried by the player :

silently try dropping the noun;

if the player is not carrying the noun,

say "[The creature] distracts you, causing you to drop [the noun]."

Instead of the creature trying taking something which is not available:

try the creature trying begging for the noun.

Reading is an action applying to one thing.

Carry out the creature trying reading:

now the noun is explored.

Report the creature trying reading:

say "[The person asked] [if a random chance of 1 in 2 succeeds]peruses[otherwise]thoughtfully studies[end if] [the noun]."

Forcing drop of is an action applying to one thing.

Instead of the creature trying forcing drop of something when the number of things carried by the person asked is 0:

let the target be a random portable available thing which can be seen by the person asked;

if the target is a thing, try the person asked trying taking the target instead.

Carry out the creature trying forcing drop of something:

let the target be a random thing carried by the person asked;

if the target is not a thing, stop the action;

try the person asked trying forcing drop of the noun with the target.

Forcing drop of it with is an action applying to two things.

Carry out the creature trying forcing drop of something with something:

move the second noun to the player;

move the noun to the person asked

Report the creature trying forcing drop of something with something:

say "[The person asked] chucks [the second noun] in your direction, causing you to drop [the noun]." instead.

Begging for is an action applying to one thing.

Carry out the creature trying begging for something: do nothing.

Report a meaty person trying begging for the player:

if the holder of the person asked is the holder of the player,

say "[The person asked] sneaks up close and [if a random chance of 1 in 2 succeeds]tries to take a bite from your calf[otherwise]licks your wrist[end if]." instead;

otherwise say "[The person asked] [if a random chance of 1 in 2 succeeds]makes bitey faces in your direction[otherwise]watches your movements with an unpleasant sort of hungry anticipation[end if]." instead.

Report the creature trying begging for something:

if the noun is the person asked, say "[The person asked] squirms." instead;

if the person asked is not in location, say "From [the holder of the person asked], [the person asked] reaches toward [the noun]." instead;

if the person asked is timid, say "[The person asked] looks at [the noun] with large eyes but does not move, speak, or gesture." instead;

choose a random row in the Table of Object Requests;

if the creature is friendly or the creature is secretive, say "[template entry][paragraph break]";

if the creature is curious, say "[curious request entry][paragraph break]";

if the creature is hostile, say "[unfriendly request entry][paragraph break]";

now the creature is passive.

Before the creature trying begging for something when the noun encloses the creature:

now the creature is passive;

say "[The creature] looks queasy and gestures for you to set it down." instead.

Instead of a smart person trying begging for something which is carried by the player:

try the person asked trying forcing drop of the noun.

Instead of a fidgety person trying begging for something when the player carries more than 4 things and the player carries the noun:

if the person asked is not visible, stop the action;

if the person asked is timid, continue the action;

if the number of things carried by the person asked is the carrying capacity of the person asked, try the person asked trying dropping a random thing carried by the person asked instead;

if the noun is the first thing held by the player, continue the action;

move the noun to the person asked;

say "[The person asked] extracts [the noun] from among your possessions, since you are holding so much and its reflexes are so good."

Instead of a vast person trying begging for something:

if the person asked is not visible, stop the action;

now the person asked is passive;

if the player wears the noun, say "[The person asked] tears [the noun] off of you. Gentle it isn't.";

otherwise say "[The person asked] pulls [the noun] away from you[if the noun is papery], nearly ripping it in the process[end if].";

move the noun to the person asked.

Instead of a vast person trying begging for something for the first time:

if the person asked is not visible, stop the action;

now the person asked is passive;

if the player wears the noun, say "[The person asked] strips [the noun] from your body in one rapid movement. Well. Pity Esther isn't in here.";

otherwise say "[The person asked] unceremoniously wrests [the noun] from your grasp, being quite a lot stronger than you are.";

move the noun to the person asked.

Table of Object Requests

Report a slothful creature trying begging for something:

say "[The creature] whines for [the noun]." instead.

Growling is an action applying to nothing.

Carry out the creature trying growling: do nothing.

Report the creature trying growling: say "[The creature] growls."

After the creature trying growling for the first time:

say "[The person asked] growls at you. Hostile, then. You back off warily.";

now the creature is passive;

stop the action.

Report a friendly creature trying growling:

say "[The noun] shows teeth, but in such a way that you know it doesn't mean anything serious by it."

Shivering is an action applying to nothing.

Carry out the creature trying shivering: now the person asked is passive.

Report the creature trying shivering: say "[The creature] [if a random chance of 1 in 2 succeeds]rubs its paws over its arms[otherwise]shivers[end if]."

Report the creature trying shivering when the person asked can see a lit thing (called the target):

say "[The creature] shivers and draws closer to [the target]." instead.

Rejecting is an action applying to one thing.

Carry out the creature trying rejecting something: now the noun is explored.

Report the creature trying rejecting: say "[The person asked] turns its head away." instead.

Report a strong person trying rejecting a stinky thing: say "[The person asked] covers its nostrils and draws back." instead.

Report an inverse person trying rejecting a stinky thing: say "[The person asked] sniffs wistfully, obviously drawn by the smell, but then shakes its head." instead.

Report a weak person trying rejecting a stinky thing: say "[The person asked] looks uninterested, but not appalled by the stench." instead.

Instead of a playful person trying rejecting an unexplored papery thing :

try the person asked trying accepting the noun;

try the person asked trying playing with the noun.

Report a playful person trying rejecting an explored papery thing:

say "[The person asked] rolls its eyes and, with an exaggerated show of patience, looks over [the noun] again, muttering to itself. Apparently it has already committed to memory everything it finds interesting here." instead.

Report a playful person trying rejecting when the person asked carries something (called distraction):

say "[The person asked] giggles, and holds up [the distraction] for you to see in exchange, as though this were some kind of show-and-tell game." instead.

Report a timid person trying rejecting: say "[The person asked] scoots out of the way." instead.

Report a hostile person trying rejecting: say "[The person asked] spits on [the noun]." instead.

Showing temper is an action applying to nothing.

Carry out the creature trying showing temper: do nothing.

Report the creature trying showing temper:

say "[The creature] grumbles to itself." instead.

Crying is an action applying to nothing.

Carry out the creature trying crying: do nothing.

Report the creature trying crying: say "[The creature] sobs."

Report the stupid creature trying crying:

say "[The creature] [if a random chance of 1 in 2 succeeds]lies curled on the floor, keening softly[otherwise]rocks itself back and forth[end if]." instead.

Report hostile smart creature trying crying:

say "[The creature] is too weak to do much at this point, but it watches you angrily, and occasionally makes a gesture at you that it must have learned from taxi drivers." instead.

Report a creature trying crying when the creature is in a container (called the trap):

say "[The creature] curls up in [the trap], weeping." instead.

Hiding oneself is an action applying to nothing.

Check the creature trying hiding oneself:

if the person asked is not in a container, stop the action.

Carry out the creature trying hiding oneself:

if the person asked is in a container (called the shelter)

begin;

if the player is in the shelter

begin;

try the person asked trying exiting;

otherwise;

if the shelter is closed and the player can see the person asked, say "[The person asked] [if a random chance of 1 in 2 succeeds]squinches its eyes shut, on an ostrich-like principle of mutual ignorance[otherwise]avoids looking at you[end if].";

otherwise try the person asked trying closing the shelter instead;

end if;

end if.

The last location is a room that varies.

Before the creature trying hiding oneself when the person asked can see a door (called escape route):

if location is not last location

begin;

now the person asked is passive;

if the person asked is visible, say "[The person asked] presses itself against the wall and tries to creep past you towards [the escape route]." instead;

otherwise;

try the person asked trying entering the escape route instead;

end if.

Before the creature trying hiding oneself when the person asked is not in a container and the player is not in a container:

if the person can see an enterable sheltering container

begin;

let the shelter be a random enterable sheltering opaque container which can be seen by the person asked;

if the shelter is not a container, let the shelter be a random enterable sheltering container which can be seen by the person asked;

try the person asked trying entering the shelter instead;

end if.

Definition: a container is sheltering if it is open or it is openable.

Dressing oneself is an action applying to nothing.

Before the creature trying dressing oneself when the person asked is not carrying something wearable:

if the person asked can see an available wearable thing (called target) which is not worn by the person asked

begin;

try the person asked trying taking the target;

otherwise if the person asked can see a wearable thing (called target) which is not worn by the person asked;

try the person asked trying taking the target;

end if.

Check the creature trying dressing oneself:

if the person asked is not carrying a wearable thing, stop the action.

Carry out something trying dressing oneself:

if the person asked is carrying a wearable thing (called target), try the person asked trying wearing the target.

Report the cold creature trying wearing something:

say "[The creature] puts on [the noun] and pulls it as tight as possible to conserve warmth." instead.

Report the cold creature trying wearing the jacket:

say "[The creature] pulls the jacket awkwardly over its arms and gathers the front shut." instead.

Dining is an action applying to nothing.

Before a meaty person trying dining when the person asked cannot see the player:

if the person asked is in an adjacent room and the person asked can see a door (called the appropriate exit):

try the person asked trying entering the appropriate exit instead.

Before the creature trying dining when the person asked is wearing a delicious thing (called lunch) and the person asked is not carrying a delicious thing:

try the person asked trying taking off the lunch instead.

Instead of the creature trying dining when the person asked does not have a delicious thing:

if the person asked can see an available useful delicious thing (called target):

try the person asked trying taking the target;

otherwise:

if the person asked can see a delicious thing (called target):

try the person asked trying taking the target;

otherwise if the person asked is smart:

try the person asked trying exploring.

Check the creature trying dining:

if the person asked is not carrying a delicious thing, stop the action.

Carry out something trying dining:

if the person asked is carrying a delicious thing (called target), try the person asked trying eating the target.

Playing with is an action applying to one thing.

Carry out the creature trying playing with something: now the noun is explored.

Report the creature trying playing with something:

say "[The person asked] [if the person asked is playful]toys with[otherwise]pokes at[end if] [the noun]";

if the person asked has the noun, say "." instead;

if the noun is in location

begin;

say "." instead;

otherwise;

if the holder of the noun is not the holder of the person asked, say " [if the holder of the noun is a container]in[otherwise]on[end if] [the holder of the noun]." instead;

otherwise say " in a bored manner." instead;

end if.

Definition: a person is fidgety if it is fast or it is lightning.

Report a vast person trying playing with something when the noun is fixed in place and a random chance of 1 in 2 succeeds:

say "[The person asked] casually lifts [the noun] a few inches, then sets it back down." instead.

Report the athletic creature trying playing with something when the noun is fixed in place and the noun is in the location:

if the person asked is vast, continue the action;

say "[The person asked] climbs up one side of [the noun] and down the other." instead.

Report the fidgety creature trying playing with something:

if a random chance of 1 in 2 succeeds,

say "[The person asked] taps [the noun] all over." instead;

otherwise say "[The person asked] beats a rapid rhythm with its claws on [the noun]." instead.

Report the fidgety creature trying playing with a container:

say "[The person asked] taps [the noun]";

if the noun is papery, say ", which rustles." instead;

otherwise say ", which thunks hollowly." instead.

Report the fidgety creature trying playing with a papery thing:

say "[The person asked] rustles [the noun]." instead.

Report a smart curious person trying playing with a papery thing:

if the noun is the box, continue the action;

say "[The person asked] reads [the noun] through, following the words with one claw and subvocalizing as it goes." instead;

Instead of a vast person trying playing with something:

try the person asked trying attacking the noun.

Carry out a vast person trying attacking an openable container:

now the noun is open;

now the noun is damaged;

now the noun is unopenable.

Report a vast person trying attacking a container:

if the noun is papery, say "Apparently by accident, [the creature] rips a big hole in the side of [the noun].";

otherwise say "[The creature] so mauls [the noun] that it is now in a permanent state of openness." instead.

A thing can be damaged or whole. A thing is usually whole.

Instead of a vast person trying attacking an unopenable papery container:

let space be the holder of the noun;

if the person asked is visible, say "[The creature] finishes dismantling [the noun], leaving [the list of things in the noun] behind.";

now every thing in the noun is in the space;

now the person asked is passive;

now the noun is nowhere.

Instead of a vast person trying attacking an edible thing:

now the noun is nowhere;

if the person asked is visible, say "[The person asked] tears apart [the noun], scattering bits everywhere.";

now the person asked is passive.

Carry out the creature trying attacking something papery:

now the noun is nowhere.

Report the creature trying attacking something papery:

say "[The person asked] rips [the noun] to tiny shreds.";

Instead of attacking a papery thing:

now the noun is nowhere;

if the noun contains something

begin;

say "You tear up [the noun], leaving behind [the list of things in the noun][if the creature is in the noun]. [The creature] blinks in surprise[end if].";

now every thing in the noun is in the location;

otherwise;

say "You rip [the noun] to bits.";

end if.

Report a vast person trying attacking a damaged thing:

if the creature has the noun,

say "[The creature] bends [the noun] in imitation of a strong-man demonstration at a fair.";

otherwise say "[The creature] jumps up and down on [the noun], but does not cause any more harm." instead.

Instead of a smart curious person trying playing with an unexplored switched off device:

if the person asked is slothful, continue the action;

now the noun is explored;

try the person asked trying switching on the noun.

Instead of a slothful person trying switching on something:

now the person asked is passive;

if the person asked is visible, say "[The person asked] fumbles painfully at [the noun], but cannot manage to flip the switch."

Instead of a slothful person trying switching off something:

now the person asked is passive;

if the person asked is visible, say "[The person asked] fumbles painfully at [the noun], but cannot manage to flip the switch."

Instead of a slothful person trying switching off something for the first time:

now the person asked is passive;

if the person asked is visible, say "[The person asked] runs its claws over the surface of [the noun], seeking to switch it off but without success."

Report a curious creature trying playing with something when the noun is fixed in place:

if the person asked is vast and a random chance of 1 in 2 succeeds, continue the action;

say "[The person asked] cranes its head around, trying to see under and behind [the noun]." instead.

Report a smart hostile person trying playing with something when the noun is fixed in place:

say "[The person asked] runs its claws around the edges of [the noun], as though seeking a way to take it apart." instead.

Report a hostile creature trying playing with something when the noun is fixed in place:

say "[The person asked] bangs its head against [the noun] repeatedly." instead.

Report a playful creature trying playing with something which is worn by the person asked:

say "[The person asked] adjusts the fit of [the noun]." instead.

Report a playful creature trying playing with the fedora when the person asked is wearing the fedora:

say "[The person asked] tilts [the fedora] at a more rakish angle." instead.

Report a hostile stupid person trying playing with the fedora when the person asked is wearing the fedora:

say "With a guttural gurgle, [the person asked] pulls [the fedora] down more tightly over its ears." instead.

Report the creature trying playing with the jacket when the jacket is worn by the person asked:

if the person asked is playful, say "[The person asked] turns up the collar of the jacket, making itself like an unearthly gangster or hoodlum." instead;

otherwise say "[The person asked] rolls up the sleeves of [the jacket]." instead.

Report the creature trying playing with something edible:

say "[The person asked] prods [the noun] into interesting shapes." instead.

Report the playful creature trying playing with something edible:

say "[The person asked] mimes wearing [the noun] as a hat, watching you slyly." instead.

The inaction rule is listed after the check stage rule in the specific action-processing rules.

This is the inaction rule:

now the person asked is passive.

Report the fidgety creature trying entering something:

say "[The creature] [if the creature is timid]creeps[otherwise]hops[end if] into [the noun][if the player is in the noun] with you[end if][if the heart's desire is not the creature] in search of [the heart's desire][end if]." instead.

Report a slow negligible person trying entering something:

say "[The creature] hauls itself into [the noun][if the player is in the noun] with you[end if][if the heart's desire is not the creature] in search of [the heart's desire][end if]." instead.

Report the creature trying entering something:

say "[The creature] climbs into [the noun]." instead.

Report the creature trying exiting:

say "[The creature] gets out again." instead.

Report the creature trying going through a door (called the escape route):

say "[The creature] slips out through [the escape route]." instead.

Report a timid person trying going through a door (called the escape route):

say "Glancing at you apprehensively, [the creature] tiptoes out [the escape route]." instead.

Instead of the creature trying attacking a portable thing which is not carried by the person asked:

try the person asked trying taking the noun.

Instead of the creature trying attacking something which is worn by the person asked:

try the person asked trying taking off the noun.

Disposing of is an action applying to one thing.

Before the creature trying disposing of something which is worn by the person asked:

try the person asked trying taking off the noun instead.

Before the creature trying disposing of something which is not held by the person asked:

if the noun is not in an openable container,

try the person asked trying taking the noun instead;

if the person asked is stupid, try the person asked trying taking the noun instead.

Before the smart creature trying disposing of something when the noun is not in an openable container:

if the person asked can see an openable container (called the tank), try the person asked trying inserting the noun into the tank instead.

Instead of the creature trying disposing of something which is not held by the person asked when the person asked is holding something stinky (called the other problem):

try the person asked trying disposing of the other problem.

Instead of the creature trying inserting something into a closed openable container:

try the person asked trying opening the second noun.

Instead of the creature trying inserting something which is not held by the person asked into something:

try the person asked trying taking the noun.

Carry out the creature trying disposing of something:

if the noun is in an openable container (called the tank), try person asked trying closing the tank;

if the noun can be touched by the person asked, stop the action.

Carry out the creature trying opening something: now the noun is explored.

Instead of the creature trying opening something for the second turn:

if the person asked is visible, say "[The person asked] looks exasperated.";

now the person asked is passive.

Report the creature trying opening something which contains the creature:

say "[The person asked] triumphantly opens [the noun] from the inside." instead.

Report the creature trying opening something which contains something:

say "[The person asked] opens [the noun]";

if the creature is in the noun, say " from within." instead;

if the odor sensitivity of the person asked is strong, say "[if the noun contains a stinky thing], wrinkling its nose at the smell of [the list of stinky things which are in the noun][end if]." instead;

otherwise say " and pokes curiously at [the list of things which are in the noun]." instead.

Report a hostile creature trying dropping something:

say "[The person asked] flings aside [the noun]." instead.

Report a vast person trying dropping something:

say "[The person asked] flings [the noun] at [the random fixed in place thing in the location]. No serious harm results." instead.

Report a fidgety hostile creature trying dropping something:

if the noun outweighs strength, do nothing;

otherwise say "[The person asked] throws [the noun] at you, but (fortunately) misjudges the velocity and angle." instead.

Report a fidgety hostile Earthlike creature trying dropping something when the creature can touch the player:

say "[The person asked] flings [the noun] at you; it hits and bounces off." instead.

Report a fidgety hostile Earthlike creature trying dropping something heavy:

say "[The person asked] flings [the noun] at you with unpleasant precision. That's going to leave a bruise in the morning." instead.

Instead of a starving creature trying exiting: try the creature trying crying instead.

Before a smart creature trying exiting when the creature is in a closed container (called the trap):

try the creature trying opening the trap instead.

Before a creature trying opening an unopenable container which contains the creature for the first time:

now the creature is passive;

say "The creature tries to open [the noun] from the inside, and soon realizes it cannot be done. Its mouth opens in a screech of fury, or terror: you hear nothing." instead.

Before a creature trying opening an unopenable container which contains the creature for the first time:

now the creature is passive;

say "The creature pummels its fists against the interior of [the noun] in desperation." instead.

Tidying is an action applying to nothing.

Check the creature trying tidying:

if the person asked can see an open openable container, continue the action;

otherwise stop the action.

Carry out the creature trying tidying:

if the person asked can see an open openable container (called the mess), try the person asked trying closing the mess.

Exploring is an action applying to nothing.

Carry out the creature trying exploring:

now the person asked is passive;

if the person asked can see a closed openable container (called target), try the person asked trying opening the target instead;

if the person asked can see a fixed in place thing (called target), try the person asked trying looking under the target instead.

Sneaking it under is an action applying to two things.

Check the creature trying sneaking something under something:

if the person asked is not carrying the noun, stop the action;

if the second noun is not fixed in place, stop the action.

Carry out the creature trying sneaking something under something:

now the noun is nowhere;

now the second noun disguises the noun.

Report the creature trying sneaking something under something:

say "[The person asked] sneakily hides [the noun] under [the second noun]."

Understand "hide [something] under [something]" as sneaking it under. Understand "put [something] under [something]" as sneaking it under. Understand "conceal [something] under [something]" as sneaking it under.

Check sneaking something under something:

if the player is not carrying the noun

begin;

try the player trying taking the noun;

if the player is not carrying the noun, stop the action;

end if;

if the second noun is a door, say "You can't hide things under [the second noun]." instead;

if the second noun is not fixed in place, say "[The second noun] would not make much of a concealment." instead.

Carry out sneaking something under something:

now the noun is nowhere;

now the second noun disguises the noun.

Report sneaking something under something:

say "You tuck [the noun] under [the second noun]."

Launching [us] is an action applying to nothing.

Before a hostile person trying launching [us]: act creepy instead.

To act creepy:

if the person asked is visible, say "[The person asked] looks at you for a long time through bright eyes and then smiles very pleasantly.";

now the person asked is passive;

now the person asked is secretive.

Before the creature trying playing with something which is carried by the player:

say "[The creature] looks with fascination at [the noun], but cannot reach it." instead.

Before the creature trying playing with something which is part of something which is carried by the player:

say "[The creature] looks at [the noun] but can't quite get at it." instead.

Report a hostile creature trying taking off something:

say "[The person asked] grumpily divests itself of [the noun]." instead.

Report a playful creature trying taking off something:

say "[The person asked] flirtatiously strips off [the noun]." instead.

Report a fast creature trying taking off something:

say "[The person asked] strips off [the noun] in a single fluid movement." instead.

Report the creature trying waiting:

choose a random row in the Table of Creature Sloth;

say "[reply entry][paragraph break]" instead.

Table of Creature Sloth

Report the creature trying jumping:

say "[The person asked] jumps[if the person asked is vast] implausibly high[end if][if the person asked is Earthlike] quite high[end if][if the person asked is Marslike], but looks surprised at how quickly it lands[end if][if the person asked is fractional], but not very far[end if][if the person asked is negligible], but only clears the floor by a few meager centimeters[end if]." instead.

Instead of the creature trying taking something when the noun outweighs strength and the noun is in a container (called receptacle):

if the receptacle is available, try the person asked trying pushing the receptacle;

otherwise continue the action.

Instead of the creature trying taking something when the noun outweighs strength and the noun is on a supporter (called surface):

try the person asked trying pushing the noun.

Instead of the creature trying pushing something which is on a supporter (called surface):

let the place be the holder of the surface;

now the noun is in place;

now the person asked is passive;

if the person asked is visible, say "[The person asked] [forcefully] pushes off [the noun] onto [if the place is location]the floor[otherwise][the place][end if].";

Dumping out is an action applying to one thing.

Understand "empty [container]" or "dump out [container]" as dumping out. Understand "empty [something]" or "dump out [something]" as dumping out.

Check dumping out:

if the noun is not a container, say "[The noun] cannot contain anything to start with." instead;

if the number of things contained by the noun is 0, say "[The noun] does not contain anything." instead;

if the player is not carrying the noun

begin;

try the player trying taking the noun;

if the player is not carrying the noun, stop the action;

end if.

Carry out dumping out:

let place be the holder of the player;

now every thing which is in the noun is in the place.

Report dumping out:

say "You empty [the noun] out [if the player is in a room]onto the floor[otherwise]into [the holder of the player][end if]."

Check the creature trying dumping out:

if the noun is not a container, stop the action;

if the number of things contained by the noun is 0, stop the action;

if the person asked does not carry the noun, stop the action.

Carry out the creature trying dumping out:

let place be the holder of the person asked;

now every thing which is in the noun is in the place.

Report the creature trying dumping out:

say "[The person asked] empties [the noun] [if the person asked is in a room]onto the floor[otherwise]into [the holder of the person asked][end if]."

Instead of the creature trying dumping out when the player carries the creature:

say "[The creature] empties [the noun]; [a list of things in the noun] ";

if the number of things in the noun is 1, say "falls beside you.";

otherwise say "rain around you.";

now every thing which is in the noun is in the location.

Understand "push [something] over" or "knock [something] over" as pushing.

Instead of pushing a container:

let the place be the holder of the noun;

say "You knock over [the noun][if something is in the noun], dumping out [the list of things which are in the noun][end if].";

now every thing which is in the noun is in the place.

Instead of the creature trying pushing a container:

let the place be the holder of the noun;

if the person asked is visible, say "[The person asked] knocks over [the noun][if something is in the noun], awkwardly spilling out [the list of things which are in the noun][end if].";

now the person asked is passive;

now every thing which is in the noun is in the place.

Instead of the creature trying taking something when the noun outweighs strength:

if the noun is pointless, stop the action;

now the noun is pointless;

if the person asked is visible, say "[The person asked] tries to pick up [the noun], but without success."

Instead of a secretive starving Earthlike creature trying taking something which is not available:

try the person asked trying attacking the player.

Instead of an Earthlike creature trying attacking the player when the person asked is not carrying a heavy thing:

if the person asked can see an available heavy thing (called target), try the person asked trying taking the target.

Instead of an Earthlike creature trying attacking the player when the person asked carries a heavy thing (called the weapon):

say "Starving, desperate, and tired of waiting for your cooperation, [the person asked] slugs you hard with [the weapon]. And what happens from there is all blackness...";

end the story saying "You have died".