Bronze — 21 of 46

Section 3 - Debtor's Paradise

The Debtor's Paradise is south of the Central Crypt. "The graves of men who died before resolving their debts." Debtor's Paradise is dark.

Some stones are a floor in the Paradise. Understand "floor" as stones when the player is in Paradise. The description is "Seemingly even[if trapdoor is not scenery], except where the trap door is[end if]." Instead of touching the stones when the trapdoor is scenery: say "You run your hands over the floor, but don't detect any telltale signs. You'll have to go about this another way."

Instead of walking toward the stones: try jumping. [1]

Before going from Debtor's Paradise when the trapdoor is scenery:

if in darkness, continue the action;

say "As you walk out of the room, you notice that your footsteps sound odd[if player wears the helmet], as though there were hollow space somewhere under the stones -- though you cannot identify a specific part of the floor that seems more vulnerable[end if]."

Before going to Debtor's Paradise when the trapdoor is scenery:

if in darkness, continue the action;

say "The floor sounds progressively[if player wears the helmet] hollower[otherwise] stranger[end if] as you walk toward the middle of the room."

Before going through the trapdoor when the trapdoor is scenery:

say "You haven't found a way down." instead.

Instead of jumping: say "You hop, but don't attain much height."

Instead of jumping when the player is on a supporter:

try exiting instead.

Instead of jumping in Debtor's Paradise:

say "The floor thuds hollowly under you."

Instead of jumping in Debtor's Paradise when the player wears the helmet and the trapdoor is scenery:

now the trapdoor is not scenery;

now the trapdoor is fixed in place;

say "You hop experimentally across the floor, the helmet amplifying your sensitivity to every sound, so that you are able to distinguish the exact flagstone at which the hollow thudding becomes most resonant.

On a bit of investigation, this stone turns out to be loose."

Instead of attacking the stones when the trapdoor is scenery:

if the player is wearing the helmet

begin;

now the trapdoor is not scenery;

now the trapdoor is fixed in place;

say "You tap experimentally on the floor, listening closely through the power of the helmet, until you find a suspiciously resonant -- and loose -- stone.";

otherwise;

say "You tap experimentally on the floor, but lack the acuity of hearing to tell whether there are different degrees of hollowness.";

end if.

Instead of listening to the stones when the player wears the helmet:

say "You press your ear to the ground and think you hear the distant movement of liquid -- but it's hard to be sure."

The trapdoor is a door. The description is "A trapdoor -- well, really, a hinged flagstone, not much different from the rest of the floor to which it belongs." Understand "stone" or "flagstone" as the trapdoor when the trapdoor is not scenery. Instead of pushing or pulling or turning the closed trapdoor: try opening the trapdoor.

Visibility rule when examining the trapdoor:

if in darkness

begin;

if the trapdoor is not scenery

begin;

say "You can't see very clearly in this light, of course, but you lean close and squint...";

there is sufficient light;

otherwise;

there is insufficient light;

end if;

otherwise;

there is sufficient light;

end if.

Understand "trap" or "door" as the trapdoor. The trapdoor is scenery. Below the trapdoor is the Dank Room. Above the trapdoor is Debtor's Paradise.

Before listing nondescript items of Debtor's Paradise when the trapdoor is unseen: now the trapdoor is not marked for listing.

Before doing something to the trapdoor when the trapdoor is scenery:

say "You can't see any such thing." instead.

Before going down in the Debtor's Paradise when the trapdoor is scenery: try going south instead. After deciding the scope of the player when the location is the Debtor's Paradise: if the trapdoor is not scenery, place trapdoor in scope.