When in Rome 1: Accounting for Taste — 28 of 31

Section 2 - Major Plot Events

To leave space:

say paragraph break; say paragraph break;

say paragraph break; say paragraph break.

To simplify the game:

if the current level is beginner:

let N be a random number between 1 and 2;

choose row N in the Table of Alien Characteristics;

otherwise:

choose a random row in the Table of Alien Characteristics;

while the difficulty entry is not the current level:

choose a random row in the Table of Alien Characteristics;

now moon of the creature is moon entry;

now mood of the creature is attitude entry;

now the odor sensitivity of the creature is nostrils entry;

now metabolism of the creature is feed time entry;

now gravity of the creature is the mass entry;

now speed of the creature is the dexterity entry;

now carrying capacity of the creature is the arms entry;

if carrying capacity of the creature is 0, now carrying capacity of the creature is 2;

now food of the creature is taste entry;

now intelligence of the creature is brain entry;

follow the setup rules;

When play begins:

now the right hand status line is "[time of day]";

now the time of day is 7:13 PM;

now the left hand status line is "Friday, May 21, 1954";

simplify the game.

When play begins:

say "'Excuse me. You in the fedora,' says a female voice, behind you. 'Excuse me, is it really too difficult to keep your dog leashed?'

'Yes,' you say, turning. 'I haven't got a dog.'

The source of the aggravation is ten feet back on the path: hair between brown and honey, a Marilyn figure, and one of those tipped-up noses that makes a girl look always just a little annoyed.

There is also a short [color of the creature] animal worrying at her skirt.

'Whatever you call it, it [italic type]obviously[roman type] shouldn't be out unleashed.'

'It isn't mine, and I don't know what it is.' You and the girl look at the creature again. In the fading twilight of Central Park, it's hard to see clearly, but you're more than ever certain that it does not belong to the genus [italic type]canis[roman type].";

leave space;

pause the game;

leave space;

center "[story title]";

center "[story headline]";

center "by [story author]";

leave space;

pause the game;

say "'Do you think it might be an escaped monkey?' you ask. There is a rip of stitches coming free: as a matter of theoretical interest, you wonder what the girl will do if the beast manages to tear off her skirt.

'I don't know!' she exclaims, swatting it with her handbag. 'But it's--'

There's a flash of [color of the creature] arms. 'It took my bag!' she exclaims, blinking, as the thing runs off for the shelter of the nearest bridge. 'Your dog took my handbag!'

You open your mouth to deny involvement, but she doesn't wait to hear it; instead she strips off her shoes and goes running after the thing. You watch her disappear into the darkness of the underpass; consider going home; then realize that you don't want to figure in this girl's mind as the man who set a rabid animal on her and then left her to her fate.";

move the creature to the player;

move the fedora to the Underpass;

move the handbag to the creature;

pause the game.

Getting handbag is a scene. Getting handbag begins when play begins. Getting handbag ends when the player does not carry the creature.

When getting handbag ends:

now the creature is nowhere.

Drinks is a scene. Drinks begins when Getting handbag ends. Drinks ends when Esther is dismissed.

Understand "thank [someone]" as thanking. Thanking is an action applying to one thing. Carry out thanking: say "Pointless." Thanking someone is useless action.

Instead of thanking the girl: say "'You're not freed yet,' she points out."

Instead of thanking Esther:

say "'Thank you for joining me,' you manage, after a minute. 'I wasn't quite ready to go straight home after our little adventure.'

She smiles.";

now esther is dismissed.

When Drinks begins:

move the handbag to Esther;

say "When the fuss is over, the girl is still with you; now you look, she's older than you first thought, closer to your own age. She does look a bit rattled, though.

'Can I buy you a drink?' you ask. 'Being throttled by a rabid animal always leaves me thirsty.'

'I don't drink with strange men.' She is adjusting her hair with the aid of a tiny compact mirror, though it is obvious that some of those curls have never been orderly and never will.

You hand her your business card. 'There, now we're introduced.'

Perhaps the staid logo of Chase Manhattan soothes her, because she replies, 'I'm Esther. Milligan.' There's a stop between the first name and the last; if you were a more suspicious man you might think she made up that moniker. But then, why choose a name like Milligan?

'Do you drink martinis, Miss Milligan?'";

if the heels are consumed, say "[line break]'Only if I can buy new shoes on the way,' she says.

'Macy's it is. And then drinks.'";

make scene break;

increase the time of day by 47 minutes;

now Esther wears the heels; [because she ought to be dressed just as the girl version of herself]

now Esther wears the dress;

move Esther to the Cafe;

move the player to the Cafe.

Martini comment is a scene. Martini comment begins when Drinks is happening and the time since Drinks began is 3 minutes.

When martini comment begins:

say "'I don't even like martinis,' Esther remarks.

'You could have mentioned it earlier.'

'I didn't want to be rude,' she says.

'But now you do?'

She shrugs. 'I realized that if I posed as someone who likes martinis, I might have to go on carrying out the ruse indefinitely, and that would be its own punishment.'

In the back of your fogged brain, alarms go off. 'Indefinitely'? Yes, you must, must leave.

Seeing but misinterpreting your appalled expression, she says, 'Really, it's all right. Sometimes a martini is the only thing when your nerves are frayed. Like medicine.'"

When martini comment ends:

repeat with item running through martini glasses

begin;

now item is nowhere;

end repeat;

say "A woman comes and takes away the martini glasses. 'I think that's my cue,' says Esther.";

now Esther is dismissed.

Martini comment ends when the time since martini comment began is 2 minutes.

When drinks ends:

say "When you shake hands, her hand lingers in yours. Now is the point when you are allowed to ask to see her again -- for a moment you seriously consider it, but habit wins. 'It was a pleasure to know you, Miss Milligan,' you say firmly.

A tiny hurt look comes into her eyes, then turns into something more like shock. Then you realize that she's looking over your shoulder -- at four extremely bulky and belligerent men.";

make scene break.

To make scene break:

center "*****";

say line break;

pause the game;

say paragraph break;

say paragraph break;

say paragraph break.

Limo Ride is a scene. Limo Ride begins when drinks ends. Limo Ride ends when the number of filled rows in the Table of Limo Banter is 0.

When Limo Ride begins:

say "'We're here from animal control,' says the largest one unconvincingly. 'We have a question about the animal you saw earlier. The escaped circus animal.'

'That wasn't a circus animal,' says Esther. 'That was like something from another planet.'

This is evidently the wrong statement. There's a more complete silence than you've ever before heard in the city of New York.

The men look at one another. 'In the car,' says the large one, suddenly, and someone gives you a shove at the middle of the back.

So much for going home and forgetting this entire incident.";

now the description of Esther is "She sits back, fingers laced, ankles crossed in ladylike fashion. She looks less frightened than you feel. Perhaps she hasn't encountered some of the things Army intelligence does when it feels threatened; it seems more and more likely that that is what you're up against.";

move Esther to the Limousine;

move thugs to the Limousine;

move the player to the Limousine.

When Limo Ride ends:

make scene break.

Every turn during Limo Ride:

repeat through the Table of Limo Banter

begin;

say "[reply entry][paragraph break]";

blank out the whole row;

rule succeeds;

end repeat.

Table of Limo Banter

When Limo Ride ends:

now the current level is easy;

simplify the game;

let N be the metabolism of the creature;

let new time be the turn count - N;

now last feed time of the creature is new time;

move the rubber ball to the creature;

increase the time of day by 12 minutes;

move the creature to the Foreman's Area;

move the player to the Foreman's Area, without printing a room description;

say "You're brought into what appears to be a derelict factory of some kind, into a small room. The man in the black suit lingers after the others have taken Esther away. 'We'd like you to be useful to us,' he says. 'If you are, we can employ you, and no one gets hurt. I say this now to make sure you understand the stakes.

'You have a small test. If you are able to discern where our friend here comes from, say your answer, and we'll come spring you out. We'll be watching in the other room with the loudspeaker.' You follow his glance to [the creature] waiting for you.

'And Miss Milligan?' you ask.

'Oh, the girl? Her test is simpler. I'm sure she'll pass. Not to worry.' He smiles. 'Unless of course you fail, in which case we won't be able to use her either. Well, good luck!'";

if the player is not carrying the paper chart

begin;

move the paper chart to the player;

say "[line break]He starts out, then comes back and puts a paper chart into your hands. Then he's gone.[line break]";

otherwise;

say "[line break]He starts out, then pauses, comes back, and writes at the bottom of the chart. 'Just in case you forget the instructions,' he says, with a condescending smile.[line break]";

end if;

Test is a scene. Test begins when Limo Ride ends. Test ends when the creature is known.

Final teaser is a scene. Final teaser begins when Test ends.

When final teaser begins:

make scene break;

now the left hand status line is "Thursday, May 27, 1954";

now the time of day is 9:25 AM;

move the salami to the Hallway;

move the player to the Hallway;

repeat with item running through things carried by the player

begin;

now item is nowhere;

end repeat; [1]

move the creature to the Office;

now Joe Dimaggio is nowhere;

now the color of the creature is a random color;

now every thing carried by the creature is in the Underpass;

now every thing worn by the creature is in the Underpass.

The player is in Central Park Underpass.