Bronze — 34 of 46

Section 2 - Reading vs Examining

A thing has some text called printing. The printing of a thing is usually "blank".

Definition: a thing is legible if the printing of it is not "blank".

After examining a legible thing: try reading the noun.

Understand the command "read" as something new. Understand "read about [text] in [something]" as consulting it about (with nouns reversed). Understand "read [something] about/on [text]" as consulting it about. Understand "read [text] in [something]" as consulting it about (with nouns reversed).

Understand "read [something]" as reading. Reading is an action applying to one thing, requiring light. Check reading: if the printing of the noun is "blank", say "Nothing is written on [the noun]." instead. Carry out reading:

let typing be the printing of the noun;

say "You read: [italic type][typing][roman type][paragraph break]". Report reading: do nothing.

Instead of reading the poison reference books: say "You flip idly through some pages in Persian before admitting to yourself that this is fruitless."

Instead of reading the papers: say "You skim the annals of 1102-1105, and decide that life has really gotten more interesting since the twelfth century. However, if you want to find anything specific here, you're going to have to look it up by name."

Instead of reading the contract book:

if the player is in the Translation Room

begin;

if the candle is visible,

say "You read with interest the indenture of a certain [if a random chance of 1 in 2 succeeds]ostler[otherwise]fighting-man[end if]. Thanks to the neat way the names are written at the top right corner of each page, you could easily look up anyone, though.";

otherwise

say "The lettering, though now in the vernacular, is too dim and small for you.";

otherwise;

say "The words are in a language you don't understand: even the Beast had to take it to the translation room to make any sense of it.";

end if.

Instead of reading the notes:

say "Simply flipping through them with no particular goal in mind is inexplicably disquieting to you, as though you might learn a maddening truth if you are not extremely cautious."

Instead of reading the helmet when the player is not in the Translation Room:

say "Lines of writing arc over each ear, but you do not know the language in question."

Before reading or examining the helmet when the player wears the helmet:

say "You can't, of course, get a good look at the helmet while you're wearing it, so... ";

try taking off the helmet;

if the player wears the helmet, stop the action.