The Reliques of Tolti-Aph — 46 of 57

Section E(q) - The seven artefacts

[The artefacts are not unlike those found in "Sorcerer's Cave", though all of the details are different. The Eye of God was differently cursed in the original: here it is dangerous to carry around, but one of the maze quests is exactly to carry it for a long way. Our version of the Ring is immensely powerful, but there is a catch: although the wearer becomes almost immortal on lower levels, he is likely to emerge back up to higher levels with dangerously low STR, so there is some danger of surviving a tussle with demons far below only to be knocked on the head by a gnome on level 1.

No equivalent to the Divining Rod and the Enchanted Map exist in the original board game: nor could they, really, since the players could always see the entire labyrinth laid out on the floor.]

An artefact is a kind of thing. An artefact is magical essence. An artefact has a number called minimum level. The minimum level of an artefact is usually 1. Every turn when the location is the Budless Grove and the player carries an artefact: say "You barely notice the disappearance of [the list of artefacts carried by the player], returned by magic into the labyrinth."; repeat with trinket running through artefacts carried by the player begin; return the trinket to the pack; end repeat.

Instead of inserting an artefact into something, say "The artefacts of the maze may not be concealed in any way."

The Charmed Flute is an artefact in Terra Incognita. "The Charmed Flute, a precious artefact, lies discarded here." The description is "When played, the Charmed Flute soothes any hostile creatures (other than the undead) to quiescence: but the Flute may be played only once before vanishing again into the labyrinth."

Musically playing is an action applying to one carried thing. Understand "play [something]" as musically playing. Check musically playing: unless the noun is the Charmed Flute, say "That is not a musical instrument you know how to play." instead.

Carry out musically playing:

if a hostile monster is in the location:

say "As you play an unearthly lullaby on the Charmed Flute, it is as if you soothe [the list of hostile monsters in the location]. You are now free to walk peaceably here; but the Flute, its task performed, vanishes away.";

now all monsters in the location are indifferent;

return the Charmed Flute to the pack;

otherwise:

say "You play a short passacaglia to pass the time. But in the absence of hostile creatures, there is no effect beyond the soothing of your tired soul.".

The Eye of God is an artefact in Terra Incognita. "The Eye of God, a baleful green gemstone, glares up at you." It has minimum level 3. The description is "Cursed and yet precious, the Eye of God is the strangest of all the artefacts of the labyrinth."

Rule for calculating combat modifiers of the player:

if the player carries the Eye of God, modify to-hit roll by -2 for "carrying the Eye of God";

continue the activity.

The Ring of Power is an artefact in Terra Incognita. "Discarded almost as if it were not the most puissant of all artefacts in the labyrinth is this Ring of Power." It has minimum level 2. The description is "On the third and lower levels of the labyrinth, the wearer of the Ring of Power is invulnerable from (most) harm inflicted by others when his or her STR falls below twice his or her own level." The Ring of Power is wearable.

The Talisman is an artefact in Terra Incognita. "Propped up in the centre of the space in front of you is the Talisman." It has minimum level 2. The description is "He who carries the Talisman will not be attacked by the undead." Instead of wearing the Talisman, say "This charm is carried, not worn."

Every turn when the player carries the Talisman and an undead monster is in the location:

now all undead monsters in the location are indifferent;

say "The Talisman wards off attack from [the list of undead monsters in the location]."

For calculating damage modifiers of the player:

let the threshold be the level of the player;

let the threshold be the threshold multiplied by 2;

let the putative strength be the strength of the player;

decrease the putative strength by the damage incurred;

if the player is wearing the Ring of Power and the current maze level is greater than 2 and the putative strength is less than the threshold:

say ": the Ring of Power on your finger glows fire-red";

let the largest safe amount be the strength of the player;

decrease the largest safe amount by the threshold;

if the largest safe amount is less than 0, let the largest safe amount be 0;

now the damage incurred is the largest safe amount;

stop; [I.e., don't continue the activity: there's no point.]

continue the activity.

The Magic Carpet is an artefact in Terra Incognita. "Rolled up in front of you is the Magic Carpet." It has minimum level 2. The description is "A useful artefact of the labyrinth: it enables the mage, once only, to move one position in any direction (north, south, east, west, up or down) regardless of walls or hedges. (Type RIDE CARPET NORTH, or how may you.)"

Carpet-riding is an action applying to one carried thing and one visible thing. Understand "ride [something] [direction]" as carpet-riding. Check carpet-riding: unless the noun is the Magic Carpet, say "That's not something you can ride." instead; unless the second noun is a direction, say "That's not a direction you can take the carpet in." instead.

Carry out carpet-riding:

let the current position be the grid position of the location;

let the new position be the vector sum of the current position and the vector of the second noun;

if the new position is <0,0,0>, say "The carpet is unable to take you that way, which would lie outwith the labyrinth." instead;

let the destination room be the room at the new position;

let the novelty factor be 0;

if the destination room is Solid Rock:

if a labyrinth room is acceptable:

let the destination room be a random acceptable labyrinth room;

position the destination room at the new position;

let the novelty factor be 1;

otherwise:

say "The carpet is unable to take you that way, which would lie outwith the labyrinth." instead;

return the Magic Carpet to the pack;

say "The Magic Carpet transports you one place [second noun] in the labyrinth, then melts away into air.";

let the way be the second noun;

let the reverse way be the opposite of the second noun;

if the room the way from the location is Terra Incognita:

if the room the reverse way from the destination room is Terra Incognita:

change the way exit of the location to the destination room;

change the reverse way exit of the destination room to the location;

otherwise:

change the way exit of the location to Solid Rock;

change the reverse way exit of the destination room to Solid Rock;

if the novelty factor is 1, draw cards for the destination room;

move the player to the destination room.

An artefact called the Divining Rod is in Terra Incognita. "The Divining Rod, one of the artefacts of the Maze, lies before you." The description is "If waved, the divining rod will give the mage some idea of his location in the labyrinth."

Instead of waving the Divining Rod:

say "The Divining Rod senses that ";

if the location is the Hedge Archway, say "you are in the Archway. Well, there's a surprise." instead;

unless the current maze level is 1, say "you are below ground, in level [current maze level] of the labyrinth; ";

let the current position be the grid position of the location;

let the budless position be the grid position of the Hedge Archway;

let the eastward journey be the easting part of the current position;

decrease the eastward journey by the easting part of the budless position;

let the northward journey be the northing part of the current position;

decrease the northward journey by the northing part of the budless position;

let the westward journey be 0 minus the eastward journey;

let the southward journey be 0 minus the northward journey;

if the eastward journey is 0 and the northward journey is 0:

say "you are vertically below the Archway, ";

otherwise:

say "you have travelled ";

if the eastward journey > 0, say "east by [eastward journey in words], ";

if the westward journey > 0, say "west by [westward journey in words], ";

if the northward journey > 0, say "north by [northward journey in words], ";

if the southward journey > 0, say "south by [southward journey in words], ";

let the way out be the best route from the location to the Hedge Archway;

if the way out is a direction, say "and it pulls your hand to the direction [way out].";

otherwise say "and it shakes in your hand."

The Enchanted Map is an artefact in Terra Incognita. "The Enchanted Map, one of the artefacts of the Maze, lies here for you to find."

To plot line (N - a number) of room (R - a room):

if R is Solid Rock:

say " ";

stop;

if R is unvisited:

say ":::::";

stop;

if R is Earthquake-damaged:

say "#####";

stop;

if R is the Island in the Deep Pool:

if N is 1, say "~~~~~";

if N is 2, say "~~O~~";

if N is 3, say "~~~~~";

stop;

if N is:

-- 1:

if R exits north, say " |";

otherwise say " ";

if R is ascending, say "/ ";

otherwise say " ";

-- 2:

if R exits west, say "-";

otherwise say " ";

say the map legend of R;

if R exits east, say "-";

otherwise say " ";

-- 3:

if R is descending, say " /";

otherwise say " ";

if R exits south, say "| ";

otherwise say " ".

Instead of examining the Enchanted Map:

let grid ref be the grid position of the location;

if grid ref is <0,0,0>, stop;

let L be the maze level part of the grid ref;

let the design be "";

if L is:

-- 1: let the design be "=-=-=";

-- 2: let the design be "-=-=-";

-- 3: let the design be "=+=+=";

-- 4: let the design be "=====";

-- 5: let the design be "=+o+=";

if L is greater than 5:

let the design be "#####";

say "[fixed letter spacing]+[design][design][design][design][design]+[line break]";

repeat with dN running from -1 to 1:

repeat with stripe running from 1 to 3:

say "#";

repeat with dE running from -2 to 2:

let E be the easting part of the grid ref;

let N be the northing part of the grid ref;

let L be the maze level part of the grid ref;

let E be E plus dE;

let N be N minus dN;

let the offset ref be the spatial coordinate with maze level part L easting part E northing part N;

let the offset room be the room at the offset ref;

plot line stripe of room offset room;

say "#[line break]";

say "+[design][design][design][design][design]+[line break][variable letter spacing]".